The LOAN Procedure
Loan Comparison
The LOAN procedure can compare alternative loans on the basis of different economic criteria and help select the most desirable loan. You can compare alternative loans through different points in time. The economic criteria offered by PROC LOAN are:
-
outstanding principal balance—that is, the unpaid balance of the loan
-
present worth of cost—that is, before-tax or after-tax net value of the loan cash flow through the comparison period. The cash flow includes all payments, discount points, initialization costs, down payment, and the outstanding principal balance at the comparison period.
-
true interest rate—that is, before-tax or after-tax effective annual interest rate charged on the loan. The cash flow includes all payments, discount points, initialization costs, and the outstanding principal balance at the specified comparison period.
-
periodic payment
-
the total interest paid on the loan
The figures for present worth of cost, true interest rate, and interest paid are reported on the cash flow through the comparison period. The reported outstanding principal balance and the periodic payment are the values as of the comparison period.
The COMPARE statement specifies the type of comparison and the periods of comparison. For each period specified in the COMPARE statement, a loan comparison report is printed that also indicates the best alternative. Different criteria can lead to selection of different alternatives. Also, the period of comparison might change the desirable alternative. See the section Loan Comparison Details for further information.
Comparison of 15-Year versus 30-Year Loan Alternatives
An issue that arises in the purchase of a house is the length of the loan life. Residential home loans are often for 15 or 30 years. Ordinarily, 15-year loans have a lower interest rate but higher periodic payments than 30-year loans. A comparison of both loans might identify the better loan for your means and needs. The following SAS statements compare two such loans:
proc loan start=1998:12 amount=120000; fixed rate=7.5 life=360 label='30 year loan'; fixed rate=6.5 life=180 label='15 year loan'; compare; run;
Default Loan Comparison Report
The default loan comparison report in Figure 17.7 shows the ending outstanding balance, periodic payment, interest paid, and before-tax true rate at the end of 30 years. In the case of the default loan comparison, the selection of the best alternative is based on minimization of the true rate.
Figure 17.7: Default Loan Comparison Report
| Loan Comparison Report Analysis through DEC2028 |
||||
|---|---|---|---|---|
| Loan Label | Ending Outstanding |
Payment | Interest Paid |
True Rate |
| 30 year loan | 0.00 | 835.48 | 182058.02 | 7.76 |
| 15 year loan | 0.00 | 1044.95 | 68159.02 | 6.70 |
| Note: | "15 year loan" is the best alternative based on true rate analysis through DEC2028. |
Based on true rate, the best alternative is the 15-year loan. However, if the objective were to minimize the periodic payment, the 30-year loan would be the more desirable.
Comparison of Fixed Rate and Adjustable Rate Loans
Suppose you want to compare a fixed rate loan to an adjustable rate alternative. The nominal interest rate on the adjustable rate loan is initially 1.5% lower than the fixed rate loan. The future rates of the adjustable rate loan are calculated using the worst case scenario.
The interest paid on a loan might be deductible for tax purposes, depending on the purpose of the loan and applicable laws. In the following example, the TAXRATE=28 (income tax rate) option in the COMPARE statement bases the calculations of true interest rate on the after-tax cash flow. Assume, also, that you are uncertain as to how long you will keep this property. The AT=(60 120) option, as shown in the following example, produces two loan comparison reports through the end of the 5th and the 10th years, respectively:
proc loan start=1998:12 amount=120000 life=360;
fixed rate=7.5 label='BANK1, Fixed Rate';
arm rate=6.0 worstcase caps=(0.5 2.5)
label='BANK3, Adjustable Rate';
compare taxrate=28 at=(60 120);
run;
After-Tax Loan Comparison Reports
The two loan comparison reports in Figure 17.8 and Figure 17.9 show the ending outstanding balance, periodic payment, interest paid, and after-tax true rate at the end of five years and ten years, respectively.
Figure 17.8: Loan Comparison Report as of December 2003
| Loan Comparison Report Analysis through DEC2003 |
||||
|---|---|---|---|---|
| Loan Label | Ending Outstanding |
Payment | Interest Paid |
True Rate |
| BANK1, Fixed Rate | 113540.74 | 839.06 | 43884.34 | 5.54 |
| BANK3, Adjustable Rate | 112958.49 | 871.83 | 40701.93 | 5.11 |
| Note: | "BANK3, Adjustable Rate" is the best alternative based on true rate analysis through DEC2003. |
Figure 17.9: Loan Comparison Report as of December 2008
| Loan Comparison Report Analysis through DEC2008 |
||||
|---|---|---|---|---|
| Loan Label | Ending Outstanding |
Payment | Interest Paid |
True Rate |
| BANK1, Fixed Rate | 104153.49 | 839.06 | 84840.69 | 5.54 |
| BANK3, Adjustable Rate | 104810.98 | 909.57 | 87128.62 | 5.60 |
| Note: | "BANK1, Fixed Rate" is the best alternative based on true rate analysis through DEC2008. |
The loan comparison report through December 2003 picks the adjustable rate loan as the best alternative, whereas the report through December 2008 shows the fixed rate loan as the better alternative. This implies that if you intend to keep the loan for 10 years or longer, the best alternative is the fixed rate alternative. Otherwise, the adjustable rate loan is the better alternative in spite of the worst-case scenario. Further analysis shows that the actual breakeven of true interest rate occurs at August 2008. That is, the desirable alternative switches from the adjustable rate loan to the fixed rate loan in August 2008.
Note that, under the assumption of worst-case scenario for the rate adjustments, the periodic payment for the adjustable rate loan already exceeds that of the fixed rate loan on December 2003 (as of the rate adjustment on January 2003 to be exact). If the objective were to minimize the periodic payment, the fixed rate loan would have been more desirable as of December 2003. However, all of the other criteria at that point still favor the adjustable rate loan.