# The CORR Procedure

### Example 2.6 Computing Cronbach’s Coefficient Alpha

The following statements create the data set `Fish1` from the `Fish` data set used in Chapter 110: The STEPDISC Procedure in SAS/STAT 14.2 User's Guide. The cubic root of the weight (`Weight3`) is computed as a one-dimensional measure of the size of a fish.

```*------------------- Fish Measurement Data ----------------------*
| The data set contains 35 fish from the species Bream caught in |
| Finland's lake Laengelmavesi with the following measurements:  |
| Weight   (in grams)                                            |
| Length3  (length from the nose to the end of its tail, in cm)  |
| HtPct    (max height, as percentage of Length3)                |
| WidthPct (max width,  as percentage of Length3)                |
*----------------------------------------------------------------*;
data Fish1 (drop=HtPct WidthPct);
title 'Fish Measurement Data';
input Weight Length3 HtPct WidthPct @@;
Weight3= Weight**(1/3);
Height=HtPct*Length3/100;
Width=WidthPct*Length3/100;
datalines;
242.0 30.0 38.4 13.4     290.0 31.2 40.0 13.8
340.0 31.1 39.8 15.1     363.0 33.5 38.0 13.3
430.0 34.0 36.6 15.1     450.0 34.7 39.2 14.2
500.0 34.5 41.1 15.3     390.0 35.0 36.2 13.4
450.0 35.1 39.9 13.8     500.0 36.2 39.3 13.7
475.0 36.2 39.4 14.1     500.0 36.2 39.7 13.3
500.0 36.4 37.8 12.0        .  37.3 37.3 13.6
600.0 37.2 40.2 13.9     600.0 37.2 41.5 15.0
700.0 38.3 38.8 13.8     700.0 38.5 38.8 13.5
610.0 38.6 40.5 13.3     650.0 38.7 37.4 14.8
575.0 39.5 38.3 14.1     685.0 39.2 40.8 13.7
620.0 39.7 39.1 13.3     680.0 40.6 38.1 15.1
700.0 40.5 40.1 13.8     725.0 40.9 40.0 14.8
720.0 40.6 40.3 15.0     714.0 41.5 39.8 14.1
850.0 41.6 40.6 14.9    1000.0 42.6 44.5 15.5
920.0 44.1 40.9 14.3     955.0 44.0 41.1 14.3
925.0 45.3 41.4 14.9     975.0 45.9 40.6 14.7
950.0 46.5 37.9 13.7
;
```

The following statements request a correlation analysis and compute Cronbach’s coefficient alpha for the variables `Weight3`, `Length3`, `Height`, and `Width`:

```ods graphics on;
title 'Fish Measurement Data';
proc corr data=fish1 nomiss alpha plots=matrix;
var Weight3 Length3 Height Width;
run;
```

The ALPHA option computes Cronbach’s coefficient alpha for the analysis variables.

The "Simple Statistics" table in Output 2.6.1 displays univariate descriptive statistics for each analysis variable.

Output 2.6.1: Simple Statistics

 Fish Measurement Data

The CORR Procedure

4 Variables: Weight3 Length3 Height Width

Simple Statistics
Variable N Mean Std Dev Sum Minimum Maximum
Weight3 34 8.44751 0.97574 287.21524 6.23168 10.00000
Length3 34 38.38529 4.21628 1305 30.00000 46.50000
Height 34 15.22057 1.98159 517.49950 11.52000 18.95700
Width 34 5.43805 0.72967 184.89370 4.02000 6.74970

The "Pearson Correlation Coefficients" table in Output 2.6.2 displays Pearson correlation statistics for pairs of analysis variables.

Output 2.6.2: Pearson Correlation Coefficients

Pearson Correlation Coefficients, N = 34
Prob > |r| under H0: Rho=0
Weight3 Length3 Height Width
Weight3
 1.00000
 0.96523 <.0001
 0.96261 <.0001
 0.92789 <.0001
Length3
 0.96523 <.0001
 1.00000
 0.95492 <.0001
 0.92171 <.0001
Height
 0.96261 <.0001
 0.95492 <.0001
 1.00000
 0.92632 <.0001
Width
 0.92789 <.0001
 0.92171 <.0001
 0.92632 <.0001
 1.00000

Since the data set contains only one species of fish, all the variables are highly correlated. Using the ALPHA option, the CORR procedure computes Cronbach’s coefficient alpha in Output 2.6.3. The Cronbach’s coefficient alpha is a lower bound for the reliability coefficient for the raw variables and the standardized variables. Positive correlation is needed for the alpha coefficient because variables measure a common entity.

Output 2.6.3: Cronbach’s Coefficient Alpha

Cronbach Coefficient Alpha
Variables Alpha
Raw 0.822134
Standardized 0.985145

Because the variances of some variables vary widely, you should use the standardized score to estimate reliability. The overall standardized Cronbach’s coefficient alpha of 0.985145 provides an acceptable lower bound for the reliability coefficient. This is much greater than the suggested value of 0.70 given by Nunnally and Bernstein (1994).

The standardized alpha coefficient provides information about how each variable reflects the reliability of the scale with standardized variables. If the standardized alpha decreases after removing a variable from the construct, then this variable is strongly correlated with other variables in the scale. On the other hand, if the standardized alpha increases after removing a variable from the construct, then removing this variable from the scale makes the construct more reliable. The "Cronbach Coefficient Alpha with Deleted Variables" table in Output 2.6.4 does not show significant increase or decrease in the standardized alpha coefficients. See the section Cronbach’s Coefficient Alpha for more information about Cronbach’s alpha.

Output 2.6.4: Cronbach’s Coefficient Alpha with Deleted Variables

Cronbach Coefficient Alpha with Deleted Variable
Deleted
Variable
Raw Variables Standardized Variables
Correlation
with Total
Alpha Correlation
with Total
Alpha
Weight3 0.975379 0.783365 0.973464 0.977103
Length3 0.967602 0.881987 0.967177 0.978783
Height 0.964715 0.655098 0.968079 0.978542
Width 0.934635 0.824069 0.937599 0.986626