Example 51.4 Nominal Response Data: Generalized Logits Model

Over the course of one school year, third graders from three different schools are exposed to three different styles of mathematics instruction: a self-paced computer-learning style, a team approach, and a traditional class approach. The students are asked which style they prefer and their responses, classified by the type of program they are in (a regular school day versus a regular day supplemented with an afternoon school program), are displayed in Table 51.7. The data set is from Stokes, Davis, and Koch (2000), and is also analyzed in the section Generalized Logits Model of Chapter 28, The CATMOD Procedure.

The levels of the response variable (self, team, and class) have no essential ordering, so a logistic regression is performed on the generalized logits. The model to be fit is

where is the probability that a student in school and program prefers teaching style , , and style is the baseline style (in this case, class). There are separate sets of intercept parameters and regression parameters for each logit, and the vector is the set of explanatory variables for the th population. Thus, two logits are modeled for each school and program combination: the logit comparing self to class and the logit comparing team to class.

The following statements create the data set school and request the analysis. The LINK=GLOGIT option forms the generalized logits. The response variable option ORDER=DATA means that the response variable levels are ordered as they exist in the data set: self, team, and class; thus, the logits are formed by comparing self to class and by comparing team to class. The ODDSRATIO statement produces odds ratios in the presence of interactions, and the ODS GRAPHICS statements produces a graphical display of the requested odds ratios.

   data school;
      length Program $ 9;
      input School Program $ Style $ Count @@; 
      datalines; 
   1 regular   self 10  1 regular   team 17  1 regular   class 26
   1 afternoon self  5  1 afternoon team 12  1 afternoon class 50 
   2 regular   self 21  2 regular   team 17  2 regular   class 26
   2 afternoon self 16  2 afternoon team 12  2 afternoon class 36 
   3 regular   self 15  3 regular   team 15  3 regular   class 16
   3 afternoon self 12  3 afternoon team 12  3 afternoon class 20 
   ; 

   ods graphics on;
   proc logistic data=school;
      freq Count; 
      class School Program(ref=first);
      model Style(order=data)=School Program School*Program / link=glogit;
      oddsratio program;
   run;
   ods graphics off;

Summary information about the model, the response variable, and the classification variables are displayed in Output 51.4.1.