PROC VARCOMP: Analyzing the Cure Rate of Rubber :: SAS/STAT(R) 9.2 User's Guide, Second Edition

The VARCOMP Procedure

Analyzing the Cure Rate of Rubber

This example, using data from Hicks (1973), concerns an experiment to determine the sources of variability in cure rates of rubber. The goal of the experiment was to find out if the different laboratories contributed more to the variance of cure rates than did the different batches of raw materials. This information would be useful in trying to control the cure rate of the final product because it would provide insight into the sources of the variability in cure rates. The rubber used was cured at three temperatures, which were taken to be fixed. Three laboratories were chosen at random, and three different batches of raw material were tested at each combination of temperature and laboratory. The following statements read the data into the SAS data set Cure.

   data Cure; 
      input Lab Temp Batch $ Cure @@;
      datalines;
   1 145 A 18.6   1 145 A 17.0   1 145 A 18.7   1 145 A 18.7
   1 145 B 14.5   1 145 B 15.8   1 145 B 16.5   1 145 B 17.6
   1 145 C 21.1   1 145 C 20.8   1 145 C 21.8   1 145 C 21.0
   1 155 A  9.5   1 155 A  9.4   1 155 A  9.5   1 155 A 10.0
   1 155 B  7.8   1 155 B  8.3   1 155 B  8.9   1 155 B  9.1
   1 155 C 11.2   1 155 C 10.0   1 155 C 11.5   1 155 C 11.1
   1 165 A  5.4   1 165 A  5.3   1 165 A  5.7   1 165 A  5.3
   1 165 B  5.2   1 165 B  4.9   1 165 B  4.3   1 165 B  5.2
   1 165 C  6.3   1 165 C  6.4   1 165 C  5.8   1 165 C  5.6
   2 145 A 20.0   2 145 A 20.1   2 145 A 19.4   2 145 A 20.0
   2 145 B 18.4   2 145 B 18.1   2 145 B 16.5   2 145 B 16.7
   2 145 C 22.5   2 145 C 22.7   2 145 C 21.5   2 145 C 21.3
   2 155 A 11.4   2 155 A 11.5   2 155 A 11.4   2 155 A 11.5
   2 155 B 10.8   2 155 B 11.1   2 155 B  9.5   2 155 B  9.7
   2 155 C 13.3   2 155 C 14.0   2 155 C 12.0   2 155 C 11.5
   2 165 A  6.8   2 165 A  6.9   2 165 A  6.0   2 165 A  5.7
   2 165 B  6.0   2 165 B  6.1   2 165 B  5.0   2 165 B  5.2
   2 165 C  7.7   2 165 C  8.0   2 165 C  6.6   2 165 C  6.3
   3 145 A 19.7   3 145 A 18.3   3 145 A 16.8   3 145 A 17.1
   3 145 B 16.3   3 145 B 16.7   3 145 B 14.4   3 145 B 15.2
   3 145 C 22.7   3 145 C 21.9   3 145 C 19.3   3 145 C 19.3
   3 155 A  9.3   3 155 A 10.2   3 155 A  9.8   3 155 A  9.5
   3 155 B  9.1   3 155 B  9.2   3 155 B  8.0   3 155 B  9.0
   3 155 C 11.3   3 155 C 11.0   3 155 C 10.9   3 155 C 11.4
   3 165 A  6.7   3 165 A  6.0   3 165 A  5.0   3 165 A  4.8
   3 165 B  5.7   3 165 B  5.5   3 165 B  4.6   3 165 B  5.4
   3 165 C  6.6   3 165 C  6.5   3 165 C  5.9   3 165 C  5.8
   ;

The variables Lab, Temp, and Batch contain levels of laboratory, temperature, and batch, respectively. The Cure variable contains the response values.

The following SAS statements perform a restricted maximum likelihood variance component analysis.

   title 'Analyzing the Cure Rate of Rubber';
   proc varcomp method=reml data=cure;
      class temp lab batch;
      model cure=temp|lab batch(lab temp) / fixed=1;
   run;

The FIXED=1 option indicates that the first factor, Temp, is fixed. The effect specification Temp|Lab is equivalent to putting the three terms Temp, Lab, and Temp*Lab in the model. Batch(Lab Temp) is equivalent to putting Batch(Temp*Lab) in the MODEL statement. The results of this analysis are displayed in Figure 94.1 through Figure 94.4.

Figure 94.1 Class Level Information

Analyzing the Cure Rate of Rubber

Variance Components Estimation Procedure

Class Level Information
Class	Levels	Values
Temp	3	145 155 165
Lab	3	1 2 3
Batch	3	A B C

Number of Observations Read	108
Number of Observations Used	108

Dependent Variable:	Cure

Figure 94.1 provides information about the variables used in the analysis and the number of observations and specifies the dependent variable.

Figure 94.2 Iteration History

REML Iterations
Iteration	Objective	Var(Lab)	Var(Temp*Lab)	Var(Batch(Temp*Lab))	Var(Error)
0	13.4500060254	0.5094464340	0	2.4004888633	0.5787185225
1	13.0898262160	0.3194348317	0	2.0869636935	0.6016005334
2	13.0893125570	0.3176048001	0	2.0738906134	0.6026217204
3	13.0893125555	0.3176017115	0	2.0738685461	0.6026234568

Convergence criteria met.

The "REML Iterations" table in Figure 94.2 displays the iteration history, which includes the value of the objective function associated with REML and the values of the variance components at each iteration.

Figure 94.3 REML Estimates

REML Estimates
Variance Component	Estimate
Var(Lab)	0.31760
Var(Temp*Lab)	0
Var(Batch(Temp*Lab))	2.07387
Var(Error)	0.60262

Figure 94.3 displays the REML estimates of the variance components.

Figure 94.4 Covariance Matrix for REML Estimates

Asymptotic Covariance Matrix of Estimates
	Var(Lab)	Var(Temp*Lab)	Var(Batch(Temp*Lab))	Var(Error)
Var(Lab)	0.32452	0	-0.04998	1.026E-12
Var(Temp*Lab)	0	0	0	0
Var(Batch(Temp*Lab))	-0.04998	0	0.45042	-0.0022417
Var(Error)	1.026E-12	0	-0.0022417	0.0089668

The "Asymptotic Covariance Matrix of Estimates" table in Figure 94.4 displays the asymptotic covariance matrix of the REML estimates.

The results of the analysis show that the variance attributable to Batch(Temp*Lab) (with a variance component of 2.0739) is considerably larger than the variance attributable to Lab (0.3176). Therefore, attempts to reduce the variability of cure rates should concentrate on improving the homogeneity of the batches of raw material used rather than standardizing the practices or equipment within the laboratories. Also, note that since the Batch(Temp*Lab) variance is considerably larger than the experimental error (Var(Error)=0.6026), the Batch(Temp*Lab) variability plays an important part in the overall variability of the cure rates.

Top of Page