The LOAN Procedure

Example 17.5 Piggyback Loans

The piggyback loan is becoming a widely available alternative. Borrowers like to avoid the PMI (private mortgage insurance) required with loans where the borrower has a down payment of less than 20% of the price. The piggyback allows a secondary home equity loan to be packaged with a primary loan with less than 20% down payment. The secondary loan usually has a shorter life and higher interest rate. The interest paid on both loans are tax-deductible whereas PMI does not qualify for a tax deduction.

The following example compares a conventional fixed rate loan with 20% down as opposed to a piggyback loan: one primary fixed rate with 10% down payment and a secondary, home equity loan for 10% of the original price. All loans have monthly payments.

The conventional loan alternative is a 30-year loan with a fixed annual rate of 7.5%. The primary loan in the piggyback loan setup is also a 30-year loan with a fixed annual rate of 7.75%. The secondary loan is a 15-year loan with a fixed annual interest rate of 8.25%.

The comparison output for the two loans comprising the piggyback loan is aggregated using the TIMESERIES procedure with a minimum of specified options:

• The INTERVAL= option requests that the data be aggregated into periods of length 5 years beginning on the 25th month, resulting in appropriately identified periods.

• The ACC=TOTAL option specifies that the output should reflect accumulated totals as opposed to, say, averages.

• The NOTSORTED option indicates that the input data set has not been sorted by the ID variable.

See Chapter 32, The TIMESERIES Procedure, for more information about this procedure.

Use the following statements to analyze the conventional loan, as well as the piggyback alternative, and compare them on the basis of their present worth of cost, outstanding balance, and interest payment amounts at the end of 5, 10, and 15 years into the loan life.

title1 'LOAN: Piggyback loan example';

title2 'LOAN: Conventional loan';

proc loan start=2002:1 noprint;

   fixed price=200000 dp=40000 rate=7.5 life=360
         label='20 percent down: Conventional Fixed Rate' ;

   compare at=(60 120 180) pwofcost taxrate=30 marr=12
           breakpay breakint outcomp=comploans;

run;

title2 'LOAN: Piggyback: Primary Loan';

proc loan start=2002:1 noprint;

   fixed amount=160000 dp=20000 rate=7.75 life=360
         label='Piggyback: Primary loan' out=loan1;

   compare at=(60 120 180 ) pwofcost taxrate=30 marr=12
          breakpay breakint outcomp=cloan1;

run;

title2 'LOAN: Piggyback: Secondary (Home Equity) Loan';

proc loan start=2002:1 noprint;

   fixed amount=20000  rate=8.25 life=180
         label='Piggyback: Secondary (Home Equity) Loan' out=loan2;

   compare at=(60 120 180 ) pwofcost taxrate=30 marr=12
           breakpay breakint  outcomp=cloan2;

run;

data cloan12;
   set cloan1  cloan2;
run;

proc timeseries data=cloan12 out= totcomp ;
   id date interval=year5.25 acc=total notsorted;
   var payment interest pwofcost balance ;
run;

/*-- LOAN: Piggyback loan --*/
title;
proc print data=totcomp;
   format date monyy7.;
run;

data comploans;
   set comploans;
   drop type label;
run;

/*-- LOAN: Conventional Loan --*/
title;
proc print data=comploans;
run;

The loan comparisons in Output 17.5.1 and Output 17.5.2 illustrate the after-tax comparison of the loans. The after-tax present value of cost for the piggyback loan is lower than the 20% down conventional fixed rate loan.