Getting Started: STEPDISC Procedure

The data in this example are measurements of 159 fish caught in Finland’s lake Laengelmavesi; this data set is available from the Puranen. For each of the seven species (bream, roach, whitefish, parkki, perch, pike, and smelt) the weight, length, height, and width of each fish are tallied. Three different length measurements are recorded: from the nose of the fish to the beginning of its tail, from the nose to the notch of its tail, and from the nose to the end of its tail. The height and width are recorded as percentages of the third length variable. PROC STEPDISC will select a subset of the six quantitative variables that might be useful for differentiating between the fish species. This subset is used in conjunction with PROC CANDISC and PROC DISCRIM to develop discrimination models.

The following steps create the data set fish and use PROC STEPDISC to select a subset of potential discriminator variables. By default, PROC STEPDISC uses stepwise selection on all numeric variables that are not listed in other statements, and the significance levels for a variable to enter the subset and to stay in the subset are set to 0.15. The following statements produce Figure 82.1 through Figure 82.5:

   title 'Fish Measurement Data';
   
   proc format;
      value specfmt
         1='Bream'
         2='Roach'
         3='Whitefish'
         4='Parkki'
         5='Perch'
         6='Pike'
         7='Smelt';
   run;
   
   data fish (drop=HtPct WidthPct);
      input Species Weight Length1 Length2 Length3 HtPct WidthPct @@;
      Height=HtPct*Length3/100;
      Width=WidthPct*Length3/100;
      format Species specfmt.;
      datalines;
   1  242.0 23.2 25.4 30.0 38.4 13.4 1  290.0 24.0 26.3 31.2 40.0 13.8
   1  340.0 23.9 26.5 31.1 39.8 15.1 1  363.0 26.3 29.0 33.5 38.0 13.3
   1  430.0 26.5 29.0 34.0 36.6 15.1 1  450.0 26.8 29.7 34.7 39.2 14.2
   
   ... more lines ...   

   7   19.7 13.2 14.3 15.2 18.9 13.6 7   19.9 13.8 15.0 16.2 18.1 11.6
   ;

   proc stepdisc data=fish;
      class Species;
   run;

PROC STEPDISC begins by displaying summary information about the analysis (see Figure 82.1). This information includes the number of observations with nonmissing values, the number of classes in the classification variable (specified by the CLASS statement), the number of quantitative variables under consideration, the significance criteria for variables to enter and to stay in the model, and the method of variable selection being used. The frequency of each class is also displayed.