Example 3.7 Sequential Scheduling of Projects

Suppose the schedule displayed in Output 3.6.4 is not acceptable; you want the first book to be finished as soon as possible and do not want resources to be claimed by the second book at the cost of the first book. One way to accomplish this is to enable activities related to the second book to be split whenever the first book demands a resource currently in use by the second book. If you do not want activities to be split, you can still accomplish your goal by sequential scheduling. The structure of the input and output data sets enables you to schedule the two subprojects sequentially.

This example illustrates the sequential scheduling of subprojects 'Book 1' and 'Book 2.' The following program first schedules the subproject 'Book 1' using the resources available. The resulting schedule is displayed in Output 3.7.1. The Usage data set bk1out is also displayed in Output 3.7.1.

/* Schedule the higher priority project first */
proc cpm data=book1 resin=resource
         out=bk1schd resout=bk1out
         date='1jan03'd interval=week;
   act      act;
   dur      dur;
   succ     succ;
   resource editor artist / per=avdate avp rcp;
   id       id;
   run;

The Usage data set produced by PROC CPM has two variables, Aeditor and Aartist, showing the availability of the editor and the artist on each day of the project, after scheduling subproject 'Book 1.' This data set is used to create the data set remres, listing the remaining resources available, which is then used as the Resource input data set for scheduling the subproject 'Book 2.' The following program shows the DATA step and the invocation of PROC CPM.

The schedule for publishing 'Book 2' is displayed in Output 3.7.2. The Usage data set bk2out is also displayed in Output 3.7.2. Note that this method of scheduling has ensured that 'Book 1' is not delayed; however, the entire project has been delayed by two more weeks, resulting in a total delay of six weeks.

/* Construct the Resource availability data set */
/* with proper resource names                   */
data remres;
   set bk1out;
   avdate=_time_;
   editor=aeditor;
   artist=aartist;
   keep avdate editor artist;
   format avdate date7.;
   run;

proc cpm data=book2 resin=remres
         out=bk2schd resout=bk2out
         date='1jan03'd interval=week;
   act      act;
   dur      dur;
   succ     succ;
   resource editor artist / per=avdate avp rcp;
   id       id;
   run;