Previous Page

|

Next Page

The STEPDISC Procedure

Example 82.1 Performing a Stepwise Discriminant Analysis

The iris data published by Fisher (1936) have been widely used for examples in discriminant analysis and cluster analysis. The sepal length, sepal width, petal length, and petal width are measured in millimeters on 50 iris specimens from each of three species: Iris setosa, I. versicolor, and I. virginica.

   title 'Fisher (1936) Iris Data';
   
   proc format;
      value specname
         1='Setosa    '
         2='Versicolor'
         3='Virginica ';
   run;
   
   data iris;
      input SepalLength SepalWidth PetalLength PetalWidth
            Species @@;
      format Species specname.;
      label SepalLength='Sepal Length in mm.'
            SepalWidth ='Sepal Width in mm.'
            PetalLength='Petal Length in mm.'
            PetalWidth ='Petal Width in mm.';
      datalines;
   50 33 14 02 1 64 28 56 22 3 65 28 46 15 2 67 31 56 24 3
   63 28 51 15 3 46 34 14 03 1 69 31 51 23 3 62 22 45 15 2
   59 32 48 18 2 46 36 10 02 1 61 30 46 14 2 60 27 51 16 2
   
   ... more lines ...   

   63 33 60 25 3 53 37 15 02 1
   ;

A stepwise discriminant analysis is performed by using stepwise selection.

In the PROC STEPDISC statement, the BSSCP and TSSCP options display the between-class SSCP matrix and the total-sample corrected SSCP matrix. By default, the significance level of an test from an analysis of covariance is used as the selection criterion. The variable under consideration is the dependent variable, and the variables already chosen act as covariates. The following SAS statements produce Output 82.1.1 through Output 82.1.8:

   %let _stdvar = ;
   proc stepdisc data=iris bsscp tsscp;
      class Species;
      var SepalLength SepalWidth PetalLength PetalWidth;
   run;

Output 82.1.1 Iris Data: Summary Information

Fisher (1936) Iris Data

The STEPDISC Procedure

The Method for Selecting Variables is STEPWISE
Total Sample Size	150	Variable(s) in the Analysis	4
Class Levels	3	Variable(s) Will Be Included	0
		Significance Level to Enter	0.15
		Significance Level to Stay	0.15

Number of Observations Read	150
Number of Observations Used	150

Class Level Information
Species	Variable Name	Frequency	Weight	Proportion
Setosa	Setosa	50	50.0000	0.333333
Versicolor	Versicolor	50	50.0000	0.333333
Virginica	Virginica	50	50.0000	0.333333

In step 1, the tolerance is 1.0 for each variable under consideration because no variables have yet entered the model. The variable PetalLength is selected because its statistic, 1180.161, is the largest among all variables.

In step 2, with the variable PetalLength already in the model, PetalLength is tested for removal before a new variable is selected for entry. Since PetalLength meets the criterion to stay, it is used as a covariate in the analysis of covariance for variable selection. The variable SepalWidth is selected because its statistic, 43.035, is the largest among all variables not in the model and because its associated tolerance, 0.8164, meets the criterion to enter. The process is repeated in steps 3 and 4. The variable PetalWidth is entered in step 3, and the variable SepalLength is entered in step 4.

Since no more variables can be added to or removed from the model, the procedure stops at step 5 and displays a summary of the selection process.

PROC STEPDISC automatically creates a list of the selected variables and stores it in a macro variable. You can submit the following statement to see the list of selected variables:

   * print the macro variable list;
   %put &_stdvar;

The macro variable _StdVar contains the following variable list:

   SepalLength SepalWidth PetalLength PetalWidth

You could use this macro variable if you want to analyze these variables in subsequent steps as follows:

   proc discrim data=iris;
      class Species;
      var &_stdvar;
   run;

The results of this step are not shown.

Copyright © 2009 by SAS Institute Inc., Cary, NC, USA. All rights reserved.