NOTPUNCT Function

Searches a character string for a character that is not a punctuation character, and returns the first position at which that character is found.

Category: Character
Restriction: I18N Level 2 functions are designed for use with SBCS, DBCS, and MBCS (UTF8).

Syntax

NOTPUNCT(string <,start> )

Required Argument

string

is the character constant, variable, or expression to search.

Optional Argument

start

is an optional numeric constant, variable, or expression with an integer value that specifies the position at which the search should start and the direction in which to search.

Details

The results of the NOTPUNCT function depend directly on the translation table that is in effect (see TRANTAB= System Option in SAS National Language Support (NLS): Reference Guide) and indirectly on the ENCODING and the LOCALE system options.
The NOTPUNCT function searches a string for the first occurrence of a character that is not a punctuation character. If such a character is found, NOTPUNCT returns the position in the string of that character. If no such character is found, NOTPUNCT returns a value of 0.
If you use only one argument, NOTPUNCT begins the search at the beginning of the string. If you use two arguments, the absolute value of the second argument, start, specifies the position at which to begin the search. The direction in which to search is determined in the following way:
  • If the value of start is positive, the search proceeds to the right.
  • If the value of start is negative, the search proceeds to the left.
  • If the value of start is less than the negative length of the string, the search begins at the end of the string.
NOTPUNCT returns a value of zero when one of the following is true:
  • The character that you are searching for is not found.
  • The value of start is greater than the length of the string.
  • The value of start = 0.

Comparisons

The NOTPUNCT function searches a character string for a character that is not a punctuation character. The ANYPUNCT function searches a character string for a punctuation character.

Examples

Example 1: Searching a String for Characters That Are Not Punctuation Characters

The following example uses the NOTPUNCT function to search a string for characters that are not punctuation characters.
data _null_;    
   string='Next = _n_ + 12E3;';  
   j=0;  
   do until(j=0);  
      j=notpunct(string,j+1);  
      if j=0 then put +3 "That's all";  
      else do;          
         c=substr(string,j,1);  
         put +3 j= c=;  
      end; 
   end;
run;
The following lines are written to the SAS log:
   j=1 c=N
   j=2 c=e
   j=3 c=x
   j=4 c=t
   j=5 c= 
   j=7 c= 
   j=9 c=n
   j=11 c= 
   j=13 c= 
   j=14 c=1
   j=15 c=2
   j=16 c=E
   j=17 c=3
   That's all

Example 2: Identifying Control Characters by Using the NOTPUNCT Function

You can execute the following program to show the control characters that are identified by the NOTPUNCT function.
data test; 
do dec=0 to 255;
   byte=byte(dec);
   hex=put(dec,hex2.);
   notpunct=notpunct(byte);
   output;
 end;
 proc print data=test;
 run;

See Also

Functions: