Introduction to the FACTEX Procedure

Example of a Half-Fraction Factorial Design

[See FACTEX3 in the SAS/QC Sample Library]Often you do not have the resources for a full factorial design. In this case, a fractional factorial design is a reasonable alternative, provided that the effects of interest can be estimated.

Box, Hunter, and Hunter (1978) describe a fractional factorial design for studying a chemical reaction to determine what percentage of the chemicals responded in a reactor. The researchers identified the following five treatment factors that were thought to influence the percentage of reactant:

• the feed rate of the chemicals (FeedRate), ranging from 10 to 15 liters per minute

• the percentage of the catalyst (Catalyst), ranging from 1% to 2%

• the agitation rate of the reactor (AgitRate), ranging from 100 to 120 revolutions per minute

• the temperature (Temperature), ranging from 140 to 180 degrees Celsius

• the concentration (Concentration), ranging from 3% to 6%

The complete factorial design requires 32 runs, but the experimenter can afford only 16 runs.

Suppose that all main effects and two-factor interactions are to be estimated. An appropriate design for this situation is a design of resolution 5 (denoted as ), in which no main effect or two-factor interaction is aliased with any other main effect or two-factor interaction but in which two-factor interactions are aliased with three-factor interactions. This design loses the ability to estimate interactions between three or more factors, but this is usually not a serious loss. For more information about resolution, see the section Resolution.

You can use the following statements to construct a 16-run factorial design that has five factors and resolution 5:

proc factex;
   factors FeedRate Catalyst AgitRate Temperature Concentration;
   size design=16;
   model resolution=5;
   output out=Reaction FeedRate      nvals=(10 15)
                       Catalyst      nvals=(1 2)
                       AgitRate      nvals=(100 120)
                       Temperature   nvals=(140 180)
                       Concentration nvals=(3 6);
proc print;
run;

The design saved in the Reaction data set is listed in Figure 7.5.

Figure 7.5 Half-Fraction of a Design for Reactors

Obs	FeedRate	Catalyst	AgitRate	Temperature	Concentration
1	10	1	100	140	6
2	10	1	100	180	3
3	10	1	120	140	3
4	10	1	120	180	6
5	10	2	100	140	3
6	10	2	100	180	6
7	10	2	120	140	6
8	10	2	120	180	3
9	15	1	100	140	3
10	15	1	100	180	6
11	15	1	120	140	6
12	15	1	120	180	3
13	15	2	100	140	6
14	15	2	100	180	3
15	15	2	120	140	3
16	15	2	120	180	6

The use of a half-fraction causes some interaction terms to be confounded with each other. You can use the EXAMINE statement with the ALIASING option to determine which interaction terms are aliased, as follows:

proc factex;
   factors FeedRate Catalyst AgitRate Temperature Concentration;
   size design=16;
   model resolution=5;
   examine aliasing;
run;

The alias structure summarizes the estimability of all main effects and two- and three-factor interactions. Figure 7.6 indicates that each of the three-factor interactions is confounded with a two-factor interaction. Thus, if a particular three-factor interaction is believed to be significant, the aliased two-factor interaction cannot be estimated with this half-fraction design.

When you submit the preceding statements, the following message is displayed in the SAS log:

NOTE: Design has 16 runs, resolution = 5.

This message confirms that the design exists. If you specify a factorial design that does not exist, an error message is displayed in the SAS log. For instance, suppose that you replaced the MODEL statement in the preceding example with the following statement:

model resolution=6;

Since the maximum resolution of a design is 5, the following message appears in the SAS log:

ERROR: No such design exists.

In general, it is good practice to check the SAS log to see if a design exists.