Previous Page

|

Next Page

The CANDISC Procedure

Example 27.1 Analysis of Iris Data With PROC CANDISC

The iris data published by Fisher (1936) have been widely used for examples in discriminant analysis and cluster analysis. The sepal length, sepal width, petal length, and petal width are measured in millimeters on 50 iris specimens from each of three species: Iris setosa, I. versicolor, and I. virginica.

This example is a canonical discriminant analysis that creates an output data set containing scores on the canonical variables and plots the canonical variables. The following statements produce Output 27.1.1 through Output 27.1.6:

   title 'Fisher (1936) Iris Data';
   
   proc format;
      value specname
         1='Setosa    '
         2='Versicolor'
         3='Virginica ';
   run;
   
   data iris;
      input SepalLength SepalWidth PetalLength PetalWidth
            Species @@;
      format Species specname.;
      label SepalLength='Sepal Length in mm.'
            SepalWidth ='Sepal Width in mm.'
            PetalLength='Petal Length in mm.'
            PetalWidth ='Petal Width in mm.';
      symbol = put(Species, specname10.);
      datalines;
   50 33 14 02 1 64 28 56 22 3 65 28 46 15 2 67 31 56 24 3
   63 28 51 15 3 46 34 14 03 1 69 31 51 23 3 62 22 45 15 2
   
   ... more lines ...   

   63 33 60 25 3 53 37 15 02 1
   ;

   proc candisc data=iris out=outcan distance anova;
      class Species;
      var SepalLength SepalWidth PetalLength PetalWidth;
   run;

PROC CANDISC first displays information about the observations and the classes in the data set in Output 27.1.1.

Output 27.1.1 Iris Data: Summary Information

Fisher (1936) Iris Data

The CANDISC Procedure

Total Sample Size	150	DF Total	149
Variables	4	DF Within Classes	147
Classes	3	DF Between Classes	2

Number of Observations Read	150
Number of Observations Used	150

Class Level Information
Species	Variable Name	Frequency	Weight	Proportion
Setosa	Setosa	50	50.0000	0.333333
Versicolor	Versicolor	50	50.0000	0.333333
Virginica	Virginica	50	50.0000	0.333333

The DISTANCE option in the PROC CANDISC statement displays squared Mahalanobis distances between class means. Results from the DISTANCE option are shown in Output 27.1.2.

The ANOVA option uses univariate statistics to test the hypothesis that the class means are equal. The resulting R-square values (see Output 27.1.3) range from 0.4008 for SepalWidth to 0.9414 for PetalLength, and each variable is significant at the 0.0001 level. The multivariate test for differences between the classes (which is displayed by default) is also significant at the 0.0001 level; you would expect this from the highly significant univariate test results.

The R square between Can1 and the class variable, 0.969872, is much larger than the corresponding R square for Can2, 0.222027. This is displayed in Output 27.1.4.

The raw canonical coefficients (shown in Output 27.1.6) for the first canonical variable, Can1, show that the classes differ most widely on the linear combination of the centered variables: .

The TEMPLATE and SGRENDER procedures within ODS Graphics are invoked to create a plot of the first two canonical variables. For general information about ODS Graphics, see Chapter 21, Statistical Graphics Using ODS. The following statements produce Output 27.1.8:

   proc template;
      define statgraph scatter;
         begingraph;
            entrytitle 'Fisher (1936) Iris Data';
            layout overlayequated / equatetype=fit
               xaxisopts=(label='Canonical Variable 1')
               yaxisopts=(label='Canonical Variable 2');
               scatterplot x=Can1 y=Can2 / group=species name='iris';
               layout gridded / autoalign=(topleft);
                  discretelegend 'iris' / border=false opaque=false;
                  endlayout;
            endlayout;
         endgraph;
      end;
   run;
   
   proc sgrender data=outcan template=scatter;
   run;

Output 27.1.8 Iris Data: Plot of First Two Canonical Variables

The plot of canonical variables in Output 27.1.8 shows that of the two canonical variables, Can1 has more discriminatory power.

Copyright © 2009 by SAS Institute Inc., Cary, NC, USA. All rights reserved.