Previous Page

|

Next Page

The PRINCOMP Procedure

Example 69.3 Job Ratings

This example uses the PRINCOMP procedure to analyze job performance. Police officers were rated by their supervisors in 14 categories as part of standard police departmental administrative procedure.

The following statements create the Jobratings data set:

   options validvarname=any;
   data Jobratings;
      input ('Communication Skills'n
             'Problem Solving'n
             'Learning Ability'n
             'Judgment Under Pressure'n
             'Observational Skills'n
             'Willingness to Confront Problems'n
             'Interest in People'n
             'Interpersonal Sensitivity'n
             'Desire for Self-Improvement'n
             'Appearance'n
             'Dependability'n
             'Physical Ability'n
             'Integrity'n
             'Overall Rating'n) (1.);
      datalines;
   26838853879867
   74758876857667
   56757863775875
   67869777988997
   99997798878888
   89897899888799
   89999889899798
   87794798468886
   35652335143113
   89888879576867
   76557899446397
   97889998898989
   76766677598888
   
   ... more lines ...   

   99899899899899
   76656399567486
   ;

The data set Jobratings contains 14 variables. Each variable contains the job ratings, using a scale measurement from 1 to 10 (1=fail to comply, 10=exceptional). The last variable Overall Rating contains a score as an overall index on how each officer performs.

The following statements request a principal component analysis on the Jobratings data set, output the scores to the Scores data set (OUT= Scores), and produce default plots. Note that variable Overall Rating is excluded from the analysis.

   ods graphics on;
   proc princomp data=Jobratings(drop='Overall Rating'n);
   run;

Figure 69.3.1 and Figure 69.3.2 display the PROC PRINCOMP output, beginning with simple statistics followed by the correlation matrix. By default, the PROC PRINCOMP statement requests principal components computed from the correlation matrix, so the total variance is equal to the number of variables, 13. In this example, it would also be reasonable to use the COV option, which would cause variables with a high variance (such as Dependability) to have more influence on the results than variables with a low variance (such as Learning Ability). If you used the COV option, scores would be computed from centered rather than standardized variables.

Output 69.3.1 Simple Statistics and Correlation Matrix from the PRINCOMP Procedure

Pre-Season 1985 College Basketball Rankings

College Teams as Ordered by PROC PRINCOMP

The PRINCOMP Procedure

Observations	103
Variables	13

Simple Statistics
	Communication Skills	Problem Solving	Learning Ability	Judgment Under Pressure	Observational Skills	Willingness to Confront Problems	Interest in People	Interpersonal Sensitivity	Desire for Self-Improvement	Appearance	Dependability	Physical Ability	Integrity
Mean	6.650485437	6.631067961	6.990291262	6.737864078	6.932038835	7.291262136	6.708737864	6.621359223	6.572815534	7.000000000	6.825242718	7.203883495	7.213592233
StD	1.764068036	1.590352602	1.339411238	1.731830976	1.761584269	1.525155524	1.892353385	1.760773587	1.729796212	1.798692335	1.917040123	1.555251845	1.845240223

Correlation Matrix
	Communication Skills	Problem Solving	Learning Ability	Judgment Under Pressure	Observational Skills	Willingness to Confront Problems	Interest in People	Interpersonal Sensitivity	Desire for Self-Improvement	Appearance	Dependability	Physical Ability	Integrity
Communication Skills	1.0000	0.6280	0.5546	0.5538	0.5381	0.5265	0.4391	0.5030	0.5642	0.4913	0.5471	0.2192	0.5081
Problem Solving	0.6280	1.0000	0.5690	0.6195	0.4284	0.5015	0.3972	0.4398	0.4090	0.3873	0.4546	0.3201	0.3846
Learning Ability	0.5546	0.5690	1.0000	0.4892	0.6230	0.5245	0.2735	0.1855	0.5737	0.3988	0.5110	0.2269	0.3142
Judgment Under Pressure	0.5538	0.6195	0.4892	1.0000	0.3733	0.4004	0.6226	0.6134	0.4826	0.2266	0.5471	0.3476	0.5883
Observational Skills	0.5381	0.4284	0.6230	0.3733	1.0000	0.7300	0.2616	0.1655	0.5985	0.4177	0.5626	0.4274	0.3906
Willingness to Confront Problems	0.5265	0.5015	0.5245	0.4004	0.7300	1.0000	0.2233	0.1291	0.5307	0.4825	0.4870	0.4872	0.3260
Interest in People	0.4391	0.3972	0.2735	0.6226	0.2616	0.2233	1.0000	0.8051	0.4857	0.2679	0.6074	0.3768	0.7452
Interpersonal Sensitivity	0.5030	0.4398	0.1855	0.6134	0.1655	0.1291	0.8051	1.0000	0.3713	0.2600	0.5408	0.2182	0.6920
Desire for Self-Improvement	0.5642	0.4090	0.5737	0.4826	0.5985	0.5307	0.4857	0.3713	1.0000	0.4474	0.5981	0.3752	0.5664
Appearance	0.4913	0.3873	0.3988	0.2266	0.4177	0.4825	0.2679	0.2600	0.4474	1.0000	0.5089	0.3820	0.4135
Dependability	0.5471	0.4546	0.5110	0.5471	0.5626	0.4870	0.6074	0.5408	0.5981	0.5089	1.0000	0.4461	0.6536
Physical Ability	0.2192	0.3201	0.2269	0.3476	0.4274	0.4872	0.3768	0.2182	0.3752	0.3820	0.4461	1.0000	0.3810
Integrity	0.5081	0.3846	0.3142	0.5883	0.3906	0.3260	0.7452	0.6920	0.5664	0.4135	0.6536	0.3810	1.0000

