Previous Page

|

Next Page

The SCORE Procedure

Example 76.2 Regression Parameter Estimates

In this example, PROC REG computes regression parameter estimates for the Fitness data. (See Example 76.1 to for more information about how to create the Fitness data set.) The parameter estimates are output to a data set and used as scoring coefficients. For the first part of this example, PROC SCORE is used to score the Fitness data, which are the same data used in the regression.

In the second part of this example, PROC SCORE is used to score a new data set, Fitness2. For PROC SCORE, the TYPE= specification is PARMS, and the names of the score variables are found in the variable _MODEL_, which gets its values from the model label. The following code produces Output 76.2.1 through Output 76.2.3:

   
   proc reg data=Fitness outest=RegOut;
   
   OxyHat: model Oxygen=Age Weight RunTime RunPulse RestPulse;
      title 'REGRESSION SCORING EXAMPLE';
   run;
   

   proc print data=RegOut;
      title2 'OUTEST= Data Set from PROC REG';
   run;
   

   proc score data=Fitness score=RegOut out=RScoreP type=parms;
      var Age Weight RunTime RunPulse RestPulse;
   run;
   

   proc print data=RScoreP;
      title2 'Predicted Scores for Regression';
   run;
   

   proc score data=Fitness score=RegOut out=RScoreR type=parms;
      var Oxygen Age Weight RunTime RunPulse RestPulse;
   run;
   

   proc print data=RScoreR;
      title2 'Negative Residual Scores for Regression';
   run;

Output 76.2.1 shows the PROC REG output. The column labeled "Parameter Estimates" lists the parameter estimates. These estimates are output to the RegOut data set.

Output 76.2.1 Creating an OUTEST= Data Set with PROC REG

REGRESSION SCORING EXAMPLE

The REG Procedure

Model: OxyHat

Dependent Variable: Oxygen

Number of Observations Read	12
Number of Observations Used	12

Analysis of Variance
Source	DF	Sum of Squares	Mean Square	F Value	Pr > F
Model	5	509.62201	101.92440	15.80	0.0021
Error	6	38.70060	6.45010
Corrected Total	11	548.32261

Root MSE	2.53970	R-Square	0.9294
Dependent Mean	48.38942	Adj R-Sq	0.8706
Coeff Var	5.24847

Parameter Estimates
Variable	DF	Parameter Estimate	Standard Error	t Value	Pr > |t|
Intercept	1	151.91550	31.04738	4.89	0.0027
Age	1	-0.63045	0.42503	-1.48	0.1885
Weight	1	-0.10586	0.11869	-0.89	0.4068
RunTime	1	-1.75698	0.93844	-1.87	0.1103
RunPulse	1	-0.22891	0.12169	-1.88	0.1090
RestPulse	1	-0.17910	0.13005	-1.38	0.2176

Output 76.2.2 lists the RegOut data set. Note that _TYPE_=’PARMS’ and _MODEL_=’OXYHAT’, which are from the label in the MODEL statement in PROC REG.

Output 76.2.3 lists the data sets created by PROC SCORE. Since the SCORE= data set does not contain observations with _TYPE_=’MEAN’ or _TYPE_=’STD’, the data in the Fitness data set are not standardized before scoring. The SCORE= data set contains the variable Intercept, so this intercept value is used in computing the score. To produce the RScoreP data set, the VAR statement in PROC SCORE includes only the independent variables from the model in PROC REG. As a result, the OxyHat variable contains predicted values. To produce the RScoreR data set, the VAR statement in PROC SCORE includes both the dependent variables and the independent variables from the model in PROC REG. As a result, the OxyHat variable contains negative residuals (PREDICTACTUAL) as shown in Output 76.2.4. If the RESIDUAL option is specified, the variable OxyHat contains positive residuals (ACTUALPREDICT). If the PREDICT option is specified, the OxyHat variable contains predicted values.

The second part of this example uses the parameter estimates to score a new data set. The following statements produce Output 76.2.5 and Output 76.2.6:

      /* The FITNESS2 data set contains observations 13-16 from */
      /* the FITNESS data set used in EXAMPLE 2 in the PROC REG */
      /* chapter.                                               */
   data Fitness2;
      input Age Weight Oxygen RunTime RestPulse RunPulse;
      datalines;
   45  66.45  44.754  11.12  51  176
   47  79.15  47.273  10.60  47  162
   54  83.12  51.855  10.33  50  166
   49  81.42  49.156   8.95  44  180
   ;

   proc print data=Fitness2;
      title 'REGRESSION SCORING EXAMPLE';
      title2 'New Raw Data Set to be Scored';
   run;
   

   proc score data=Fitness2 score=RegOut out=NewPred type=parms
              nostd predict;
      var Oxygen Age Weight RunTime RunPulse RestPulse;
   run;
   

   proc print data=NewPred;
      title2 'Predicted Scores for Regression';
      title3 'for Additional Data from FITNESS2';
   run;
   

Output 76.2.5 lists the Fitness2 data set.

PROC SCORE scores the Fitness2 data set by using the parameter estimates in the RegOut data set. These parameter estimates result from fitting a regression equation to the Fitness data set. The NOSTD option is specified, so the raw data are not standardized before scoring. (However, the NOSTD option is not necessary here. The SCORE= data set does not contain observations with _TYPE_=’MEAN’ or _TYPE_=’STD’, so standardization is not performed.) The VAR statement contains the dependent variables and the independent variables used in PROC REG. In addition, the PREDICT option is specified. This combination gives predicted values for the new score variable. The name of the new score variable is OxyHat, from the value of the _MODEL_ variable in the SCORE= data set. Output 76.2.6 shows the data set produced by PROC SCORE.

Copyright © 2009 by SAS Institute Inc., Cary, NC, USA. All rights reserved.