Previous Page | Next Page

The MODEL Procedure

Example 18.4 MA(1) Estimation

This example estimates parameters for an MA(1) error process for the Grunfeld model, using both the unconditional least squares and the maximum likelihood methods. The ARIMA procedure estimates for Westinghouse equation are shown for comparison. The output of the following statements is summarized in Output 18.4.1: 

proc model outmodel=grunmod;
   var gei whi gef gec whf whc;
   parms ge_int ge_f ge_c wh_int wh_f wh_c;
   label ge_int = 'GE Intercept'
         ge_f   = 'GE Lagged Share Value Coef'
         ge_c   = 'GE Lagged Capital Stock Coef'
         wh_int = 'WH Intercept'
         wh_f   = 'WH Lagged Share Value Coef'
         wh_c   = 'WH Lagged Capital Stock Coef';
   gei = ge_int + ge_f * gef + ge_c * gec;
   whi = wh_int + wh_f * whf + wh_c * whc;
run;

title1 'Example of MA(1) Error Process Using Grunfeld''s Model';
title2 'MA(1) Error Process Using Unconditional Least Squares';

proc model data=grunfeld model=grunmod;
   %ma(gei,1, m=uls);
   %ma(whi,1, m=uls);
   fit whi gei start=( gei_m1 0.8 -0.8) / startiter=2;
run;

Output 18.4.1 PROC MODEL Results by Using ULS Estimation
Example of MA(1) Error Process Using Grunfeld's Model
MA(1) Error Process Using Unconditional Least Squares

The MODEL Procedure

Nonlinear OLS Summary of Residual Errors 
Equation DF Model DF Error SSE MSE Root MSE R-Square Adj R-Sq Label
whi 4 16 1874.0 117.1 10.8224 0.7299 0.6793 Gross Investment WH
resid.whi   16 1295.6 80.9754 8.9986     Gross Investment WH
gei 4 16 13835.0 864.7 29.4055 0.6915 0.6337 Gross Investment GE
resid.gei   16 7646.2 477.9 21.8607     Gross Investment GE

Nonlinear OLS Parameter Estimates
Parameter Estimate Approx Std Err t Value Approx
Pr > |t|		 Label
ge_int -26.839 32.0908 -0.84 0.4153 GE Intercept
ge_f 0.038226 0.0150 2.54 0.0217 GE Lagged Share Value Coef
ge_c 0.137099 0.0352 3.90 0.0013 GE Lagged Capital Stock Coef
wh_int 3.680835 9.5448 0.39 0.7048 WH Intercept
wh_f 0.049156 0.0172 2.85 0.0115 WH Lagged Share Value Coef
wh_c 0.067271 0.0708 0.95 0.3559 WH Lagged Capital Stock Coef
gei_m1 -0.87615 0.1614 -5.43 <.0001 MA(gei) gei lag1 parameter
whi_m1 -0.75001 0.2368 -3.17 0.0060 MA(whi) whi lag1 parameter

The estimation summary from the following PROC ARIMA statements is shown in Output 18.4.2. 

title2 'PROC ARIMA Using Unconditional Least Squares';

proc arima data=grunfeld;
   identify var=whi cross=(whf whc ) noprint;
   estimate q=1 input=(whf whc) method=uls maxiter=40;
run;

Output 18.4.2 PROC ARIMA Results by Using ULS Estimation
Example of MA(1) Error Process Using Grunfeld's Model
PROC ARIMA Using Unconditional Least Squares

The ARIMA Procedure

Unconditional Least Squares Estimation
Parameter Estimate Standard Error t Value Approx
Pr > |t|		 Lag Variable Shift
MU 3.68608 9.54425 0.39 0.7044 0 whi 0
MA1,1 -0.75005 0.23704 -3.16 0.0060 1 whi 0
NUM1 0.04914 0.01723 2.85 0.0115 0 whf 0
NUM2 0.06731 0.07077 0.95 0.3557 0 whc 0

Constant Estimate 3.686077
Variance Estimate 80.97535
Std Error Estimate 8.998631
AIC 149.0044
SBC 152.9873
Number of Residuals 20

The model stored in Example 18.3 is read in by using the MODEL= option and the moving-average terms are added using the %MA macro.

The MA(1) model using maximum likelihood is estimated by using the following statements: 

title2 'MA(1) Error Process Using Maximum Likelihood ';

proc model data=grunfeld model=grunmod;
   %ma(gei,1, m=ml);
   %ma(whi,1, m=ml);
   fit whi gei;
run;

For comparison, the model is estimated by using PROC ARIMA as follows: 

title2 'PROC ARIMA Using Maximum Likelihood ';

proc arima data=grunfeld;
   identify var=whi cross=(whf whc) noprint;
   estimate q=1 input=(whf whc) method=ml;
run;

PROC ARIMA does not estimate systems, so only one equation is evaluated.

The estimation results are shown in Output 18.4.3 and Output 18.4.4. The small differences in the parameter values between PROC MODEL and PROC ARIMA can be eliminated by tightening the convergence criteria for both procedures.

Output 18.4.3 PROC MODEL Results by Using ML Estimation
Example of MA(1) Error Process Using Grunfeld's Model
MA(1) Error Process Using Maximum Likelihood

The MODEL Procedure

Nonlinear OLS Summary of Residual Errors 
Equation DF Model DF Error SSE MSE Root MSE R-Square Adj R-Sq Label
whi 4 16 1857.5 116.1 10.7746 0.7323 0.6821 Gross Investment WH
resid.whi   16 1344.0 84.0012 9.1652     Gross Investment WH
gei 4 16 13742.5 858.9 29.3071 0.6936 0.6361 Gross Investment GE
resid.gei   16 8095.3 506.0 22.4935     Gross Investment GE

Nonlinear OLS Parameter Estimates
Parameter Estimate Approx Std Err t Value Approx
Pr > |t|		 Label
ge_int -25.002 34.2933 -0.73 0.4765 GE Intercept
ge_f 0.03712 0.0161 2.30 0.0351 GE Lagged Share Value Coef
ge_c 0.137788 0.0380 3.63 0.0023 GE Lagged Capital Stock Coef
wh_int 2.946761 9.5638 0.31 0.7620 WH Intercept
wh_f 0.050395 0.0174 2.89 0.0106 WH Lagged Share Value Coef
wh_c 0.066531 0.0729 0.91 0.3749 WH Lagged Capital Stock Coef
gei_m1 -0.78516 0.1942 -4.04 0.0009 MA(gei) gei lag1 parameter
whi_m1 -0.69389 0.2540 -2.73 0.0148 MA(whi) whi lag1 parameter

Output 18.4.4 PROC ARIMA Results by Using ML Estimation
Example of MA(1) Error Process Using Grunfeld's Model
PROC ARIMA Using Maximum Likelihood

The ARIMA Procedure

Maximum Likelihood Estimation
Parameter Estimate Standard Error t Value Approx
Pr > |t|		 Lag Variable Shift
MU 2.95645 9.20752 0.32 0.7481 0 whi 0
MA1,1 -0.69305 0.25307 -2.74 0.0062 1 whi 0
NUM1 0.05036 0.01686 2.99 0.0028 0 whf 0
NUM2 0.06672 0.06939 0.96 0.3363 0 whc 0

Constant Estimate 2.956449
Variance Estimate 81.29645
Std Error Estimate 9.016455
AIC 148.9113
SBC 152.8942
Number of Residuals 20

Previous Page | Next Page | Top of Page

Copyright © SAS Institute, Inc. All Rights Reserved.