The PANEL Procedure

Example 20.4 The Airline Cost Data: Random-Effects Models

This example continues to use the Christenson Associates airline data, which measures costs, prices of inputs, and utilization rates for six airlines over the time span 1970–1984. There are six cross sections and fifteen time observations. Here, you examine the different estimates generated from the one-way random-effects and two-way random-effects models, by using four different methods to estimate the variance components: Fuller and Battese, Wansbeek and Kapteyn, Wallace and Hussain, and Nerlove.

The data for this example is created by the PROC PANEL statements shown in Example 20.2. The PROC PANEL statements necessary to generate the estimates are as follows:

proc panel data=airline outest=estimates;
   id I T;
   RANONE:   model lC = lQ lPF lF / ranone vcomp=fb;
   RANONEwk: model lC = lQ lPF lF / ranone vcomp=wk;
   RANONEwh: model lC = lQ lPF lF / ranone vcomp=wh;
   RANONEnl: model lC = lQ lPF lF / ranone vcomp=nl;
   RANTWO:   model lC = lQ lPF lF / rantwo vcomp=fb;
   RANTWOwk: model lC = lQ lPF lF / rantwo vcomp=wk;
   RANTWOwh: model lC = lQ lPF lF / rantwo vcomp=wh;
   RANTWOnl: model lC = lQ lPF lF / rantwo vcomp=nl;
   POOLED:   model lC = lQ lPF lF / pooled;
   BTWNG:    model lC = lQ lPF lF / btwng;
   BTWNT:    model lC = lQ lPF lF / btwnt;
data table;
  set estimates;
   VarCS  = round(_VARCS_,.00001);
   VarTS  = round(_VARTS_,.00001);
   VarErr = round(_VARERR_,.00001);
   Int    = round(Intercept,.0001);
   lQ2    = round(lQ,.0001);
   lPF2   = round(lPF,.0001);
   lF2    = round(lF,.0001);
   if _n_ >= 9 then do;
     VarCS = . ;
     VarTS = . ;
   keep _MODEL_ _METHOD_ VarCS VarTS VarErr Int lQ2 lPF2 lF2;

The parameter estimates and variance components for both models are reported in Output 20.4.1 and Output 20.4.2.

Output 20.4.1: Parameter Estimates

Parameter Estimates

Method Model Intercept lQ lPF lF
_Ran1FB_ RANONE 9.7097 0.9187 0.4177 -1.0700
_Ran1WK_ RANONEWK 9.6295 0.9069 0.4227 -1.0646
_Ran1WH_ RANONEWH 9.6439 0.9090 0.4218 -1.0650
_Ran1NL_ RANONENL 9.6406 0.9086 0.4220 -1.0648
_Ran2FB_ RANTWO 9.3627 0.8665 0.4362 -0.9805
_Ran2WK_ RANTWOWK 9.6436 0.8433 0.4097 -0.9263
_Ran2WH_ RANTWOWH 9.3793 0.8692 0.4353 -0.9852
_Ran2NL_ RANTWONL 9.9726 0.8387 0.3829 -0.9134
_POOLED_ POOLED 9.5169 0.8827 0.4540 -1.6275
_BTWGRP_ BTWNG 85.8094 0.7825 -5.5240 -1.7509
_BTWTME_ BTWNT 11.1849 1.1333 0.3343 -1.3509

Output 20.4.2: Variance Component Estimates

Variance Component Estimates

Method Model Variance Component
for Cross Sections
Variance Component
for Time Series
Variance Component
for Error
_Ran1FB_ RANONE 0.47442 . 0.00361
_Ran1WK_ RANONEWK 0.01602 . 0.00361
_Ran1WH_ RANONEWH 0.01871 . 0.00328
_Ran1NL_ RANONENL 0.01745 . 0.00325
_Ran2FB_ RANTWO 0.01744 0.00108 0.00264
_Ran2WK_ RANTWOWK 0.01561 0.03913 0.00264
_Ran2WH_ RANTWOWH 0.01875 0.00085 0.00250
_Ran2NL_ RANTWONL 0.01707 0.05909 0.00196
_POOLED_ POOLED . . 0.01553
_BTWGRP_ BTWNG . . 0.01584
_BTWTME_ BTWNT . . 0.00051

In the random-effects model, individual constant terms are viewed as randomly distributed across cross-sectional units and not as parametric shifts of the regression function, as in the fixed-effects model. This is appropriate when the sampled cross-sectional units are drawn from a large population. Clearly, in this example, the six airlines are a sample of all the airlines in the industry and not an exhaustive, or nearly exhaustive, list.

There are four ways of computing the variance components in the one-way random-effects model. The method by Fuller and Battese (1974) (FB), uses a fitting of constants methods to estimate them. The Wansbeek and Kapteyn (1989) (WK) method uses the true disturbances, while the Wallace and Hussain (WH) method uses ordinary least squares residuals.

Looking at the estimates of the variance components for cross section and error in Output 20.4.2, you see that equal variance components for error are computed for both FB and WK, while WH and NL are nearly equal.

All four techniques produce different variance components for cross sections. These estimates are then used to estimate the values of the parameters in Output 20.4.1. All the parameters appear to have similar and equally plausible estimates. Both the index for output in revenue passenger miles (lQ) and fuel price (lPF) have small, positive effects on total costs, which you would expect. The load factor (LF) has a somewhat larger and negative effect on total costs, suggesting that as utilization increases, costs decrease.

As in the one-way random-effects model, the variance components for error produced by the FB and WK methods are equal. However, in this case, the WH and NL methods produce variance estimates that are dissimilar. The estimates of the variance component for cross sections are all different, but in a close range. The same cannot be said for the variance component for time series. As varied as each of the variance estimates may be, they produce parameter estimates that are similar and plausible. As with the one-way effects model, the index for output (lQ) and fuel price (lPF) are small and positive. The load factor (LF) estimates are all negative and, with the exception of the estimate produced by the WH method, somewhat smaller than the estimates produced in the one-way model. During the time the data were collected, the Civil Aeronautics Board dissolved, so it is possible that the dummy variables are proxies for this dissolution. This would lead to the decay of time effects and an imprecise estimation of the effects of the load factors, even though the estimates are statistically significant.

The pooled estimates give you something to compare the random-effects estimates against. You see that signs and magnitudes of output and fuel price are similar but that the magnitude of the load factor coefficient is somewhat larger under pooling. Since the model appears to have both cross-sectional and time series effects, the pooled model should not be used.

Finally, you examine the between groups estimators. For the between groups estimate, you are looking at each airline’s data averaged across time. You see in Output 20.4.1 that the between groups parameter estimates are radically different from all other parameter estimates. This could indicate that the time component is not being appropriately handled with this technique. For the between times estimate, you are looking at the average across all airlines in each time period. In this case, the parameter estimates are of the same sign and closer in magnitude to the previously computed estimates. Both the output and load factor effects appear to have more bearing on total costs.