Previous Page

|

Next Page

The VARMAX Procedure

Example 32.1 Analysis of U.S. Economic Variables

Consider the following four-dimensional system of U.S. economic variables. Quarterly data for the years 1954 to 1987 are used (Lütkepohl 1993, Table E.3.).

title 'Analysis of U.S. Economic Variables';
data us_money;
   date=intnx( 'qtr', '01jan54'd, _n_-1 );
   format date yyq. ;
   input y1 y2 y3 y4 @@;
   y1=log(y1);
   y2=log(y2);
   label y1='log(real money stock M1)'
         y2='log(GNP in bil. of 1982 dollars)'
         y3='Discount rate on 91-day T-bills'
         y4='Yield on 20-year Treasury bonds';
datalines;
450.9 1406.8  0.010800000 0.026133333
453.0 1401.2 0.0081333333 0.025233333

   ... more lines ...   

The following statements plot the series and proceed with the VARMAX procedure.

proc timeseries data=us_money vectorplot=series;
   id date interval=qtr;
   var y1 y2;
run;

Output 32.1.1 shows the plot of the variables and .

Output 32.1.1 Plot of Data

The following statements plot the variables and .

proc timeseries data=us_money vectorplot=series;
   id date interval=qtr;
   var y3 y4;
run;

Output 32.1.2 shows the plot of the variables and .

Output 32.1.2 Plot of Data

proc varmax data=us_money;
   id date interval=qtr;
   model y1-y4 / p=2 lagmax=6 dftest
                 print=(iarr(3) estimates diagnose)
                 cointtest=(johansen=(iorder=2))
                 ecm=(rank=1 normalize=y1);
   cointeg rank=1 normalize=y1 exogeneity;
run;

This example performs the Dickey-Fuller test for stationarity, the Johansen cointegrated test integrated order 2, and the exogeneity test. The VECM(2) is fit to the data. From the outputs shown in Output 32.1.5, you can see that the series has unit roots and is cointegrated in rank 1 with integrated order 1. The fitted VECM(2) is given as

The prefixed to a variable name implies differencing.

Output 32.1.3 through Output 32.1.14 show the details. Output 32.1.3 shows the descriptive statistics.

Output 32.1.3 Descriptive Statistics

Analysis of U.S. Economic Variables

The VARMAX Procedure

Number of Observations	136
Number of Pairwise Missing	0

Simple Summary Statistics
Variable	Type	N	Mean	Standard Deviation	Min	Max	Label
y1	Dependent	136	6.21295	0.07924	6.10278	6.45331	log(real money stock M1)
y2	Dependent	136	7.77890	0.30110	7.24508	8.27461	log(GNP in bil. of 1982 dollars)
y3	Dependent	136	0.05608	0.03109	0.00813	0.15087	Discount rate on 91-day T-bills
y4	Dependent	136	0.06458	0.02927	0.02490	0.13600	Yield on 20-year Treasury bonds

Output 32.1.4 shows the output for Dickey-Fuller tests for the nonstationarity of each series. The null hypotheses is to test a unit root. All series have a unit root.

The Johansen cointegration rank test shows whether the series is integrated order either 1 or 2 as shown in Output 32.1.5. The last two columns in Output 32.1.5 explain the cointegration rank test with integrated order 1. The results indicate that there is the cointegrated relationship with the cointegration rank 1 with respect to the 0.05 significance level because the test statistic of 20.6542 is smaller than the critical value of 29.38. Now, look at the row associated with . Compare the test statistic value and critical value pairs such as (219.62395, 29.38), (89.21508, 15.34), and (27.32609, 3.84). There is no evidence that the series are integrated order 2 at the 0.05 significance level.

Output 32.1.6 shows the estimates of the long-run parameter, , and the adjustment coefficient, .

Output 32.1.7 shows the estimates and .

Output 32.1.8 shows that the VECM(2) is fit to the data. The ECM=(RANK=1) option produces the estimates of the long-run parameter, , and the adjustment coefficient, .

Output 32.1.9 shows the parameter estimates in terms of the constant, the lag one coefficients () contained in the estimates, and the coefficients associated with the lag one first differences ().

Output 32.1.10 shows the parameter estimates and their significance.

Output 32.1.11 shows the innovation covariance matrix estimates, the various information criteria results, and the tests for white noise residuals. The residuals have significant correlations at lag 2 and 3. The Portmanteau test results into significant. These results show that a VECM(3) model might be better fit than the VECM(2) model is.

Output 32.1.12 describes how well each univariate equation fits the data. The residuals for and are off from the normality. Except the residuals for , there are no AR effects on other residuals. Except the residuals for , there are no ARCH effects on other residuals.

The PRINT=(IARR) option provides the VAR(2) representation in Output 32.1.13.

Output 32.1.14 shows whether each variable is the weak exogeneity of other variables. The variable is not the weak exogeneity of other variables, , , and ; the variable is not the weak exogeneity of other variables, , , and ; the variable and are the weak exogeneity of other variables.

Copyright © SAS Institute, Inc. All Rights Reserved.