Example 57.3 Cluster Analysis with Significance Tests

This example uses artificial data containing two clusters. One cluster is from a circular bivariate normal distribution. The other is a ring-shaped cluster that completely surrounds the first cluster. Without significance tests, the ring is divided into several sample clusters for any degree of smoothing that yields reasonable density estimates. The JOIN= option puts the ring back together. Output 57.3.1 displays a short summary generated from the first PROC MODECLUS statement. Output 57.3.2 contains a series of tables produced from the second PROC MODECLUS statement. The lack of -value in the JOIN= option makes joining continue until only one cluster remains (see the description of the JOIN= option ). The cluster memberships are then plotted as displayed in Output 57.3.1 through Output 57.3.8.

The following statements produce Output 57.3.1 through Output 57.3.8:

      title  'Modeclus Analysis with the JOIN= option';
      title2 'A Normal Cluster Surrounded by a Ring Cluster';
   
   data circle; keep x y;
      c=1;
      do n=1 to 30;
         x=rannor(5);
         y=rannor(5);
         output;
      end;
   
      c=2;
      do n=1 to 300;
         x=rannor(5);
         y=rannor(5);
         z=rannor(5)+8;
         l=z/sqrt(x**2+y**2);
         x=x*l;
         y=y*l;
         output;
      end;

   proc modeclus data=circle m=1 r=1 to 3.5 by .25 join=20 short; run;

   proc modeclus data=circle m=1 r=2.5 join out=out; run;

   proc sgplot data=out noautolegend; 
      yaxis values=(-10 to 10 by 5);
      xaxis values=(-15 to 15 by 5);
      scatter y=y x=x / group=cluster Markerchar=cluster;
      by _NJOIN_;
   run;