Previous Page

|

Next Page

The MI Procedure

Example 54.10 Transforming to Normality

This example applies the MCMC method to the FitMiss data set in which the variable Oxygen is transformed. Assume that Oxygen is skewed and can be transformed to normality with a logarithmic transformation. The following statements invoke the MI procedure and specify the transformation. The TRANSFORM statement specifies the log transformation for Oxygen. Note that the values displayed for Oxygen in all of the results correspond to transformed values.

   proc mi data=FitMiss seed=32937921 mu0=50 10 180 out=outex10;
      transform log(Oxygen);
      mcmc chain=multiple displayinit;
      var Oxygen RunTime RunPulse;
   run;

The "Missing Data Patterns" table in Output 54.10.1 lists distinct missing data patterns with corresponding statistics for the FitMiss data. Note that the values of Oxygen shown in the tables are transformed values.

Output 54.10.1 Missing Data Patterns

The MI Procedure

Missing Data Patterns
Group	Oxygen	RunTime	RunPulse	Freq	Percent	Group Means
						Oxygen	RunTime	RunPulse
1	X	X	X	21	67.74	3.829760	10.809524	171.666667
2	X	X	.	4	12.90	3.851813	10.137500	.
3	X	.	.	3	9.68	3.955298	.	.
4	.	X	X	1	3.23	.	11.950000	176.000000
5	.	X	.	2	6.45	.	9.885000	.
Transformed Variables: Oxygen

The "Variable Transformations" table in Output 54.10.2 lists the variables that have been transformed.

The "Initial Parameter Estimates for MCMC" table in Output 54.10.3 displays the starting mean and covariance estimates used in the MCMC method.

Output 54.10.4 displays variance information from the multiple imputation.

Output 54.10.5 displays parameter estimates from the multiple imputation. Note that the parameter value of has also been transformed using the logarithmic transformation.

The following statements list the first 10 observations of the data set outmi in Output 54.10.6. Note that the values for Oxygen are in the original scale.

   proc print data=outex10(obs=10);
      title 'First 10 Observations of the Imputed Data Set';
   run;

Note that the results in Output 54.10.6 can also be produced from the following statements without using a TRANSFORM statement. A transformed value of log(50)=3.91202 is used in the MU0= option.

   data temp;
      set FitMiss;
      LogOxygen= log(Oxygen);
   run;
   proc mi data=temp seed=14337921 mu0=3.91202 10 180 out=outtemp;
      mcmc chain=multiple displayinit;
      var LogOxygen RunTime RunPulse;
   run;
   data outex10;
      set outtemp;
      Oxygen= exp(LogOxygen);
   run;

Copyright © 2009 by SAS Institute Inc., Cary, NC, USA. All rights reserved.