Previous Page

|

Next Page

The ANOM Procedure

Example 4.7 ANOM for Cell Means in Presence of Interaction

[See ANMXEX6 in the SAS/QC Sample Library]This example illustrates the use of analysis of means in an experiment with two factors where an interaction effect is present. The following data set cleaninginteract is a modified version of the data set Cleaning, which includes an interaction effect for position and depth.

Consider the following data set cleaninginteract:

data cleaninginteract;  
   do position = 1 to 5;
      do depth = 1 to 3;
         do rep = 1 to 2;
            input concentration @@;
            output;
         end; 
      end;
   end;
   datalines;
   15 16 15 14 19 5
   15 16 14 14 0  1
   19 15 16 16 11 8
   18 16 24 23 8  14
   15 12 23 24 8  11
   ;  
run;

The following statements use PROC GLM to test for an interaction:

proc glm data=cleaninginteract;
   class position depth;
   model concentration = position depth position*depth;
run;

The analysis of variance results in Output 4.7.1 indicate a significant interaction between position and depth.

Output 4.7.1 GLM Results

ANOM for Effect of Position

The GLM Procedure

 

Dependent Variable: concentration

Source	DF	Sum of Squares	Mean Square	F Value	Pr > F
Model	14	885.666667	63.261905	6.66	0.0004
Error	15	142.500000	9.500000
Corrected Total	29	1028.166667

R-Square	Coeff Var	Root MSE	concentration Mean
0.861404	21.75676	3.082207	14.16667

Source	DF	Type I SS	Mean Square	F Value	Pr > F
position	4	169.0000000	42.2500000	4.45	0.0144
depth	2	515.4666667	257.7333333	27.13	<.0001
position*depth	8	201.2000000	25.1500000	2.65	0.0496

Since an interaction effect is present, an appropriate way to analyze the data is to create an ANOM chart for the cell means.

In order to create the chart you first need to compute the cell means and a new group variable which designates the cells. The following statements use PROC MEANS for this purpose.

proc means data=cleaninginteract n mean std;
   class position depth; 
   var concentration;
   types position*depth;
   output out=cellmeans mean=concentrationX std=concentrationS;
run;
data cellmeans; set cellmeans;
   rename _FREQ_ = concentrationN;
   pos = put(position, z1.);
   dep = put(depth, z1.);
   cell  = cat('P',pos, 'D', dep);
   drop _TYPE_ pos dep;
run;

The cell means are stored in the data set cellmeans shown in Output 4.7.2:

The data set cellmeans has the structure of a SUMMARY= input data set for the ANOM procedure. For details concerning a SUMMARY= data set, see the section Creating ANOM Charts for Means from Group Summary Data.

The following statements use cellmeans to create the ANOM chart for the cell means using SUMMARY= option:

title "ANOM for Cell Means of Position and Depth";
proc ANOM summary = cellmeans;
   xchart concentration * cell / turnhlabels;      
   label concentrationX = 'Mean of Concentration';
   label cell           = 'Cell';
run;

The chart is shown in Output 4.7.3:

Output 4.7.3 ANOM for Cell Means of Position and Depth

The chart shows that the cell means for P2D3, P4D2, and P5D2 are significantly different from the average concentration level.

Copyright © SAS Institute, Inc. All Rights Reserved.