SCHART Statement: SHEWHART Procedure

Note: See Computing Average Run Lengths for s Charts in the SAS/QC Sample Library.

This example illustrates how you can compute the average run length of an s chart. The data used here are the power measurements in the data set Turbine, which is introduced in Creating Standard Deviation Charts from Raw Data.

The in-control average run length of a Shewhart chart is , where p is the probability that a single point exceeds its control limits. Since this probability is saved as the value of the variable _ALPHA_ in an OUTLIMITS= data set, you can compute ARL for an s chart as follows:

title 'Average In-Control Run Length';
proc shewhart data=Turbine;
   schart KWatts*Day / outlimits=Turblim nochart;

data ARLcomp;
   keep _var_ _sigmas_ _alpha_ arl;
   set Turblim;
   arl = 1 / _alpha_;
run;

The data set ARLcomp is listed in Output 17.30.1, which shows that the ARL is equal to 358.

To compute out-of-control average run lengths, define f as the slippage factor for the process standard deviation , where f > 1. In other words, the “shifted” standard deviation to be detected by the chart is . The following statements compute the ARL as a function of f:

data ARLshift;
   keep f f_std p arl_f;
   set Turblim;
   df = _limitn_ - 1;
   do f = 1 to 1.5 by 0.05;
      f_std = f * _stddev_;
      low   = df * ( _lcls_ / f_std )**2;
      upp   = df * ( _ucls_ / f_std )**2;
      p     = probchi( low, df ) + 1 - probchi( upp, df );
      arl_f = 1 / p;
      output;
   end;
run;

The data set ARLshift is listed in Output 17.30.2. For example, on average, 53 samples are required to detect a ten percent increase in (a shifted standard deviation of approximately 219). The computations use the fact that has a distribution with degrees of freedom, assuming that the measurements are normally distributed.