The PLOTS(INTERPOLATE) Option

This section illustrates one use of the PLOTS(INTERPOLATE) option for use with ODS Graphics. The data set has two groups of observations, c = 1 and c = 2. Each group is sparse, having only five observations, so the plots of the transformations and fit functions are not smooth. A second DATA step adds additional observations to the data set, over the range of x, with y missing. These observations do not contribute to the analysis, but they are used in computations of transformed and predicted values. The resulting plots are much smoother in the latter case than in the former. The other results of the analysis are the same. The following statements produce Figure 90.78 and Figure 90.79:

   title 'Smoother Interpolation with PLOTS(INTERPOLATE)';
   
   data a;
      input c y x;
      output;
      datalines;
   1 1 1
   1 2 2
   1 4 3
   1 6 4
   1 7 5
   2 3 1
   2 4 2
   2 5 3
   2 4 4
   2 5 5
   ;

   ods graphics on;
   
   proc transreg data=a plots=(tran fit) ss2;
      model ide(y) = pbs(x) * class(c / zero=none);
      run;
   
   data b;
      set a end=eof;
      output;
      if eof then do;
         y = .;
         do x = 1 to 5 by 0.05;
            c = 1; output;
            c = 2; output;
            end;
         end;
      run;
   
   proc transreg data=b plots(interpolate)=(tran fit) ss2;
      model ide(y) = pbs(x) * class(c / zero=none);
      run;
   
   ods graphics off;

The results with no interpolation are shown in Figure 90.78. The transformation and fit functions are not at all smooth. The results with interpolation are shown in Figure 90.79. The transformation and fit functions are smooth in Figure 90.79, because there are intermediate points to plot.