Controlling ODS Search Paths

Before you submit your modified style definition, you should consider whether this style is for your use only or whether you want to share it with others. Your decision determines where you store the style.

The ODS PATH statement determines the read and write locations for SAS item store templates.

ods path show;

Current ODS PATH list is:
1. SASUSER.TEMPLAT(UPDATE)
2. SASHELP.TMPLMST(READ)

By default, modified templates are stored in SASUSER.TEMPLAT, which is appropriate for your personal use. To store a modified template in this default location, you will see the following note in the SAS Log after submitting the PROC TEMPLATE code:

NOTE: STYLE 'Styles.SerifStatistical' has been saved to:
SASUSER.TEMPLAT

You can then run your program with the new style:

ods rtf style=serifStatistical ;
ods graphics on;
proc reg data=sashelp.class;
  model weight=height;
quit;
ods rtf close;

To save a modified template to a location where others can access it, you cannot use the default SASUSER.TEMPLAT location. Rather, store the template in a different library, using the ODS PATH statement to set the search path:

libname common "u:\ODS_templates";

ods path common.dept(update)
         sasuser.templat(update)
         sashelp.tmpmst(read);

This ODS PATH statement establishes a new search path. The first item store (common.dept) can be updated and will contain the new template (Styles.SerifStatistical). It is important to include SASHELP.TMPLMST in the path because the inherited parent style (Styles.Default) is in SASHELP.

After setting this new search path, you will see the following note in the SAS Log when you submit the PROC TEMPLATE code:

NOTE: STYLE 'Styles.SerifStatistical' has been saved to:
COMMON.DEPT

For others to access this style definition, everyone needs to precede their programs with the following code:

libname common "u:\ODS_templates" access=readonly;
ods path sasuser.templat(update)
         common.dept(read)
         sashelp.tmpmst(read);

They can then run their program with the new style:

ods rtf style=serifStatistical;
ods graphics on;
proc reg data=sashelp.class;
  model weight=height;
quit;
ods rtf close;

The following figure shows a table and graph from the output.