Previous Page

|

Next Page

The PLAN Procedure

Example 65.7 Crossover Designs

In crossover experiments, the same experimental units or subjects are given multiple treatments in sequence, and the model for the response at any one period includes an effect for the treatment applied in the previous period. A good design for a crossover experiment will therefore be one which balances how often each treatment is preceded by each other treatment. Cox (1992) gives the following example of a balanced crossover experiment for paper production. In this experiment, the subjects are production runs of the mill, with the treatments being six different concentrations of pulp used in sequence. The following statements construct this design in a standard form, as shown in Output 65.7.1.

   proc plan;
      factors Run=6 ordered Period=6 ordered;
      treatments Treatment=6 cyclic (1 2 6 3 5 4);
   run;

Output 65.7.1 Crossover Design for Six Treatments

The PLAN Procedure

Plot Factors
Factor	Select	Levels	Order
Run	6	6	Ordered
Period	6	6	Ordered

Treatment Factors
Factor	Select	Levels	Order	Initial Block / Increment
Treatment	6	6	Cyclic	(1 2 6 3 5 4) / 1

Run	Period						Treatment
1	1	2	3	4	5	6	1	2	6	3	5	4
2	1	2	3	4	5	6	2	3	1	4	6	5
3	1	2	3	4	5	6	3	4	2	5	1	6
4	1	2	3	4	5	6	4	5	3	6	2	1
5	1	2	3	4	5	6	5	6	4	1	3	2
6	1	2	3	4	5	6	6	1	5	2	4	3

The construction method for this example is due to Williams (1949). The initial block for the treatment variable Treatment is defined thus for :

This general form serves to generate a balanced crossover design for treatments and subjects in periods when is even. When is odd, subjects are required, with the initial blocks

respectively.

In order to randomize Williams’ crossover designs, the following statements randomly permute the subjects and treatments:

   proc plan seed=136149876;
      factors Run=6 ordered Period=6 ordered / noprint;
      treatments Treatment=6 cyclic (1 2 6 3 5 4);
      output out=RandomizedDesign
         Run       random
         Treatment random
         ;

   /* 
   / Relabel Period to obtain the same design as in Cox (1992).
   /------------------------------------------------------------------*/
   data RandomizedDesign; set RandomizedDesign;
      Period = mod(Period+2,6)+1;
   run;

   proc sort data=RandomizedDesign;
      by Run Period;
   proc transpose data=RandomizedDesign out=tDesign(drop=_name_);
      by notsorted Run;
      var Treatment;
   data tDesign; set tDesign;
      rename COL1-COL6 = Period_1-Period_6;
   proc print data=tDesign noobs;
   run;

In the preceding, Run and Treatment are randomized by using the RANDOM option in the OUTPUT statement and new labels for Period are obtained in a subsequent DATA step. This Period relabeling is not necessary and might not be valid for Williams’ designs in general; it is used in this example only to match results with those of Cox (1992). The SORT and TRANSPOSE steps then prepare the design to be printed in a standard form, shown in Output 65.7.2.

The analysis of a crossover experiment requires for each observation a carryover variable whose values are the treatment in the preceding period. The following statements add such a variable to the randomized design constructed previously, displaying the values of the carryover variable for each run and period in Output 65.7.3.

   proc sort data=RandomizedDesign;
      by Run Period;
   data RandomizedDesign; set RandomizedDesign;
      by Run period;
      LagTreatment = lag(Treatment);
      if (first.Run) then LagTreatment = .;
   run;
      
   proc transpose data=RandomizedDesign out=tDesign(drop=_name_);
      by notsorted Run;
      var LagTreatment;
   data tDesign; set tDesign;
      rename COL1-COL6 = Period_1-Period_6;
   proc print data=tDesign noobs;
   run;

Of course, the carryover variable has no effect in the first period, which is why it is coded with a missing value in this case.

The experimental EFFECT statement in PROC GLIMMIX provides a convenient mechanism for incorporating the carryover variable into the analysis. The following statements first add the observed data to the design to create the Mills data set. Then PROC GLIMMIX is invoked and the carryover effect is defined as a multimember effect (having only a single member in this case) with the NOEFFECT option. The NOEFFECT option specifies that the columns for the carryover effect will be all zero when LagTreatment is missing. GLIMMIX is a very general procedure, so ODS is used to trim down the results to show only the parts that are usually of interest in crossover analysis. For more information about the EFFECTS statement in PROC GLIMMIX, see the section EFFECT Statement. The carryover analysis is shown in Output 65.7.4.

   data Responses;
      input Response @@;
   datalines;
   56.7 53.8 54.4 54.4 58.9 54.5 
   58.5 60.2 61.3 54.4 59.1 59.8
   55.7 60.7 56.7 59.9 56.6 59.6
   57.3 57.7 55.2 58.1 60.2 60.2
   53.7 57.1 59.2 58.9 58.9 59.6
   58.1 55.7 58.9 56.6 59.6 57.5
   ;
   data Mills;
      merge RandomizedDesign Responses;
   run;

   proc glimmix data=Mills outdesign=d;
      class Run Period Treatment LagTreatment;
      effect CarryOver = mm(LagTreatment / noeffect);
      model Response = Run Period Treatment CarryOver / htype=1;
      lsmeans Treatment CarryOver / obsmargins diff=anom e;
      ods select Tests1 LSMeans Diffs;
   run;

The Type I analysis of variance indicates that all effects are significant—in particular, both the direct and the carryover effects of the treatment. In the presence of carryover effects, the LS-means need to be defined with some care. The LS-means for treatments computed using balanced margins for the carryover effect are inestimable, so the OBSMARGINS option is specified in the LSMEANS statement in order to use the observed margins instead. The observed margins take the absence of a carryover effect in the first period into account. Note that the LS-means themselves of the carryover effect are inestimable, but their differences are estimable. The LS-means of the direct effect of the treatment and the ANOM differences for the LS-means of their carryover effect match the "adjusted direct effects" and "adjusted residual effects," respectively, of Cox (1992).

Copyright © 2009 by SAS Institute Inc., Cary, NC, USA. All rights reserved.