Example 7.4 Fold-Over Design

[See FACTEX10 in the SAS/QC Sample Library]Folding over a fractional factorial design is a method for breaking the links between aliased effects in a design. Folding over a design means adding a new fraction identical to the original fraction except that the signs of all the factors are reversed. The new fraction is called a fold-over design. Combining a fold-over design with the original fraction converts a design of odd resolution into a design of resolution . ¹ For example, folding over a resolution 3 design yields a resolution 4 design. You can use the FACTEX procedure to construct the original design fraction and a DATA step to generate the fold-over design.

Consider a fraction of a factorial design with factors A, B, C, D, E, and F. The following statements construct a design:

proc factex;
   factors A B C D E F;
   size fraction=8;          
   model resolution=3;        
   examine aliasing;
   output out=Original;
run;

title 'Original Design';
proc print data=Original;
run;

The option FRACTION=8 of the SIZE statement specifies a fraction of a complete factorial—that is, 8 (=). The design, which is saved in the data set Original, is displayed in Output 7.4.1.

Output 7.4.1 A Design

Original Design

Obs	A	B	C	D	E	F
1	-1	-1	-1	-1	1	1
2	-1	-1	1	1	-1	-1
3	-1	1	-1	1	-1	1
4	-1	1	1	-1	1	-1
5	1	-1	-1	1	1	-1
6	1	-1	1	-1	-1	1
7	1	1	-1	-1	-1	-1
8	1	1	1	1	1	1

Since the design is of resolution 3, the alias structure in Output 7.4.2 indicates that all the main effects are confounded with the two-factor interactions.

Output 7.4.2 Alias Structure for a Design

The FACTEX Procedure

Aliasing Structure
A = C*F = D*E
B = C*E = D*F
C = A*F = B*E
D = A*E = B*F
E = A*D = B*C
F = A*C = B*D
A*B = C*D = E*F

To separate the main effects and the two-factor interactions, augment the original design with a 1/8 fraction in which the signs of all the factors are reversed. The combined design (original design and fold-over design) of resolution 4 breaks the alias links between the main effects and the two-factor interactions. The fold-over design can be created by using the following DATA step:

data FoldOver;             
   set Original;          
   A=-A; B=-B; C=-C;
   D=-D; E=-E; F=-F;
run;
title 'Fold-Over Design';
proc print data=FoldOver;
run;

Here, the DATA step creates the fold-over fraction by reversing the signs of the values of the factors in the original fraction. The fold-over design is displayed in Output 7.4.3.

Output 7.4.3 A Design with Signs Reversed

Fold-Over Design

Obs	A	B	C	D	E	F
1	1	1	1	1	-1	-1
2	1	1	-1	-1	1	1
3	1	-1	1	-1	1	-1
4	1	-1	-1	1	-1	1
5	-1	1	1	-1	-1	1
6	-1	1	-1	1	1	-1
7	-1	-1	1	1	1	1
8	-1	-1	-1	-1	-1	-1