Example 48.1 Motorette Failure

This example fits a Weibull model and a lognormal model to the example given in Kalbfleisch and Prentice (1980, p. 5). An output data set called models is specified to contain the parameter estimates. By default, the natural log of the variable time is used by the procedure as the response. After this log transformation, the Weibull model is fit using the extreme-value baseline distribution, and the lognormal is fit using the normal baseline distribution.

Since the extreme-value and normal distributions do not contain any shape parameters, the variable SHAPE1 is missing in the models data set. An additional output data set, out, is created that contains the predicted quantiles and their standard errors for values of the covariate corresponding to temp=130 and temp=150. This is done with the control variable, which is set to 1 for only two observations.

Using the standard error estimates obtained from the output data set, approximate 90% confidence limits for the predicted quantities are then created in a subsequent DATA step for the log response. The logs of the predicted values are obtained because the values of the P= variable in the OUT= data set are in the same units as the original response variable, time. The standard errors of the quantiles of log(time) are approximated (using a Taylor series approximation) by the standard deviation of time divided by the mean value of time. These confidence limits are then converted back to the original scale by the exponential function.

The following statements produce Output 48.1.1:

   title 'Motorette Failures With Operating Temperature as a Covariate';
   data motors;
      input time censor temp @@;
      if _N_=1 then
         do;
            temp=130;
            time=.;
            control=1;
            z=1000/(273.2+temp);
            output;
            temp=150;
            time=.;
            control=1;
            z=1000/(273.2+temp);
            output;
         end;
      if temp>150;
      control=0;
      z=1000/(273.2+temp);
      output;
      datalines;
   8064 0 150 8064 0 150 8064 0 150 8064 0 150 8064 0 150
   8064 0 150 8064 0 150 8064 0 150 8064 0 150 8064 0 150
   1764 1 170 2772 1 170 3444 1 170 3542 1 170 3780 1 170
   4860 1 170 5196 1 170 5448 0 170 5448 0 170 5448 0 170
    408 1 190  408 1 190 1344 1 190 1344 1 190 1440 1 190
   1680 0 190 1680 0 190 1680 0 190 1680 0 190 1680 0 190
    408 1 220  408 1 220  504 1 220  504 1 220  504 1 220
    528 0 220  528 0 220  528 0 220  528 0 220  528 0 220
   ;
   run;

   proc print data=motors;
   run;

The following statements produce Output 48.1.2 and Output 48.1.3:

   proc lifereg data=motors outest=modela covout;
      a: model time*censor(0)=z;
         output out=outa quantiles=.1 .5 .9 std=std p=predtime
            control=control;
   run;

   proc lifereg data=motors outest=modelb covout;
      b: model time*censor(0)=z / dist=lnormal;
         output out=outb quantiles=.1 .5 .9 std=std p=predtime
            control=control;
   run;