Example 7.15 Fractional Factorial Split-Plot Designs

In split-plot designs, not all factor levels can change from plot to plot. In the simplest split-plot structure, runs are grouped into wholeplots; certain factors are applied to all plots in the wholeplot, while others are applied to individual plots within a wholeplot. The two types of factors are termed wholeplot factors and subplot factors. Split-plot designs are very common in chemical and process industries, where factors of interest are often applied at different stages of the production process and the final measurements of interest are made on the finished product. In this case, the different stages of production may give rise to multiple wholeplot effects.

Suppose you are designing an experiment to measure six factors that affect characteristics of metal wires sheathed with a certain material. Three of the factors (W1, W2, W3) apply to how the wires themselves are made, and the other three (S1, S2, S3) apply to the sheathing material. You propose to first prepare 8 different batches of wire, making 2 wires from each batch, and then to prepare the sheathing material for each wire individually. This describes a standard split-plot experiment with batches of wires forming whole plots and sheathed wires forming subplots. The following code constructs a resolution 4 design for this experiment, specifying the Wire unit effect in the BLOCKS statement and then in the UNITEFFECT statement specifying that W1, W2, and W3 should be constant within Wire and that S1, S2, and S3 should change within Wire. The resulting design is printed, sorted by Wire.

proc factex;
   factors W1 W2 W3 
           S1 S2 S3;          
   size design=16;
   blocks units=(Wire=8);
   model r=4;
   uniteffect Wire / whole=(W1 W2 W3) 
                     sub  =(S1 S2 S3);
   output out=WireExperiment1;
run;
proc sort data=WireExperiment1;
   by Wire W1-W3 S1-S3;
run;
proc print data=WireExperiment1;
run;

The final design is listed in Output 7.15.1. Notice that the factors W1, W2, and W3 are constant within Wire, while S1, S2, and S3 change within Wire.

To see why the Wire factors are constant within wire and the sheath factors change, examine the confounding rules for the design. The following code produces the table of confounding rules listed in Output 7.15.2.

proc factex;
   factors W1 W2 W3
           S1 S2 S3;
   size design=16;
   blocks units=(Wire=8);
   model r=4;
   uniteffect Wire / whole=(W1 W2 W3) 
                     sub  =(S1 S2 S3);
   examine confounding;
run;