### BOUNDS Statement

`BOUNDS` bound1 <, bound2 …> ;

The BOUNDS statement imposes simple boundary constraints either on the parameters in an estimation or on the solution variables specified in a solve operation. A BOUNDS statement that applies to parameters constrains the parameters estimated in the preceding FIT statement or, in the absence of a preceding FIT statement, in the following FIT statement. A BOUNDS statement that is applied to solution variables constrains the solution of the preceding SOLVE statement or, in the absence of a preceding SOLVE statement, of the following SOLVE statement. You can specify any number of BOUNDS statements.

Each bound is composed of either parameters or solution variables, constants, and inequality operators:

`item operator item < operator item < operator item …> > `

For BOUNDS statements that apply to FIT statements, each item is a constant, the name of an estimated parameter, or a list of parameter names. For BOUNDS statements that apply to SOLVE statements, each item is a constant, the name of a solution variable, or a list of solution variables. Each operator is <, >, <=, or >=.

You can use either the BOUNDS statement or the RESTRICT statement to impose boundary constraints when estimating parameters or solving for solution variables.

The BOUNDS statement provides a simpler syntax for specifying boundary constraints than the RESTRICT statement. For more information about the computational details of estimation and solutions with inequality restrictions, see the section RESTRICT Statement.

#### Parameter Estimates

Each active boundary constraint on estimated parameters is associated with a Lagrange multiplier. In the printed output and in the OUTEST= data set, the Lagrange multiplier estimates are identified with the names BOUND0, BOUND1, and so forth. The probabilities of the Lagrange multipliers are computed by using a beta distribution (LaMotte 1994). To give the constraints more descriptive names, use the RESTRICT statement instead of the BOUNDS statement.

The following BOUNDS statement constrains the estimates of the parameters A and B and the ten parameters P1 through P10 to be between 0 and 1. This example illustrates the use of parameter lists to specify boundary constraints.

```bounds 0 < a b p1-p10 < 1;
```

The following statements show how to use the BOUNDS statement, and they produce the output shown in Figure 19.13:

```title 'Holzman Function (1969), Himmelblau No. 21, N=3';
data zero;
do i = 1 to 99;
output;
end;
run;

proc model data=zero;
parms x1= 100 x2= 12.5 x3=  3;
bounds .1 <= x1 <= 100,
0 <= x2 <=  25.6,
0 <= x3 <=   5;

t = 2 / 3;
u = 25 + (-50 * log(0.01 * i )) ** t;
v = (u - x2) ** x3;
w = exp(-v / x1);
eq.foo = -.01 * i + w;

fit foo / method=marquardt;
run;
```

Figure 19.13: Output from Bounded Estimation

 Holzman Function (1969), Himmelblau No. 21, N=3

The MODEL Procedure

Nonlinear OLS Parameter Estimates
Parameter Estimate Approx Std Err t Value Approx
Pr > |t|
x1 49.99999 0 . .
x2 25 0 . .
x3 1.5 0 . .

#### Solution Variables

Boundary constraints on solution variables can be used to specify which solution is reported when an equation has multiple solutions. The BOUNDS statement in the following example causes its associated SOLVE statement to compute only the negative value of the solution variable shown in Figure 19.14:

```data d;
date = 0;
run;

proc model data=d;
endo x;
bounds x < 0;

eq.sqrt = x**2 - 4;

solve / optimize out=o;
run;

proc print data = o; run;
```

Figure 19.14: Listing of OUT= Data Set Created by a Bounded SOLVE Statement

Obs _TYPE_ _MODE_ _ERRORS_ x
1 PREDICT SIMULATE 0 -2