The GPLOT Procedure

Example 9: Plotting with Different Scales of Values

Procedure features:

PLOT statement options:

	HAXIS=
	HMINOR=

PLOT and PLOT2 statement options:

	VAXIS=
	VMINOR=

Other features:

GOPTIONS statement option:

BORDER

AXIS statement

SYMBOL statement

Sample library member:

GPLSCVL1

[Plotting with Different Scales of Values]

This example shows how a PLOT2 statement generates a right axis that displays the values of the vertical coordinates in a different scale from the scale that is used for the left axis.

In this plot of the average monthly temperature for Minneapolis, temperature variables that represent degrees centigrade (displayed on the left axis) and degrees Fahrenheit (displayed on the right axis) are plotted against the variable MONTH. Although the procedure produces two sets of data points, it calibrates the axes so that the data points are identical and it displays only one plot.

This example uses SYMBOL statements to define symbol definitions. By default, the SYMBOL1 statement is assigned to the plot that is generated by the PLOT statement, and SYMBOL2 is assigned to the plot generated by the PLOT2 statement.

goptions reset=all border;

data minntemp;
   input @10 month
         @23 f2;     /* fahrenheit temperature for Minneapolis */
         c2=(f2-32)/1.8; /* calculate centigrade temperature */
                         /* for Minneapolis                  */
   output;
   datalines;
01JAN83  1    1   40.5  12.2  52.1
01FEB83  2    1   42.2  16.5  55.1
01MAR83  3    2   49.2  28.3  59.7
01APR83  4    2   59.5  45.1  67.7
01MAY83  5    2   67.4  57.1  76.3
01JUN83  6    3   74.4  66.9  84.6
01JUL83  7    3   77.5  71.9  91.2
01AUG83  8    3   76.5  70.2  89.1
01SEP83  9    4   70.6  60.0  83.8
01OCT83  10   4   60.2  50.0  72.2
01NOV83  11   4   50.0  32.4  59.8
01DEC83  12   1   41.2  18.6  52.5
;

title1 "Average Monthly Temp for Minneapolis";
footnote1 j=l " Source: 1984 American Express";
footnote2 j=l "         Appointment Book"
          j=r "GPLSCVL1 ";

symbol1 interpol=needle ci=blue cv=red  value=star
        ;

symbol2 interpol=none
        value=none;

axis1 label=none
      value=( "JAN" "FEB" "MAR" "APR" "MAY" "JUN"
            "JUL" "AUG" "SEP" "OCT" "NOV" "DEC")
      order=(1 to 12 by 1)
      offset=(2)
      ;
axis2 label=( "Degrees" justify=right " Centigrade")
      order=(-20 to 30 by 10)

      ;
axis3 label=( "Degrees" justify=left "Fahrenheit")
      order=(-4 to 86 by 18)

;

proc gplot data= minntemp;
   plot c2*month / haxis=axis1 hminor=0
                   vaxis=axis2 vminor=1;
   plot2 f2*month / vaxis=axis3 vminor=1;
run;
quit;

Top of Page