Example 6.8 Nonarc Variables in the Side Constraints

Notice in DUALOUT=dual5 from Example 6.7 the FACT2 MAR GIZMO constraint (observation 24) has a _VALUE_ of 3470, which is not equal to the _RHS_ of this constraint. Not all of the 3750 chips that can be supplied to factory 2 for March production are used. It is suggested that all the possible chips be obtained in March and those not used be saved for April production. Because chips must be kept in an air-controlled environment, it costs 1 dollar to store each chip purchased in March until April. The maximum number of chips that can be stored in this environment at each factory is 150. In addition, a search of the parts inventory at factory 1 turned up 15 chips available for their March production.

Nonarc variables are used in the side constraints that handle the limitations of supply of Gizmo chips. A nonarc variable called "f1 unused chips" has as a value the number of chips that are not used at factory 1 in March. Another nonarc variable, "f2 unused chips", has as a value the number of chips that are not used at factory 2 in March. "f1 chips from mar" has as a value the number of chips left over from March used for production at factory 1 in April. Similarly, "f2 chips from mar" has as a value the number of chips left over from March used for April production at factory 2 in April. The last two nonarc variables have objective function coefficients of 1 and upper bounds of 150. The Gizmo side constraints are

  3*prod f1 19 mar + 4*prod f1 25 mar + f1 unused chips = 2615
  3*prod f2 19 apl + 4*prod f2 25 apl + f2 unused chips = 3750
  3*prod f1 19 apl + 4*prod f1 25 apl - f1 chips from mar = 2600
  3*prod f2 19 apl + 4*prod f2 25 apl - f2 chips from mar = 3750
  f1 unused chips + f2 unused chips -
  f1 chips from mar - f2 chips from mar >= 0

The last side constraint states that the number of chips not used in March is not less than the number of chips left over from March and used in April. Here, this constraint is called CHIP LEFTOVER.

The following SAS code creates a new data set containing constraint data. It seems that most of the constraints are now equalities, so you specify DEFCONTYPE=EQ in the PROC NETFLOW statements from now on and provide constraint type data for constraints that are not "equal to" type, using the default TYPEOBS value _TYPE_ as the _COLUMN_ variable value to indicate observations that contain constraint type data. Also, from now on, the default RHSOBS value is used.

title 'Nonarc Variables in the Side Constraints';
title2 'Production Planning/Inventory/Distribution';
data con6;
  input _column_ &$17. _row_ &$15. _coef_ ;
  datalines;
prod f1 19 mar     FACT1 MAR GIZMO  3
prod f1 25 mar     FACT1 MAR GIZMO  4
f1 unused chips    FACT1 MAR GIZMO  1
_RHS_              FACT1 MAR GIZMO  2615
prod f2 19 mar     FACT2 MAR GIZMO  3
prod f2 25 mar     FACT2 MAR GIZMO  4
f2 unused chips    FACT2 MAR GIZMO  1
_RHS_              FACT2 MAR GIZMO  3750
prod f1 19 apl     FACT1 APL GIZMO  3
prod f1 25 apl     FACT1 APL GIZMO  4
f1 chips from mar  FACT1 APL GIZMO  -1
_RHS_              FACT1 APL GIZMO  2600
prod f2 19 apl     FACT2 APL GIZMO  3
prod f2 25 apl     FACT2 APL GIZMO  4
f2 chips from mar  FACT2 APL GIZMO  -1
_RHS_              FACT2 APL GIZMO  3750
f1 unused chips    CHIP LEFTOVER    1
f2 unused chips    CHIP LEFTOVER    1
f1 chips from mar  CHIP LEFTOVER    -1
f2 chips from mar  CHIP LEFTOVER    -1
_TYPE_             CHIP LEFTOVER    1
back f1 19 apl     TOTAL BACKORDER  1
back f1 25 apl     TOTAL BACKORDER  1
back f2 19 apl     TOTAL BACKORDER  1
back f2 25 apl     TOTAL BACKORDER  1
back f1 19 may     TOTAL BACKORDER  1
back f1 25 may     TOTAL BACKORDER  1
back f2 19 may     TOTAL BACKORDER  1
back f2 25 may     TOTAL BACKORDER  1
_TYPE_             TOTAL BACKORDER  -1
_RHS_              TOTAL BACKORDER  50
;

The nonarc variables "f1 chips from mar" and "f2 chips from mar" have objective function coefficients of 1 and upper bounds of 150. There are various ways in which this information can be furnished to PROC NETFLOW. If there were a TYPE list variable in the CONDATA= data set, observations could be in the form

  _COLUMN_           _TYPE_  _ROW_ _COEF_
  f1 chips from mar  objfn     .       1
  f1 chips from mar  upperbd   .     150
  f2 chips from mar  objfn     .       1
  f2 chips from mar  upperbd   .     150

It is desirable to assign ID list variable values to all the nonarc variables:

data arc6;
  set con5;
  drop oldcost oldfc oldflow _flow_ _fcost_ _status_ _rcost_;
data arc6_b;
  length key_id $10;
  input _name_ &$17. _cost_ _capac_ factory key_id $ ;
  datalines;
f1 unused chips    .   . 1 chips
f2 unused chips    .   . 2 chips
f1 chips from mar  1 150 1 chips
f2 chips from mar  1 150 2 chips
;

proc append force nowarn
   base=arc6 data=arc6_b;
run;

proc netflow
   nodedata=node0 arcdata=arc6
   condata=con6 defcontype=eq sparsecondata
   dualout=dual7 conout=con7;
run;

print nonarcs/short;

The following messages appear on the SAS log:

The output in Output 6.8.1 is produced by

The optimal solution data sets, CONOUT=CON7 in Output 6.8.2 and DUALOUT=DUAL7 in Output 6.8.4 follow.

 
  proc print data=con7;
     sum _fcost_;
  proc print data=dual7;

The optimal value of the nonarc variable "f2 unused chips" is 280. This means that although there are 3750 chips that can be used at factory 2 in March, only 3470 are used. As the optimal value of "f1 unused chips" is zero, all chips available for production in March at factory 1 are used. The nonarc variable "f2 chips from mar" also has zero optimal value. This means that the April production at factory 2 does not need any chips that could have been held in inventory since March. However, the nonarc variable "f1 chips from mar" has value of 20. Thus, 3490 chips should be ordered for factory 2 in March. Twenty of these chips should be held in inventory until April, then sent to factory 1.