Previous Page

|

Next Page

The TRANSREG Procedure

ANOVA Codings

This section illustrates several different codings of classification variables and hence several different ways of fitting two-way ANOVA models to some data. Each example fits an ANOVA model, displays the ANOVA table and parameter estimates, and displays the coded design matrix. Note throughout that the ANOVA tables and R squares are identical for all of the models, showing that the codings are equivalent. For each model, the parameter estimates are stated as a function of the cell means. The formulas are appropriate for a design such as this one, which is balanced and orthogonal (every level and every pair of levels occurs equally often). They will not work with unequal frequencies. Since this data set has cells, the full-rank codings all have six parameters. The following statements create the input data set, and display it in Figure 90.44:

   title 'Two-Way ANOVA Models';
   
   data x;
      input a b @@;
      do i = 1 to 2; input y @@; output; end;
      drop i;
      datalines;
   1 1   16 14         1 2   15 13
   2 1    1  9         2 2   12 20
   3 1   14  8         3 2   18 20
   ;

   proc print label;
   run;

Figure 90.44 Input Data Set

Two-Way ANOVA Models

Obs	a	b	y
1	1	1	16
2	1	1	14
3	1	2	15
4	1	2	13
5	2	1	1
6	2	1	9
7	2	2	12
8	2	2	20
9	3	1	14
10	3	1	8
11	3	2	18
12	3	2	20

The following statements fit a cell-means model and produce Figure 90.45 and Figure 90.46:

   proc transreg data=x ss2 short;
      title2 'Cell-Means Model';
      model identity(y) = class(a * b / zero=none);
      output replace;
   run;
   
   proc print label;
   run;

Figure 90.45 Cell-Means Model

Two-Way ANOVA Models

Cell-Means Model

The TRANSREG Procedure

Dependent Variable Identity(y)

Class Level Information
Class	Levels	Values
a	3	1 2 3
b	2	1 2

Number of Observations Read	12
Number of Observations Used	12
Implicit Intercept Model

The TRANSREG Procedure Hypothesis Tests for Identity(y)

Univariate ANOVA Table Based on the Usual Degrees of Freedom
Source	DF	Sum of Squares	Mean Square	F Value	Pr > F
Model	5	234.6667	46.93333	3.20	0.0946
Error	6	88.0000	14.66667
Corrected Total	11	322.6667

Root MSE	3.82971	R-Square	0.7273
Dependent Mean	13.33333	Adj R-Sq	0.5000
Coeff Var	28.72281

Univariate Regression Table Based on the Usual Degrees of Freedom
Variable	DF	Coefficient	Type II Sum of Squares	Mean Square	F Value	Pr > F	Label
Class.a1b1	1	15.0000000	450.000	450.000	30.68	0.0015	a 1 * b 1
Class.a1b2	1	14.0000000	392.000	392.000	26.73	0.0021	a 1 * b 2
Class.a2b1	1	5.0000000	50.000	50.000	3.41	0.1144	a 2 * b 1
Class.a2b2	1	16.0000000	512.000	512.000	34.91	0.0010	a 2 * b 2
Class.a3b1	1	11.0000000	242.000	242.000	16.50	0.0066	a 3 * b 1
Class.a3b2	1	19.0000000	722.000	722.000	49.23	0.0004	a 3 * b 2

The parameter estimates are

The next model is a reference cell model, and the default reference cell is the last cell, which in this case is the (3,2) cell. The following statements fit a reference cell model and produce Figure 90.47 and Figure 90.48:

   proc transreg data=x ss2 short;
      title2 'Reference Cell Model, (3,2) Reference Cell';
      model identity(y) = class(a | b);
      output replace;
   run;
   
   proc print label;
   run;

The parameter estimates are

The next model is a deviations-from-means model. This coding is also called effects coding. The default reference cell is the last cell (3,2). The following statements produce Figure 90.49 and Figure 90.50:

   proc transreg data=x ss2 short;
      title2 'Deviations from Means, (3,2) Reference Cell';
      model identity(y) = class(a | b / deviations);
      output replace;
   run;
   
   proc print label;
   run;

The parameter estimates are

The next model is a less-than-full-rank model. The parameter estimates are constrained to sum to zero within each effect. The following statements produce Figure 90.51 and Figure 90.52:

   proc transreg data=x ss2 short;
      title2 'Less-Than-Full-Rank Model';
      model identity(y) = class(a | b / zero=sum);
      output replace;
   run;
   
   proc print label;
   run;

The parameter estimates are

The constraints are

Only four of the five interaction constraints are needed. The fifth constraint is implied by the other four. (Given a table with four marginal sum-to-zero constraints, you can freely fill in only two cells. The values in the other four cells are determined from the first two cells and the constraints.) A full-rank model has six estimable parameters. This less-than-full-rank model has one parameter for the intercept, two for the first main effect (plus one more as determined by the first constraint), one for the second main effect (plus one more as determined by the second constraint), and two for the interactions (plus four more as determined by the next four constraints). Six of the twelve parameters are determined given the other six and the constraints. Notice that and match the corresponding estimates from the effects coding.

The next model is a reference cell model, but this time the reference cell is the first cell (1,1). The following statements produce Figure 90.53 and Figure 90.54:

   proc transreg data=x ss2 short;
      title2 'Reference Cell Model, (1,1) Reference Cell';
      model identity(y) = class(a | b / zero=first);
      output replace;
   run;
   
   proc print label;
   run;

The parameter estimates are

The next model is a deviations-from-means model, but this time the reference cell is the first cell (1,1). This coding is also called effects coding. The following statements produce Figure 90.55 and Figure 90.56:

   proc transreg data=x ss2 short;
      title2 'Deviations from Means, (1,1) Reference Cell';
      model identity(y) = class(a | b / deviations zero=first);
      output replace;
   run;
   
   proc print label;
   run;

The parameter estimates are

Notice that all of the parameter estimates match the corresponding estimates from the less-than-full-rank coding.

The following statements fit a model with an orthogonal-contrast coding and produce Figure 90.57 and Figure 90.58:

   proc transreg data=x ss2 short;
      title2 'Orthogonal Contrast Coding';
      model identity(y) = class(a | b / orthogonal);
      output replace;
   run;
   
   proc print label;
   run;

The parameter estimates are

The following statements fit a model with a standardized-orthogonal coding and produce Figure 90.59 and Figure 90.60:

   proc transreg data=x ss2 short;
      title2 'Standardized-Orthogonal Coding';
      model identity(y) = class(a | b / standorth);
      output replace;
   run;
   
   proc print label;
   run;

The parameter estimates are

The numerators in the square roots are sums of squares of the coded values for the unstandardized-orthogonal codings, and the denominators are the numbers of levels. These terms convert the estimates from the orthogonal contrast coding to the standardized-orthogonal coding. The term , which is 1 and could be dropped, is included in the preceding formulas to show the general pattern. Notice the regression tables for the orthogonal-contrast coding and the standardized-orthogonal coding. Some of the coefficients are different, but the rest of the table is the same since the coded variables for the two models differ only by a constant.

Copyright © 2009 by SAS Institute Inc., Cary, NC, USA. All rights reserved.