Controlling Where Your Output Is Stored

With the exception of the ODS HTML destination, by default, ODS output is stored in the current SAS output directory, which is displayed on the status bar of the SAS window. A special case applies to the ODS HTML destination. When you start a new SAS session, the ODS HTML destination is open by default. This initial instance of the ODS HTML destination sends its output to the SAS WORK directory instead of the current directory. To find the path to the WORK directory, in the SAS Explorer window, you can right-click Work in the Libraries folder, and then select Properties from the pop-up menu.

When you close the initial instance of the ODS HTML destination and open a new instance, the output of the new instance and all other instances that are opened in that SAS session is sent to the current directory instead of the WORK directory. It is important that you keep this behavior in mind so that you can locate your ODS output, especially when using the ODS HTML destination.

You can use the FILE= option in your ODS statement to specify where your ODS output files are stored. For the HTML destination, you can also use the PATH=, GPATH=, and the BODY= options to specify a different location for the HTML output file and the graphics output files. Here is an example that uses the FILE= ODS option with the PDF destination to send the PDF output to file mygraph.pdf in the default SAS directory.

goptions reset=all;
ods html close;
ods pdf style=money file="mygraph.pdf";
proc gchart data=sashelp.prdsale;
   vbar Product / sumvar=actual;
      title1 "First Quarter Sales in Canada";
      where Quarter=1 and Country="CANADA";
   run;
quit;
ods pdf close;
ods html;

Here is an example that uses the PATH=, GPATH=, and the BODY= ODS options with the HTML destination to send the HTML output to file mygraph.html in the current directory, and the graphics output file to the images subdirectory.

goptions reset=all;
ods html style=banker path="./" gpath="images" body="mygraph.html";
proc gchart data=sashelp.prdsale;
   vbar Product / sumvar=actual;
      title1 "First Quarter Sales in Canada";
      where Quarter=1 and Country="CANADA";
   run;
quit;
ods html close;
ods html;

For more information about the PATH=, GPATH=, and BODY= options, see SAS Output Delivery System: User's Guide .

When you use the ODS LISTING destination, you can use the GSFNAME= graphics option to send your output to a graphics output file that you specify. The GSFNAME= option requires a FILENAME statement that creates a file reference that points to a file or an aggregate file storage location. The syntax of the FILENAME statement is as follows:

FILENAME RefName 
"DirectoryOrFile"

Here is an example that shows how to send the output of the GCHART procedure to file mychart.png in the MyGraphs directory.

filename graphout "MyGraphs";
goptions reset=all device=png gsfname=graphout;
ods html close;
ods listing;
proc gchart data=sashelp.cars;
   pie Make / name="MYCHART";
      where MSRP <= 15000;
   run;
quit
ods listing close;
ods html;

If a MYCHART GRSEG entry does not already exist in the temporary catalog, the device sends the output to file mychart.png in the Mygraphs directory. If a MYCHART GRSEG entry already exists, the device uses an incremented name such as MYCHART1. In the previous example, you can replace the aggregate file location with a filename in the FILENAME statement and omit the NAME= option and get the same result.

You can also store your output in a graphics output file on a remote host using FTP. Here is an example that uses FTP to store multiple PNG graphs in directory /public/sas/graphs on the remote UNIX host unixhost73.

filename grafout ftp "/public/sas/graphs" dir host="unixhost73" fileext
   user="anonymous";
ods html close;
ods listing style=banker;
goptions reset=all device=png gsfname=grafout;

/* Create our data set by sorting sashelp.cars by type */
proc sort data=sashelp.cars out=work.cars;
   by type;
run;

/* Generate the graphs */
proc gchart data=work.cars;
   vbar Make;
      title1 "30 MPG or Better";
      where MPG_Highway >= 30;
      by type;
   run;
quit;
ods listing close;
ods html;

This example creates four PNG files in directory /public/sas/graphs on host unixhost73. Since the GCHART procedure uses BY-group processing, the FILENAME statement includes the DIR option, which defines an aggregate file storage location. If you need to create only one graph, remove the DIR option and specify the absolute path to your graphics output file in your FILENAME statement.

When duplicate names occur in graphics output filenames, SAS/GRAPH procedures use indexing systems to determine unique names for new graphics output files. (Numbers are added to the end of the filename to create new filenames). Two indexing systems are used: ODS Statistical Graphics indexing and catalog-based indexing. ODS Statistical Graphics indexing is used in all ODS Statistical Graphics output and by the procedures listed in Filename Indexing Systems Used by SAS/GRAPH Procedures. All of the other procedures use catalog-based indexing.

Because two independent indexing systems are used by the SAS/GRAPH procedures, it is possible that graphics output files can be overwritten if the same graphics filename both for procedures that use catalog-based indexing and for procedures that use ODS Statistical Graphics indexing. To avoid this problem, make sure that you specify different names for the procedures that use ODS Statistical Graphics indexing and the procedures that use catalog-based indexing. For example, if your application uses both the GMAP procedure and the GAREABAR procedure, and you are using the NAME= option to specify output filenames, make sure you specify different filenames for each procedure.

How SAS/GRAPH Generates Initial GRSEG Names and Filenames summarizes how SAS/GRAPH generates names for catalog entries and graphics output files, depending on 1) whether the NAME= option is used, and 2) the file reference specification in the FILENAME statement. This illustration assumes that the GCHART procedure is used with the DEVICE=GIF graphics option. It describes the case where a GRSEG and output file of the same name do not already exist, and the case where they do already exist.

When a GRSEG of the same name already exists in the catalog, the SAS/GRAPH software combines the NAME= option value with a number to create an incremented name of no more than eight characters. If the GSFNAME= graphics option is used and the file reference points to an aggregate file location, the new graphics output filename is also incremented using the same number that is used for the GRSEG name. The way in which the incremented graphics output filename is formed depends on the length of the NAME= value as follows:

If the GSFNAME= graphics option points to a file, the graphics output filename remains the same and the original file is replaced with the new graph by default.

How SAS/GRAPH Increments GRSEG Names and Filenames demonstrates how the SAS/GRAPH software increments the GRSEG name and the graphics output filenames when a GRSEG and graphics output file of the same name already exist.

Notice that in the NAME="MYIMAGES" example the incremented external filename is formed by appending the number to the first seven characters of the NAME= value, while in the NAME="WEATHEROBS" and NAME="FRED" examples, the incremented external filename is formed by appending the number to the full NAME= value. Be aware that the way in which the incremented graphics output filename is formed is different when the length of the NAME= value is exactly eight characters than when it is more or less than eight characters.

You cannot replace individual GRSEGs in a catalog. To replace a GRSEG, you must delete the GRSEG, and then re-create it. Therefore, even though the contents of the graphics output file are replaced, the GRSEG is not. Each time you submit the program, a new GRSEG is created, and the GRSEG name is incremented.