Nelson (2002) and Doganaksoy and Nelson (1998) show how the difference of MCFs from two samples can be used to compare the populations from which they are drawn. The RELIABILITY procedure provides Doganaksoy and Nelson’s confidence intervals for the pointwise difference of the two MCFs, which can be used to assess whether the difference is statistically significant.

Doganaksoy and Nelson (1998) give an example of two samples of locomotives with braking grids from two different production batches. Figure 12.35 contains a listing of the data. The variable ID is a unique identifier for individual locomotives. The variable Days provides the locomotive age in days. The variable Value is 1 if the age corresponds to a valve seat replacement or -1 if the age corresponds to the locomotive’s latest age (the current end of its history). The variable Sample is a group variable that identifies the grid production batch.

   data grids;                                                    
      if _N_ < 40 then sample = 'Sample1';                       
      else sample = 'Sample2';                                   
      input ID$ days value @@;                                   
      datalines;                                                     
   S1-01 462  1    S1-01 730 -1    S1-02 364  1    S1-02 391  1  
   S1-02 548  1    S1-02 724 -1    S1-03 302  1    S1-03 444  1  
   S1-03 500  1    S1-03 730 -1    S1-04 250  1    S1-04 730 -1  
   S1-05 500  1    S1-05 724 -1    S1-06  88  1    S1-06 724 -1  
   S1-07 272  1    S1-07 421  1    S1-07 552  1    S1-07 625  1  
   S1-07 719 -1    S1-08 481  1    S1-08 710 -1    S1-09 431  1  
   S1-09 710 -1    S1-10 367  1    S1-10 710 -1    S1-11 635  1  
   S1-11 650  1    S1-11 708 -1    S1-12 402  1    S1-12 700 -1  
   S1-13  33  1    S1-13 687 -1    S1-14 287  1    S1-14 687 -1  
   S1-15 317  1    S1-15 498  1    S1-15 657 -1    S2-01 203  1  
   S2-01 211  1    S2-01 277  1    S2-01 373  1    S2-01 511 -1  
   S2-02 293  1    S2-02 503 -1    S2-03 173  1    S2-03 470 -1  
   S2-04 242  1    S2-04 464 -1    S2-05  39  1    S2-05 464 -1  
   S2-06  91  1    S2-06 462 -1    S2-07 119  1    S2-07 148  1  
   S2-07 306  1    S2-07 461 -1    S2-08 382  1    S2-08 460 -1  
   S2-09 250  1    S2-09 434 -1    S2-10 192  1    S2-10 448 -1  
   S2-11 369  1    S2-11 448 -1    S2-12  22  1    S2-12 447 -1  
   S2-13  54  1    S2-13 441 -1    S2-14 194  1    S2-14 432 -1  
   S2-15  61  1    S2-15 419 -1    S2-16  19  1    S2-16 185  1  
   S2-16 419 -1    S2-17 187  1    S2-17 416 -1    S2-18  93  1  
   S2-18 205  1    S2-18 264  1    S2-18 415 -1                  
   ;                                                             

The following statements request the Nelson (1995) nonparametric estimate and confidence limits for the difference of the MCF functions shown in Figure 12.36 for the braking grids:

proc reliability data=grids;
   unitid ID;
   mcfplot days*value(-1) = sample / mcfdiff;
run;

The MCFPLOT statement requests a plot of each MCF estimate as a function of age (provided by Days), and it specifies that the end of history for each system is identified by Value equal to -1. The variable Sample identifies the two samples of braking grids. The option MCFDIFF requests that the difference between the MCFs of the two groups given in the variable Sample be computed and plotted. Confidence limits for the MCF difference are also computed and plotted. The UNITID statement specifies that the variable Id uniquely identify each system.

Figure 12.36 shows the plot of the MCF difference function and pointwise 95% confidence intervals. Since the pointwise confidence limits do not include zero for some system ages, the difference between the two populations is statistically significant.

A listing of the tabular output is shown in Figure 12.37. It contains a summary of the repair data for the two samples, estimates, standard errors, and confidence intervals for the MCF difference.

Figure 12.36 Mean Cumulative Function Difference