Example 13.12 Specifying Standard Values for the Process Mean and Standard Deviation

[See SHWIREX2 in the SAS/QC Sample Library]By default, the IRCHART statement estimates the process mean () and standard deviation () from the data, as in the previous example. However, there are applications in which known (standard) values and are available for these parameters based on previous experience or extensive sampling.

For example, suppose that the manufacturing process described in the previous example produces engines whose weights are normally distributed with a mean of 1250 and a standard deviation of 12. The following statements create individual measurements and moving range charts based on these values:

symbol v = dot h = .8;
title 'Specifying Standard Process Mean and Standard Deviation';
proc shewhart data=Engines;
   irchart Weight*ID /
       mu0      = 1250
       sigma0   = 12
       xsymbol  = mu0;
run;

The charts are shown in Output 13.12.1. The MU0= option and SIGMA0= option specify and . The XSYMBOL= option specifies the label for the central line on the individual measurements chart, and the keyword MU0 requests a label indicating that the central line is based on a standard value.

Output 13.12.1 Specifying Standard Values with MU0= and SIGMA0=

You can also specify and as the values of the variables _MEAN_ and _STDDEV_ in a LIMITS= data set. For example, the following statements create a LIMITS= data set with the standard values specified in the preceding IRCHART statement:

data Enginelimits;
   length _var_ _subgrp_ _type_ $8;
   _var_    = 'Weight';
   _subgrp_ = 'id';
   _limitn_ = 2;
   _type_   = 'STANDARD';
   _mean_   = 1250;
   _stddev_ = 12;
run;

The variables _VAR_ and _SUBGRP_ are required, and their values must match the process and subgroup-variable, respectively, specified in the IRCHART statement. The bookkeeping variable _TYPE_ is not required, but it is recommended to indicate that the variables _MEAN_ and _STDDEV_ provide standard values rather than estimated values. See LIMITS= Data Set for details.

The following statements read Enginelimits as a LIMITS= data set:

proc shewhart data=Engines limits=Enginelimits;
   irchart Weight*ID / xsymbol=mu0;
run;

The resulting charts (not shown here) are identical to those shown in Output 13.12.1.