The SASECRSP Interface Engine

Example 38.7 Comparing Different Ways of Accessing CCM Data

You can use three different ways to select CCM data: by the primary key, GVKEY, or by either of the two secondary keys PERMNO and PERMCO. This section demonstrate the three different ways.

This example retrieves data on Cimflex Teknowledge Corporation which was previously known as Teknowledge Inc. This company is considered a single entity by the CRSP Stock database and is identified by PERMNO=10083 and PERMCO=8026. The Compustat database, however, considers Teknowledge Inc. and Cimflex Teknowledge Corporation as two separate entities, and each has its own GVKEY. Thus, PERMNO=10083 maps to GVKEYs 11947 and 15495, and PERMCO=8026 has the identical relationship. Access by PERMNO and PERMCO are equivalent in this case, but differ from access by GVKEY. PERMNO/PERMCO access retrieves data only within the active period of the links, and only the primary linked GVKEY is used for header access. In contrast, GVKEY access provides wide-open, full data for both GVKEYs. See PERMNO= option for more details.

title1 'Comparing various access methods for CCM data';
libname _all_ clear;

/* assign libnames for the three different access methods */
libname crsp1a sasecrsp "%sysget(CRSP_CST)"
        setid=200
        permno=10083
        range='19870101-19900101';

libname crsp1b sasecrsp "%sysget(CRSP_CST)"
        setid=200
        permco=8026
        range='19870101-19900101';

libname crsp2 sasecrsp "%sysget(CRSP_CST)"
        setid=200
        gvkey=11947 gvkey=15495
        range='19870101-19900101';

title2 'PERMNO=10083 access of CCM data';
title3 'Sales (Net)';

data permnoaccess;
  set crsp1a.iqitems(keep=gvkey rcaldt fiscaldt iq2);
run;

proc print data=permnoaccess;
run;

Output 38.7.1 shows PERMNO access of CCM quarterly 'Sales (Net)' data.

title2 'GVKEY=11947 and GVKEY=15495 access of CCM data';
title3 'Sales (Net)';

data gvkeyaccess;
  set crsp2.iqitems(keep=gvkey rcaldt fiscaldt iq2);
run;

proc print data=gvkeyaccess;
run;

Output 38.7.2 shows GVKEY access of CCM quarterly Sales data.

title3 'LINK: Link information';
proc print data=crsp2.link;
run;

/* Show how PERMNO and PERMCO access are the same */
title4 'Proc compare of PERMNO vs. PERMCO access of CCM data';
proc compare base=crsp1a.iqitems compare=crsp1b.iqitems brief;
run;

Output 38.7.3 shows CRSP link information and comparison of GVKEY to PERMNO access.

                             The COMPARE Procedure                              
                Comparison of CRSP1A.IQITEMS with CRSP1B.IQITEMS                
                                 (Method=EXACT)                                 
                                                                                
NOTE: No unequal values were found. All values compared are exactly equal.