Previous Page

|

Next Page

The TRANSREG Procedure

Hypothesis Tests for Simple Univariate Models

If the dependent variable has one parameter (IDENTITY, LINEAR with no missing values, and so on) and if there are no monotonicity constraints, PROC TRANSREG fits univariate models, which can also be fit with a DATA step and PROC REG. This is illustrated with the following artificial data set:

   data htex;
      do i = 0.5 to 10 by 0.5;
         x1 = log(i);
         x2 = sqrt(i) + sin(i);
         x3 = 0.05 * i * i + cos(i);
         y  = x1 - x2 + x3 + 3 * normal(7);
         x1 = x1 + normal(7);
         x2 = x2 + normal(7);
         x3 = x3 + normal(7);
         output;
      end;
   run;

Both PROC TRANSREG and PROC REG are run to fit the same polynomial regression model as follows:

   proc transreg data=htex ss2 short;
      title 'Fit a Polynomial Regression Model with PROC TRANSREG';
      model identity(y) = spline(x1);
   run;
   
   data htex2;
      set htex;
      x1_1 = x1;
      x1_2 = x1 * x1;
      x1_3 = x1 * x1 * x1;
   run;
   
   proc reg;
      title 'Fit a Polynomial Regression Model with PROC REG';
      model y = x1_1 - x1_3;
   run; quit;

The ANOVA and regression tables from PROC TRANSREG are displayed in Figure 90.69. The ANOVA and regression tables from PROC REG are displayed in Figure 90.70. The SHORT a-option is specified with PROC TRANSREG to suppress the iteration history.

Figure 90.69 ANOVA and Regression Output from PROC TRANSREG

Fit a Polynomial Regression Model with PROC TRANSREG

The TRANSREG Procedure

Dependent Variable Identity(y)

Number of Observations Read	20
Number of Observations Used	20

Identity(y)
Algorithm converged.

The TRANSREG Procedure Hypothesis Tests for Identity(y)

Univariate ANOVA Table Based on the Usual Degrees of Freedom
Source	DF	Sum of Squares	Mean Square	F Value	Pr > F
Model	3	5.8365	1.94550	0.14	0.9329
Error	16	218.3073	13.64421
Corrected Total	19	224.1438

Root MSE	3.69381	R-Square	0.0260
Dependent Mean	0.85490	Adj R-Sq	-0.1566
Coeff Var	432.07258

Univariate Regression Table Based on the Usual Degrees of Freedom
Variable	DF	Coefficient	Type II Sum of Squares	Mean Square	F Value	Pr > F
Intercept	1	1.4612767	18.8971	18.8971	1.38	0.2565
Spline(x1)	3	-0.3924013	5.8365	1.9455	0.14	0.9329

The PROC TRANSREG regression table differs in several important ways from the parameter estimate table produced by PROC REG. The REG procedure displays standard errors and t statistics. PROC TRANSREG displays Type II sums of squares, mean squares, and F statistics. The difference is because the numerator degrees of freedom are not always 1, so t tests are not uniformly appropriate. When the degrees of freedom for variable is 1, the following relationships hold between the standard errors and the Type II sums of squares ():

and

PROC TRANSREG does not provide tests of the individual terms that go into the transformation. (However, it could if BSPLINE or PSPLINE had been specified instead of SPLINE.) The test of spline(x1) is the same as the test of the overall model. The intercepts are different due to the different numbers of variables and their standardizations.

In the next example, both x1 and x2 are transformed in the first PROC TRANSREG step, and PROC TRANSREG is used instead of a DATA step to create the polynomials for PROC REG. Both PROC TRANSREG and PROC REG fit the same polynomial regression model. The following statements run PROC TRANSREG and PROC REG and produce Figure 90.71 and Figure 90.72:

   title 'Two-Variable Polynomial Regression';
   
   proc transreg data=htex ss2 solve;
      model identity(y) = spline(x1 x2);
   run;
   
   proc transreg noprint data=htex maxiter=0;
      /* Use PROC TRANSREG to prepare input to PROC REG */
      model identity(y) = pspline(x1 x2);
      output out=htex2;
   run;
   
   proc reg data=htex2;
      model y = x1_1-x1_3 x2_1-x2_3;
      test x1_1, x1_2, x1_3;
      test x2_1, x2_2, x2_3;
   run; quit;

There are three iteration histories: one for the overall model and two for the two independent variables. The first PROC TRANSREG iteration history shows the R square of 0.17287 for the fit of the overall model. The second is for the following model:

   model identity(y) = spline(x2);

This model excludes spline(x1). The third iteration history is for the following model:

   model identity(y) = spline(x1);

This model excludes spline(x2). The difference between the first and second R square times the total sum of squares is the model sum of squares for spline(x1):

The difference between the first and third R square times the total sum of squares is the model sum of squares for spline(x2):

Figure 90.72 displays the PROC REG results. The TEST statement in PROC REG tests the null hypothesis that the vector of parameters for x1_1 x1_2 x1_3 is zero. This is the same test as the spline(x1) test used by PROC TRANSREG. Similarly, the PROC REG test that the vector of parameters for x2_1 x2_2 x2_3 is zero is the same as the PROC TRANSREG SPLINE(x2) test. So for models with no monotonicity constraints and no dependent variable transformations, PROC TRANSREG provides little more than a different packaging of standard least-squares methodology.

Copyright © 2009 by SAS Institute Inc., Cary, NC, USA. All rights reserved.