Previous Page

|

Next Page

The FACTOR Procedure

Example 33.2 Principal Factor Analysis

This example uses the data presented in Example 33.1, and performs a principal factor analysis with squared multiple correlations for the prior communality estimates (PRIORS=SMC). Unlike Example 33.1, which analyzes the principal components, the current analysis is based on a common factor model.

To help determine whether the common factor model is appropriate, Kaiser’s measure of sampling adequacy (MSA) is requested, and the residual correlations and partial correlations are computed (RESIDUAL).

The ROTATE= and REORDER options are specified to enhance factor interpretability. The ROTATE=PROMAX option produces an orthogonal varimax prerotation (default) followed by an oblique Procrustes rotation, and the REORDER option reorders the variables according to their largest factor loadings. An OUTSTAT= data set is created by PROC FACTOR and displayed in Output 33.2.12.

PROC FACTOR can produce high-quality graphs that are very useful to interpret the factor solutions. To request these graphs, you must first enable ODS Graphics by specifying the ods graphics on statement, as shown in the following code. All ODS graphs in PROC FACTOR are requested with the PLOTS= option. In this example, a scree plot is requested to help you determine the number of factors. Loading plots for the initial unrotated solution, prerotated (varimax) solution, and promax-rotated solution are also requested to help you visualize the patterns of factor loadings in various stages.

   
   ods graphics on;
   
   title3 'Principal Factor Analysis with Promax Rotation';
   proc factor data=SocioEconomics 
      priors=smc msa residual 
      rotate=promax reorder
      outstat=fact_all 
      plots=(scree initloadings preloadings loadings);
   run;
   
   ods graphics off;
   

Output 33.2.1 displays the results of the principal factor extraction.

Output 33.2.1 Principal Factor Analysis

Five Socioeconomic Variables

See Page 14 of Harman: Modern Factor Analysis, 3rd Ed

Principal Factor Analysis with Promax Rotation

The FACTOR Procedure

Initial Factor Method: Principal Factors

Partial Correlations Controlling all other Variables
	Population	School	Employment	Services	HouseValue
Population	1.00000	-0.54465	0.97083	0.09612	0.15871
School	-0.54465	1.00000	0.54373	0.04996	0.64717
Employment	0.97083	0.54373	1.00000	0.06689	-0.25572
Services	0.09612	0.04996	0.06689	1.00000	0.59415
HouseValue	0.15871	0.64717	-0.25572	0.59415	1.00000

Kaiser's Measure of Sampling Adequacy: Overall MSA = 0.57536759
Population	School	Employment	Services	HouseValue
0.47207897	0.55158839	0.48851137	0.80664365	0.61281377

Prior Communality Estimates: SMC
Population	School	Employment	Services	HouseValue
0.96859160	0.82228514	0.96918082	0.78572440	0.84701921

Eigenvalues of the Reduced Correlation Matrix: Total = 4.39280116 Average = 0.87856023
	Eigenvalue	Difference	Proportion	Cumulative
1	2.73430084	1.01823217	0.6225	0.6225
2	1.71606867	1.67650586	0.3907	1.0131
3	0.03956281	0.06408626	0.0090	1.0221
4	-.02452345	0.04808427	-0.0056	1.0165
5	-.07260772		-0.0165	1.0000

If the data are appropriate for the common factor model, the partial correlations controlling the other variables should be small compared to the original correlations. The partial correlation between the variables School and HouseValue, for example, is , slightly less than the original correlation of . The partial correlation between Population and School is , which is much larger in absolute value than the original correlation; this is an indication of trouble. Kaiser’s MSA is a summary, for each variable and for all variables together, of how much smaller the partial correlations are than the original correlations. Values of or are considered good, while MSAs below are unacceptable. The variables Population, School, and Employment have very poor MSAs. Only the Services variable has a good MSA. The overall MSA of is sufficiently poor that additional variables should be included in the analysis to better define the common factors. A commonly used rule is that there should be at least three variables per factor. In the following analysis, there seems to be two common factors in these data, so more variables are needed for a reliable analysis.

The SMCs are all fairly large; hence, the factor loadings do not differ greatly from those in the principal component analysis.

