Although latent variable or factor scores are unobserved, they can be estimated after you fit your model using PROC CALIS. Latent variable or factor scores are estimated as linear combinations of observed variables, weighted by the latent variable (factor) score regression coefficients.

To display the latent variable (factor) score regression coefficients in the PROC CALIS output, you can use the PLATCOV option. You can also save these coefficients in an output data set by using the OUTSTAT= option. These coefficients can then be used by the SCORE procedure to compute the latent variable (factor) scores.

To summarize, do the following if you need to compute latent variable (factor) scores for each observation by using the SCORE procedure:

• Create an output data set with the OUTSTAT= option in the PROC CALIS statement.

• Use the SCORE procedure with both the raw data and the OUTSTAT= data set.

For example, you can use the following statements to compute the latent variable (factor) scores, which are stored in the OUT= data set named "scores":

   proc calis data=raw outstat=ostat;
      lineqs
         v1 = a1 f1 + e1,                      
         v2 = a2 f1 + e2,                      
         v3 = a3 f1 + e3;
      std                      
         f1 = 1.,
         e1-e3 = evar1-evar3;
   run;
   
   proc score data=raw score=ostat out=scores;
   run;

If you analyze a correlation or covariance matrix in PROC CALIS, the original raw data must be used in the PROC SCORE procedure, as shown in the following statements:

   proc corr data=raw out=correl;
   run;
   
   proc calis data=correl outstat=ostat;
      lineqs
         v1 = a1 f1 + e1,                      
         v2 = a2 f1 + e2,                      
         v3 = a3 f1 + e3;
      std                      
         f1 = 1.,
         e1-e3 = evar1-evar3;
   run;
   
   proc score data=raw score=ostat out=scores;
   run;

For a more detailed example, see Example 76.1 in Chapter 76, The SCORE Procedure. Although the FACTOR procedure is used in that example, it is also applicable to the CALIS procedure. Essentially, an OUTSTAT= data set containing the latent variable or factor score regression coefficients, either from PROC FACTOR or PROC CALIS, is used with the raw data in the SCORE procedure to create the latent variable or factor scores.