The PDLREG Procedure

## Example 20.1 Industrial Conference Board Data

In this example, a second-degree Almon polynomial lag model is fit to a model with a five-period lag, and dummy variables are used for quarter effects. The PDL model is estimated using capital appropriations data series for the period 1952 to 1967. The estimation model is written

where CE represents capital expenditures and CA represents capital appropriations.

```   title 'National Industrial Conference Board Data';
title2 'Quarterly Series - 1952Q1 to 1967Q4';

data a;
input ce ca @@;
qtr = mod( _n_-1, 4 ) + 1;
q1  = qtr=1;
q2  = qtr=2;
q3  = qtr=3;
datalines;

... more lines ...

```
```   proc pdlreg data=a;
model ce = q1 q2 q3 ca(5,2) / dwprob;
run;
```

The printed output produced by the PDLREG procedure is shown in Output 20.1.1. The small Durbin-Watson test indicates autoregressive errors.

Output 20.1.1 Printed Output Produced by PROC PDLREG
 National Industrial Conference Board Data Quarterly Series - 1952Q1 to 1967Q4

The PDLREG Procedure

Dependent Variable ce

 National Industrial Conference Board Data Quarterly Series - 1952Q1 to 1967Q4

The PDLREG Procedure

Ordinary Least Squares Estimates
SSE 1205186.4 DFE 48
MSE 25108 Root MSE 158.45520
SBC 733.84921 AIC 719.797878
MAE 107.777378 AICC 722.180856
MAPE 3.71653891 Regress R-Square 0.9834
Durbin-Watson 0.6157 Total R-Square 0.9834

Variable DF Estimate Standard Error t Value Approx
Pr > |t|
Intercept 1 210.0109 73.2524 2.87 0.0061
q1 1 -10.5515 61.0634 -0.17 0.8635
q2 1 -20.9887 59.9386 -0.35 0.7277
q3 1 -30.4337 59.9004 -0.51 0.6137
ca**0 1 0.3760 0.007318 51.38 <.0001
ca**1 1 0.1297 0.0251 5.16 <.0001
ca**2 1 0.0247 0.0593 0.42 0.6794

Estimate of Lag Distribution
Variable Estimate Standard Error t Value Approx
Pr > |t|

0                                    0.2444
ca(0) 0.089467 0.0360 2.49 0.0165 |***************                          |
ca(1) 0.104317 0.0109 9.56 <.0001 |*****************                        |
ca(2) 0.127237 0.0255 5.00 <.0001 |*********************                    |
ca(3) 0.158230 0.0254 6.24 <.0001 |***************************              |
ca(4) 0.197294 0.0112 17.69 <.0001 |*********************************        |
ca(5) 0.244429 0.0370 6.60 <.0001 |*****************************************|

The following statements use the REG procedure to fit the same polynomial distributed lag model. A DATA step computes lagged values of the regressor X, and RESTRICT statements are used to impose the polynomial lag distribution. Refer to Judge et al. (1985, pp. 357–359) for the restricted least squares estimation of the Almon distributed lag model.

```   data b;
set a;
ca_1 = lag( ca );
ca_2 = lag2( ca );
ca_3 = lag3( ca );
ca_4 = lag4( ca );
ca_5 = lag5( ca );
run;

proc reg data=b;
model  ce = q1 q2 q3 ca ca_1 ca_2 ca_3 ca_4 ca_5;
restrict   - ca + 5*ca_1 - 10*ca_2 + 10*ca_3 - 5*ca_4 +   ca_5;
restrict     ca - 3*ca_1 +  2*ca_2 +  2*ca_3 - 3*ca_4 +   ca_5;
restrict  -5*ca + 7*ca_1 +  4*ca_2 -  4*ca_3 - 7*ca_4 + 5*ca_5;
run;
```

The REG procedure output is shown in Output 20.1.2.

Output 20.1.2 Printed Output Produced by PROC REG
 National Industrial Conference Board Data Quarterly Series - 1952Q1 to 1967Q4

The REG Procedure
Model: MODEL1
Dependent Variable: ce

Analysis of Variance
Source DF Sum of
Squares
Mean
Square
F Value Pr > F
Model 6 71343377 11890563 473.58 <.0001
Error 48 1205186 25108
Corrected Total 54 72548564

 Root MSE R-Square 158.455 0.9834 3185.69 0.9813 4.97397

Parameter Estimates
Variable DF Parameter
Estimate
Standard
Error
t Value Pr > |t|
Intercept 1 210.01094 73.25236 2.87 0.0061
q1 1 -10.55151 61.06341 -0.17 0.8635
q2 1 -20.98869 59.93860 -0.35 0.7277
q3 1 -30.43374 59.90045 -0.51 0.6137
ca 1 0.08947 0.03599 2.49 0.0165
ca_1 1 0.10432 0.01091 9.56 <.0001
ca_2 1 0.12724 0.02547 5.00 <.0001
ca_3 1 0.15823 0.02537 6.24 <.0001
ca_4 1 0.19729 0.01115 17.69 <.0001
ca_5 1 0.24443 0.03704 6.60 <.0001
RESTRICT -1 623.63242 12697 0.05 0.9614*
RESTRICT -1 18933 44803 0.42 0.6772*
RESTRICT -1 10303 18422 0.56 0.5814*

* Probability computed using beta distribution.

 Previous Page | Next Page | Top of Page