Language Reference

Consider the differential equation

The following statements attempt to find the solution at :

/* Define the integrand */
start fun(t,y);
   v = -t*y;
   return(v);
finish;

/* Call ODE */
c   = 0.5;
t   = {0 1};
h   = {1E-12 1 1E-5};
call ode(r1, "FUN", c, t, h);
print r1[format=E21.14];

In this case, the integration is carried out over to give the value of y at . The optional parameter eps has not been specified, so it is internally set to 1E4. Also, the optional parameter "jacobian" has not been specified, so finite-difference methods are used to estimate the Jacobian. The accuracy of the answer can be increased by specifying eps. For example, set EPS=1E7, as follows:

call ode(r2, "FUN", c, t, h) eps=1E-7;
print r2[format =E21.14];

Compare this value to and observe that the result is correct through the sixth decimal digit and has an error relative to 1 that is .

If the solution was desired at 1 and 2 with an accuracy of 1E7, you would use the following statements:

t   = {0 1 2};
h   = {1E-12 1 1E-5};
call ode(r3, "FUN", c, t, h) eps=1E-7;
print r3[format=E21.14];

Note that r3 contains the solution at in the first column and at in the second column.

Now consider the smoothness of the forcing function . For the purpose of estimating errors, adaptive methods require some degree of smoothness in the function . If this smoothness is not present in over the interior and including the left endpoint of the subinterval, the reported result does not have the desired accuracy. The function must be at least continuous. If the function does not meet this requirement, you should specify the discontinuity as an intermediate point. For example, consider the differential equation

To find the solution at , use the following statements:

/* Define the integrand */
start fun(t,y);
    if t < 1 then v = t;
    else v = .5*t*t;
    return(v);
finish;

c   = 0;
t   = {0 2};
h   = {1E-12 1. 1E-5};
call ode(r1, "FUN", c, t, h) eps=1E-12;
print r1[format=E21.14];

In the preceding case, the integration is carried out over a single interval, . The optional parameter eps is specified to be 1E12. The optional parameter "jacobian" is not specified, so finite-difference methods are used to estimate the Jacobian.

Note that the value of r1 does not have the required accuracy (it should contain a 12 decimal-place representation of 5/3), although no error message is produced. The reason is that the function is not continuous at the point . Even the lowest-order method cannot produce a local reliable error estimate near the point of discontinuity. To avoid this problem, you can create subintervals so that the integration is carried out first over and then over . The following statements implement this method:

c   = 0;
t   = {0 1 2};
h   = {1E-12 1 1E-5};
call ode(r2, "FUN", c, t, h) eps=1E-12;
print r2[format=E21.14];

The variable r2 contains the solutions at both and , and the errors are of the specified order. Although there is no interest in the solution at the point , the advantage of specifying subintervals with no discontinuities is that the function is infinitely differentiable in each subinterval.

When is continuous, the ODE subroutine can compute the integration to the specified precision, even if the function is defined piecewise. Consider the differential equation

The following statements finds the solution at . Since the function is continuous, the requirements for error control are satisfied.

/* Define the integrand */
start fun(t,y);
    if t < 1 then v = t;
    else v = t*t;
    return(v);
finish;

c   = 0.5;
t   = {0 2};
h   = {1E-12 1 1E-5};
call ode(r, "FUN", c, t, h) eps=1E-12;
print r[format=E21.14];

This example compares the ODE subroutine to an eigenvalue decomposition for stiff-linear systems. In the problem

where A is a symmetric constant matrix, the solution can be written in terms of the eigenvalue decomposition as

where U is the matrix of eigenvectors and D is a diagonal matrix with the eigenvalues on its diagonal.

The following statements produce two solutions, one by using the ODE subroutine and the other by using the eigenvalue decomposition:

/* Define the integrand */
start fun(t,x) global(a,count);
   count = count+1;
   v = a*x;
   return(v);
finish;

/* Define the Jacobian */
start jac(t,x) global(a);
   return(a);
finish;

a = {-1000 -1 -2 -3,
        -1 -2  3 -1,
        -2  3 -4 -3,
        -3 -1 -3 -5 };

count = 0;
t = {0 1 2};
h = {1E-12  1 1E-5};
eps = 1E-9;
c = {1, 0, 0, 0 };
call ode(z, "FUN", c, t, h)  eps=eps j="JAC";
print z[format=E21.14];
print count;

/* Do the eigenvalue decomposition */
start eval(t) global(d,u,c);
   v = u*diag(exp(d*t))*u`*c;
   return(v);
finish;

call eigen(d,u,a);
free z1;
do i = 1 to nrow(t)*ncol(t)-1;
   z1 = z1 || (eval(t[i+1]));
end;
print z1[format=E21.14];

Is this an result? Note that for the problem

with the 1E6 result, the ODE subroutine should attempt to maintain an accuracy of 1E9 relative to 1. Therefore, the 1E6 result should have almost three correct decimal places. At , the first component of z is 6.58597048842310E06, while its more accurate value is 6.58580950203220E06, showing an error.

The ODE subroutine can fail for problems with unusual qualitative properties, such as finite escape time in the interval of integration (that is, the solution goes towards infinity at some finite time). In such cases, try testing with different subintervals and different levels of accuracy to gain some qualitative information about the behavior of the solution of the differential equation.