Previous Page

|

Next Page

The TRANSREG Procedure

Output Data Set

The OUT= output data set can contain a great deal of information; however, in most cases, the output data set contains a small portion of the entire range of available information.

Output Data Set Examples

This section provides three brief examples, illustrating some typical OUT= output data sets. See the section Output Data Set Contents for a complete list of the contents of the OUT= data set.

The first example shows the output data set from a two-way ANOVA model. The following statements produce Figure 90.66:

   title 'ANOVA Output Data Set Example';
   
   data ReferenceCell;
      input y x1 $ x2 $;
      datalines;
   11  a  a
   12  a  a
   10  a  a
    4  a  b
    5  a  b
    3  a  b
    5  b  a
    6  b  a
    4  b  a
    2  b  b
    3  b  b
    1  b  b
   ;

   * Fit Reference Cell Two-Way ANOVA Model;
   proc transreg data=ReferenceCell;
      model identity(y) = class(x1 | x2);
      output coefficients replace predicted residuals;
   run;
   
   * Print the Results;
   proc print;
   run;
   
   proc contents position;
      ods select position;
   run;

Figure 90.66 ANOVA Example Output Data Set Contents

ANOVA Output Data Set Example

Obs	_TYPE_	_NAME_	y	Py	Ry	Intercept	x1a	x2a	x1ax2a	x1	x2
1	SCORE	ROW1	11	11	0	1	1.0	1	1	a	a
2	SCORE	ROW2	12	11	1	1	1.0	1	1	a	a
3	SCORE	ROW3	10	11	-1	1	1.0	1	1	a	a
4	SCORE	ROW4	4	4	0	1	1.0	0	0	a	b
5	SCORE	ROW5	5	4	1	1	1.0	0	0	a	b
6	SCORE	ROW6	3	4	-1	1	1.0	0	0	a	b
7	SCORE	ROW7	5	5	0	1	0.0	1	0	b	a
8	SCORE	ROW8	6	5	1	1	0.0	1	0	b	a
9	SCORE	ROW9	4	5	-1	1	0.0	1	0	b	a
10	SCORE	ROW10	2	2	0	1	0.0	0	0	b	b
11	SCORE	ROW11	3	2	1	1	0.0	0	0	b	b
12	SCORE	ROW12	1	2	-1	1	0.0	0	0	b	b
13	M COEFFI	y	.	.	.	2	2.0	3	4
14	MEAN	y	.	.	.	.	7.5	8	11

ANOVA Output Data Set Example

The CONTENTS Procedure

Variables in Creation Order
#	Variable	Type	Len	Label
1	_TYPE_	Char	8
2	_NAME_	Char	32
3	y	Num	8
4	Py	Num	8	y Predicted Values
5	Ry	Num	8	y Residuals
6	Intercept	Num	8	Intercept
7	x1a	Num	8	x1 a
8	x2a	Num	8	x2 a
9	x1ax2a	Num	8	x1 a * x2 a
10	x1	Char	32
11	x2	Char	32

The _TYPE_ variable indicates observation type: score, multiple regression coefficient (parameter estimates), and marginal means. The _NAME_ variable contains the default observation labels, "ROW1", "ROW2", and so on, and contains the dependent variable name (y) for the remaining observations. If you specify an ID statement, _NAME_ contains the values of the first ID variable for score observations. The y variable is the dependent variable, Py contains the predicted values, Ry contains the residuals, and the variables Intercept through x1ax2a contain the design matrix. The x1 and x2 variables are the original CLASS variables.

The next example shows the contents of the output data set from fitting a curve through a scatter plot. The following statements produce Figure 90.67:

   title 'Output Data Set for Curve Fitting Example';
   
   data a;
      do x = 1 to 100;
         y = log(x) + sin(x / 10) + normal(7);
         output;
      end;
   run;
   
   proc transreg;
      model identity(y) = spline(x / nknots=9);
      output predicted out=b;
   run;
   
   proc contents position;
      ods select position;
   run;

Figure 90.67 Predicted Values Example Output Data Set Contents

Output Data Set for Curve Fitting Example

The CONTENTS Procedure

Variables in Creation Order
#	Variable	Type	Len	Label
1	_TYPE_	Char	8
2	_NAME_	Char	32
3	y	Num	8
4	Ty	Num	8	y Transformation
5	Py	Num	8	y Predicted Values
6	Intercept	Num	8	Intercept
7	x	Num	8
8	TIntercept	Num	8	Intercept Transformation
9	Tx	Num	8	x Transformation

The OUT= data set contains _TYPE_ and _NAME_ variables. Since no coefficients or coordinates are requested, all observations are _TYPE_=’SCORE’. The y variable is the original dependent variable, Ty is the transformed dependent variable, Py contains the predicted values, x is the original independent variable, and Tx is the transformed independent variable. The data set also contains an Intercept and transformed intercept TIntercept variable. (In this case, the transformed intercept is the same as the intercept. However, if you specify the TSTANDARD= and ADDITIVE options, these are not always the same.)

The following example shows the results from specifying METHOD=MORALS when there is more than one dependent variable:

   title 'METHOD=MORALS Output Data Set Example';
   
   data x;
      input y1 y2 x1 $ x2 $;
      datalines;
   11 1 a a
   10 4 b a
    5 2 a b
    5 9 b b
    4 3 c c
    3 6 b a
    1 8 a b
   ;

   * Fit Reference Cell Two-Way ANOVA Model;
   proc transreg data=x noprint solve;
      model spline(y1 y2) = opscore(x1 x2 / name=(n1 n2));
      output coefficients predicted residuals;
      id x1 x2;
   run;
   
   * Print the Results;
   proc print;
   run;
   
   proc contents position;
      ods select position;
   run;

These statements produce Figure 90.68.

If you specify METHOD=MORALS with multiple dependent variables, PROC TRANSREG performs separate univariate analyses and stacks the results in the OUT= data set. For this example, the results of the first analysis are in the partition designated by _DEPVAR_=’Spline(y1)’ and the results of the second analysis are in the partition designated by _DEPVAR_=’Spline(y2)’, which are the transformation and dependent variable names. Each partition has _TYPE_=’SCORE’ observations for the variables and a _TYPE_=’M COEFFI’ observation for the coefficients. In this example, an ID variable is specified, so the _NAME_ variable contains the formatted values of the first ID variable. Since both dependent variables have to go into the same column, the dependent variable is given a new name, _DEPEND_. The dependent variable transformation is named T_DEPEND_, the predicted values variable is named P_DEPEND_, and the residuals variable is named R_DEPEND_.

The independent variables are character OPSCORE variables. By default, PROC TRANSREG replaces character OPSCORE variables with category numbers and discards the original character variables. To avoid this, the input variables are renamed from x1 and x2 to n1 and n2 and the original x1 and x2 are added to the data set as ID variables. The n1 and n2 variables contain the initial values for the OPSCORE transformations, and the Tn1 and Tn2 variables contain optimal scores. The data set also contains an Intercept and transformed intercept TIntercept variable. The regression coefficients are in the transformation columns, which also contain the variables to which they apply.

Copyright © 2009 by SAS Institute Inc., Cary, NC, USA. All rights reserved.