Example 19.4 The Airline Cost Data: Random-Effects Models

This example continues to use the Christenson Associates airline data, which measures costs, prices of inputs, and utilization rates for six airlines over the time span 1970–1984. There are six cross sections and fifteen time observations. Here, you examine the different estimates generated from the one-way random-effects and two-way random-effects models, by using four different methods to estimate the variance components: Fuller and Battese, Wansbeek and Kapteyn, Wallace and Hussain, and Nerlove.

The data for this example is created by the PROC PANEL statements shown in Example 19.2. The PROC PANEL statements necessary to generate the estimates are as follows:

   proc panel data=airline outest=estimates;
      id I T;
      RANONE:   model lC = lQ lPF lF / ranone vcomp=fb;
      RANONEwk: model lC = lQ lPF lF / ranone vcomp=wk;
      RANONEwh: model lC = lQ lPF lF / ranone vcomp=wh;
      RANONEnl: model lC = lQ lPF lF / ranone vcomp=nl;
      RANTWO:   model lC = lQ lPF lF / rantwo vcomp=fb;
      RANTWOwk: model lC = lQ lPF lF / rantwo vcomp=wk;
      RANTWOwh: model lC = lQ lPF lF / rantwo vcomp=wh;
      RANTWOnl: model lC = lQ lPF lF / rantwo vcomp=nl;
      POOLED:   model lC = lQ lPF lF / pooled;
      BTWNG:    model lC = lQ lPF lF / btwng;
      BTWNT:    model lC = lQ lPF lF / btwnt;
   run;

   data table;
     set estimates;
      VarCS  = round(_VARCS_,.00001);
      VarTS  = round(_VARTS_,.00001);
      VarErr = round(_VARERR_,.00001);
      Int    = round(Intercept,.0001);
      lQ2    = round(lQ,.0001);
      lPF2   = round(lPF,.0001);
      lF2    = round(lF,.0001);
      if _n_ >= 9 then do; 
      VarCS = . ;                                                                                                                       
      VarTS = . ;                                                                                                                                    end;                                                                                                                              
      keep _MODEL_ _METHOD_ VarCS VarTS VarErr Int lQ2 lPF2 lF2;
   run;

The parameter estimates and variance components for both models are reported in Output 19.4.1 and Output 19.4.2.

   title "Parameter Estimates";
   proc print data=table label noobs;
      label _MODEL_  = "Model"
            _METHOD_ = "Method"
            Int  = "Intercept"
            lQ2  = "lQ"
            lPF2 = "lPF"
            lF2  = "lF";
      var _METHOD_ _MODEL_ Int lQ2 lPF2 lF2;
   run;

   title "Variance Component Estimates" ;
   proc print data=table label noobs;
      label _MODEL_  = "Model"
            _METHOD_ = "Method"
            VarCS  = "Variance Component for Cross Sections"
            VarTS  = "Variance Component for Time Series"
            VarErr = "Variance Component for Error";
      var _METHOD_ _MODEL_ VarCS VarTS VarErr;
   run;
   title '';

In the random-effects model, individual constant terms are viewed as randomly distributed across cross-sectional units and not as parametric shifts of the regression function, as in the fixed-effects model. This is appropriate when the sampled cross-sectional units are drawn from a large population. Clearly, in this example, the six airlines are a sample of all the airlines in the industry and not an exhaustive, or nearly exhaustive, list.

There are four ways of computing the variance components in the one-way random-effects model. The method by Fuller and Battese (1974) (FB), uses a "fitting of constants" methods to estimate them. The Wansbeek and Kapteyn (1989) (WK) method uses the true disturbances, while the Wallace and Hussain (WH) method uses ordinary least squares residuals.

Looking at the estimates of the variance components for cross section and error in Output 19.4.2, you see that equal variance components for error are computed for both FB and WK, while WH and NL are nearly equal.

All four techniques produce different variance components for cross sections. These estimates are then used to estimate the values of the parameters in Output 19.4.1. All the parameters appear to have similar and equally plausible estimates. Both the index for output in revenue passenger miles (lQ) and fuel price (lPF) have small, positive effects on total costs, which you would expect. The load factor (LF) has a somewhat larger and negative effect on total costs, suggesting that as utilization increases, costs decrease.

As in the one-way random-effects model, the variance components for error produced by the FB and WK methods are equal. However, in this case, the WH and NL methods produce variance estimates that are dissimilar. The estimates of the variance component for cross sections are all different, but in a close range. The same cannot be said for the variance component for time series. As varied as each of the variance estimates may be, they produce parameter estimates that are similar and plausible. As with the one-way effects model, the index for output (lQ) and fuel price (lPF) are small and positive. The load factor (LF) estimates are all negative and, with the exception of the estimate produced by the WH method, somewhat smaller than the estimates produced in the one-way model. During the time the data were collected, the Civil Aeronautics Board dissolved, so it is possible that the dummy variables are proxies for this dissolution. This would lead to the decay of time effects and an imprecise estimation of the effects of the load factors, even though the estimates are statistically significant.

The pooled estimates give you something to compare the random-effects estimates against. You see that signs and magnitudes of output and fuel price are similar but that the magnitude of the load factor coefficient is somewhat larger under pooling. Since the model appears to have both cross-sectional and time series effects, the pooled model should not be used.

Finally, you examine the between groups estimators. For the between groups estimate, you are looking at each airline’s data averaged across time. You see in Output 19.4.1 that the between groups parameter estimates are radically different from all other parameter estimates. This could indicate that the time component is not being appropriately handled with this technique. For the between times estimate, you are looking at the average across all airlines in each time period. In this case, the parameter estimates are of the same sign and closer in magnitude to the previously computed estimates. Both the output and load factor effects appear to have more bearing on total costs.