Figure 69.3.2 displays the eigenvalues. The first principal component explains about 50% of the total variance, the second principal component explains about 13.6%, and the third principal component explains about 7.7%. Note that the eigenvalues sum to the total variance. The eigenvalues indicate that three to five components provide a good summary of the data, with three components accounting for about 71.7% of the total variance and five components explaining about 82.7%. Subsequent components contribute less than 5% each.

When the ods graphics on statement is specified, PROC PRINCOMP produces the scree plot as shown in Figure 69.3.3 by default, which helps to visualize and choose the number of components. You can obtain more plots by specifying the PLOTS= option in the PROC PRINCOMP statement.

The "Scree Plot" on the left shows that the eigenvalue of the first component is approximately 6.5 and the eigenvalue of the second component is largely decreased to under 2.0. The "Variance Explained" plot on the right shows that you can explain a near 80% of total variance with the first four principal components.

Output 69.3.3 Scree Plot from the PRINCOMP Procedure

The first component reflects overall performance since the first eigenvector shows approximately equal loadings on all variables. The second eigenvector has high positive loadings on the variables Observational Skills and Willingness to Confront Problems but even higher negative loadings on the variables Interest in People and Interpersonal Sensitivity. This component seems to reflect the ability to take action, but it also reflects a lack of interpersonal skills. The third eigenvector has a very high positive loading on the variable Physical Ability and high negative loadings on the variables Problem Solving and Learning Ability. This component seems to reflect physical strength, but also shows poor learning and problem-solving skills.

In short, the three components represent the following:

First Component:

overall performance

Second Component:

smart, tough, and introverted

Third Component:

superior strength and average intellect

PROC PRINCOMP also produces other plots besides the scree plot, which are helpful while interpreting the results. The following statements request plots from the PRINCOMP procedure:

   proc princomp data=Jobratings(drop='Overall Rating'n)
                 plots(ncomp=3)=all n=5;
   run;
   ods graphics off;

PLOTS=ALL(NCOMP=3) in the PROC PRINCOMP statement requests all plots to be produced but limits the number of components to be plotted in the component pattern plots and the component score plots to three. The N=5 option sets the number of principal components to be computed to five. Besides a scree plot similar to the one shown before, the rest of plots are displayed in the following context.

Output 69.3.4 shows a matrix plot of component scores between the first five principal components. The histogram of each component is displayed in the diagonal element of the matrix. The histograms indicate that the first principal component is skewed to the left and the second principal component is slightly skewed to the right.

Output 69.3.4 Matrix Plot of Component Scores

The pairwise component pattern plots are shown in Output 69.3.5 to Output 69.3.7. The pattern plots show the following:

• All variables positively and evenly correlate with the first principal component (Output 69.3.5 and Output 69.3.6).

• The variables Observational Skills and Willingness to Confront Problems correlate highly with the second component, and the variables Interest in People and Interpersonal Sensitivity correlate highly but negatively with the second component (Output 69.3.5).

• The variable Physical Ability correlates highly with the third component, and the variables Problem Solving and Learning Ability correlate highly but negatively with the third component (Output 69.3.6).

• The variable Observational Skills, Willingness to Confront Problems, Interest in People, and Interpersonal Sensitivity correlate highly (either positively or negatively) with the second component, but all have very low correlations with the third component; the variables Physical Ability and Problem Solving correlate highly (either positively or negatively) with the third component, but both have very low correlations with the second component (Output 69.3.7).

Output 69.3.5 Pattern Plot of Component 2 by Component 1

Output 69.3.6 Pattern Plot of Component 3 by Component 1

Output 69.3.7 Pattern Plot of Component 3 by Component 2

Output 69.3.8 shows a component pattern profile. As it was shown in the pattern plots, the nearly horizontal profile from the first component indicates that the first component is mostly correlated evenly across all variables.

Output 69.3.8 Component Pattern Profile Plot from the PRINCOMP Procedure

Output 69.3.9 through Output 69.3.11 display the pairwise component score plots. Observation numbers are used as the plotting symbol.

Output 69.3.9 shows a scatter plot of the first and third components. Observations 82, 9, and 84 seem like outliers on the first component; Observations 16 and 59 can be potential outliers on the second component.

Output 69.3.9 Component 2 versus Component 1

Output 69.3.10 shows a scatter plot of the first and third components. Observations 82, 9, and 84 seem like outliers on the first component.

Output 69.3.10 Component 3 versus Component 1

Output 69.3.11 shows a scatter plot of the second and third components. Observations 95, 15, 16, and 59 can be potential outliers on the second component.

Output 69.3.11 Component 3 versus Component 2

Output 69.3.12 shows a scatter plot of the second and third components, displaying density with color. Color interpolation is based on the first component, such as in the statistical style, going from blue (minimum density) to tan (median density) and to red (maximum density).

Output 69.3.12 Component 3 versus Component 2, Painted by Component 1

Copyright © 2009 by SAS Institute Inc., Cary, NC, USA. All rights reserved.