The Quadratic Programming Solver: Portfolio Optimization :: SAS/OR(R) 9.22 User's Guide: Mathematical Programming

The Quadratic Programming Solver

Example 14.2 Portfolio Optimization

Consider a portfolio optimization example. The two competing goals of investment are (1) long-term growth of capital and (2) low risk. A good portfolio grows steadily without wild fluctuations in value. The Markowitz model is an optimization model for balancing the return and risk of a portfolio. The decision variables are the amounts invested in each asset. The objective is to minimize the variance of the portfolio’s total return, subject to the constraints that (1) the expected growth of the portfolio reaches at least some target level and (2) you do not invest more capital than you have.

Let $\text{[math]}$ be the amount invested in each asset, $\text{[math]}$ be the amount of capital you have, $\text{[math]}$ be the random vector of asset returns over some period, and $\text{[math]}$ be the expected value of $\text{[math]}$ . Let $\text{[math]}$ be the minimum growth you hope to obtain, and $\text{[math]}$ be the covariance matrix of $\text{[math]}$ . The objective function is $\text{[math]}$ , which can be equivalently denoted as $\text{[math]}$ .

Assume, for example, $\text{[math]}$ = 4. Let $\text{[math]}$ = 10,000, $\text{[math]}$ = 1000, $\text{[math]}$ , and

$\text{[math]}$

The QP formulation can be written as

$\text{[math]}$

Use the following SAS code to solve the problem:

/* example 2: portfolio optimization */
proc optmodel;
   /* let x1, x2, x3, x4 be the amount invested in each asset */
   var x{1..4} >= 0;
   
   num coeff{1..4, 1..4} = [0.08 -.05 -.05 -.05
                            -.05 0.16 -.02 -.02
                            -.05 -.02 0.35 0.06
                            -.05 -.02 0.06 0.35];
   num r{1..4}=[0.05 -.20 0.15 0.30];
   
   /* minimize the variance of the portfolio's total return */
   minimize f = sum{i in 1..4, j in 1..4}coeff[i,j]*x[i]*x[j];
   
   /* subject to the following constraints */
   con BUDGET: sum{i in 1..4}x[i] <= 10000;
   con GROWTH: sum{i in 1..4}r[i]*x[i] >= 1000;
   
   solve with qp;
   
   /* print the optimal solution */
   print x;

The summaries and the optimal solution are shown in Output 14.2.1.

Output 14.2.1 Portfolio Optimization

The OPTMODEL Procedure

Problem Summary
Objective Sense	Minimization
Objective Function	f
Objective Type	Quadratic

Number of Variables	4
Bounded Above	0
Bounded Below	4
Bounded Below and Above	0
Free	0
Fixed	0

Number of Constraints	2
Linear LE (<=)	1
Linear EQ (=)	0
Linear GE (>=)	1
Linear Range	0

Solution Summary
Solver	QP
Objective Function	f
Solution Status	Optimal
Objective Value	2232313.8093
Iterations	7

Primal Infeasibility	0
Dual Infeasibility	0
Bound Infeasibility	0
Duality Gap	4.4734294E-7
Complementarity	0.9932470284

[1]	x
1	3.4529E+03
2	7.0389E-04
3	1.0688E+03
4	2.2235E+03

Thus, the minimum variance portfolio that earns an expected return of at least 10% is $\text{[math]}$ = 3452, $\text{[math]}$ = 0, $\text{[math]}$ = 1068, $\text{[math]}$ . Asset 2 gets nothing because its expected return is $\text{[math]}$ 20% and its covariance with the other assets is not sufficiently negative for it to bring any diversification benefits. What if we drop the nonnegativity assumption?

Financially, that means you are allowed to short-sell—i.e., sell low-mean-return assets and use the proceeds to invest in high-mean-return assets. In other words, you put a negative portfolio weight in low-mean assets and "more than 100%" in high-mean assets.

To solve the portfolio optimization problem with the short-sale option, continue to submit the following SAS code:

   /* example 2: portfolio optimization with short-sale option */
   /* dropping nonnegativity assumption */
   for {i in 1..4} x[i].lb=-x[i].ub;
   
   solve with qp;
   
   /* print the optimal solution */
   print x;
quit;

You can see in the optimal solution displayed in Output 14.2.2 that the decision variable $\text{[math]}$ , denoting Asset 2, is equal to $\text{[math]}$ 1563.61, which means short sale of that asset.

Output 14.2.2 Portfolio Optimization with Short-Sale Option

The OPTMODEL Procedure

Solution Summary
Solver	QP
Objective Function	f
Solution Status	Optimal
Objective Value	1907123.1559
Iterations	6

Primal Infeasibility	0
Dual Infeasibility	0
Bound Infeasibility	0
Duality Gap	6.1120033E-7
Complementarity	1.1690054718

[1]	x
1	1684.35
2	-1563.61
3	682.51
4	1668.95

Note: This procedure is experimental.

Top of Page