Previous Page | Next Page

The ANOM Procedure

Saving Decision Limits

[See ANMXLIM in the SAS/QC Sample Library]You can save the decision limits for an ANOM chart, together with the parameters used to compute the limits, in a SAS data set.

The following statements read measurements from the data set LabelDeviations (see the section Creating ANOM Charts for Means from Response Values) and save the decision limits displayed in Figure 4.3.3 in a data set named LabelLimits:

proc anom data=LabelDeviations;
   xchart Deviation*Position / outlimits=LabelLimits
                               nochart;
run;

The OUTLIMITS= option names the data set containing the decision limits, and the NOCHART option suppresses the display of the chart. The data set LabelLimits is listed in Figure 4.3.7.

Output 4.3.7 The Data Set LabelLimits Containing Decision Limit Information
Decision Limits for Labler Position Deviations

_VAR_ _GROUP_ _TYPE_ _LIMITN_ _ALPHA_ _LDLX_ _MEAN_ _UDLX_ _MSE_ _DFE_ _LIMITK_
Deviation Position ESTIMATE 10 0.05 -.009875609 .009996667 0.029869 .000643787 54 6

The data set LabelLimits contains one observation with the limits for response Deviation. The values of _LDLX_ and _UDLX_ are the lower and upper decision limits for the means, and the value of _MEAN_ is the weighted average of the group means, which is represented by the central line.

The values of _MEAN_, _MSE_, _DFE_, _LIMITN_, _LIMITK_, and _ALPHA_ are the parameters used to compute the decision limits as described in the section Constructing ANOM Charts for Means. The value of _MSE_ is the mean square error, and the value of _DFE_ is the associated degrees of freedom. The value of _LIMITN_ is the nominal sample size () associated with the decision limits, the value of _LIMITK_ is the number of groups (), and the value of _ALPHA_ is the value of the significance level (). The variables _VAR_ and _GROUP_ are bookkeeping variables that save the response and group-variable. The variable _TYPE_ is a bookkeeping variable that indicates whether the values of _MEAN_ and _MSE_ are estimates computed from the data or standard (known) values specified with procedure options. In most applications, the value of _TYPE_ will be 'ESTIMATE.'

[See ANMXTAB in the SAS/QC Sample Library]You can create an output data set containing both decision limits and group summary statistics with the OUTTABLE= option, as illustrated by the following statements:

proc anom data=LabelDeviations;
   xchart Deviation*Position / outtable=LabelTab
                               nochart;
run;

The data set LabelTab is listed in Figure 4.3.8.

Output 4.3.8 The Data Set LabelTab
Summary Statistics and Decision Limits

_VAR_ Position _ALPHA_ _LIMITN_ _SUBN_ _LDLX_ _SUBX_ _MEAN_ _UDLX_ _EXLIM_
Deviation 1 0.05 10 10 -.009875609 -0.02234 .009996667 0.029869 LOWER
Deviation 2 0.05 10 10 -.009875609 0.01625 .009996667 0.029869  
Deviation 3 0.05 10 10 -.009875609 0.00604 .009996667 0.029869  
Deviation 4 0.05 10 10 -.009875609 0.06473 .009996667 0.029869 UPPER
Deviation 5 0.05 10 10 -.009875609 0.00813 .009996667 0.029869  
Deviation 6 0.05 10 10 -.009875609 -0.01283 .009996667 0.029869 LOWER

This data set contains one observation for each group sample. The variables _SUBX_ and _SUBN_ contain the group means and sample sizes. The variables _LDLX_ and _UDLX_ contain the lower and upper decision limits, and the variable _MEAN_ contains the central line. The variables _VAR_ and Position contain the response name and values of the group-variable, respectively. For more information, see the section OUTTABLE= Data Set.

An OUTTABLE= data set can be read later as a TABLE= data set. For example, the following statements read LabelTab and display an ANOM chart (not shown here) identical to the chart in Figure 4.3.3:

title 'Analysis of Label Deviations';
proc anom table=LabelTab;
   xchart Deviation*Position;
label _SUBX_ = 'Mean Deviation from Center (mm)';
run;

Because the ANOM procedure simply displays the information in a TABLE= data set, you can use TABLE= data sets to create specialized ANOM charts.

For more information, see the section TABLE= Data Set.

Previous Page | Next Page | Top of Page