The eigenvalues in Output 33.2.1 show clearly that two common factors are present. The first two largest positive eigenvalues account for of the common variance. This is possible because the reduced correlation matrix, in general, is not necessarily positive definite, and negative eigenvalues for the matrix are possible. These cumulative proportions of common variance explained by factors are plotted in the right panel of Output 33.2.2, which shows that the curve flattens out essentially after the second factor. Showing in the left panel of Output 33.2.2 is the scree plot, which displays a sharp bend at the third eigenvalue, reinforcing the conclusion that two common factors are present.

Output 33.2.2 Scree and Variance Explained Plots

As displayed in Output 33.2.3, the principal factor pattern is similar to the principal component pattern seen in Example 33.1. For example, the variable Services has the largest loading on the first factor, and the Population variable has the smallest. The variables Population and Employment have large positive loadings on the second factor, and the HouseValue and School variables have large negative loadings.

The final communality estimates are all fairly close to the priors. Only the communality for the variable HouseValue increased appreciably, from 0.847 to 0.885. Nearly 100% of the common variance is accounted for. The residual correlations (off-diagonal elements) are low, the largest being 0.03 (Output 33.2.4). The partial correlations are not quite as impressive, since the uniqueness values are also rather small. These results indicate that the SMCs are good but not quite optimal communality estimates.

As displayed in Output 33.2.5, the unrotated factor pattern reveals two tight clusters of variables, with the variables HouseValue and School at the negative end of Factor2 axis and the variables Employment and Population at the positive end. The Services variable is in between but closer to the HouseValue and School variables. A good rotation would put the reference axes through the two clusters.

Output 33.2.5 Unrotated Factor Pattern Plot

Output 33.2.6 and Output 33.2.7 display the results of the varimax rotation. This rotation puts one axis through the variables HouseValue and School but misses the Population and Employment variables slightly.

Output 33.2.7 Varimax-Rotated Factor Loadings

An alternative to the scatter plot of factor loadings as shown in Output 33.2.7 is the so-called vector plot of loadings. The vector plot is requested with the suboption VECTOR in the PLOTS= option. For example:

   plots=preloadings(vector)

This will generate the vector plot of loadings as shown in Output 33.2.8.

Output 33.2.8 Varimax-Rotated Factor Loadings: Vector Plot

The results of oblique promax rotation are shown in Output 33.2.9 and Output 33.2.10. The corresponding plot of factor loadings is shown in Output 33.2.11.

Output 33.2.11 Promax-Rotated Factor Loadings

As shown in Output 33.2.11, the promax solution places an axis through the variables Population and Employment but misses the HouseValue and School variables. Since an independent-cluster solution would be possible if it were not for the variable Services, a Harris-Kaiser rotation weighted by the Cureton-Mulaik technique could be used. Rather than reanalyze the entire problem with the Harris-Kaiser rotation, you can simply use the preceding results stored in the OUTSTAT= data set.

First, the OUTSTAT= data set is printed using this code:

   
   title3 'Factor Output Data Set';
   proc print data=fact_all;
   run;
   

The output data set is displayed in Output 33.2.12.

This output data set can be used for Harris-Kaiser rotation by deleting observations with _TYPE_=’PATTERN’ and _TYPE_=’FCORR’, which are for the promax-rotated factors, and changing _TYPE_=’UNROTATE’ to _TYPE_=’PATTERN’. In this way, the initial orthogonal factor pattern matrix is saved in the observations with _TYPE_=’PATTERN’. The following factor analysis will then read in the factor pattern in the fact2 data set as an initial factor solution, which will then be rotated by the Harris-Kaiser rotation with Cureton-Mulaik weights.

The following statements produce Output 33.2.13:

   data fact2(type=factor);
      set fact_all;
      if _TYPE_ in('PATTERN' 'FCORR') then delete;
      if _TYPE_='UNROTATE' then _TYPE_='PATTERN';

   ods graphics on;
   
   title3 'Harris-Kaiser Rotation with Cureton-Mulaik Weights';
   proc factor rotate=hk norm=weight reorder
        plots=loadings;
   run;
   
   ods graphics off;

The results of the Harris-Kaiser rotation are displayed in Output 33.2.13.

A plot of the rotated loadings is shown in Output 33.2.14.

Output 33.2.14 Factor Pattern with Harris-Kaiser Rotation

In the results of the Harris-Kaiser rotation, the variable Services receives a small weight, and the axes are placed as desired.

Copyright © 2009 by SAS Institute Inc., Cary, NC, USA. All rights reserved.