PROC LOAN: Refinancing a Loan :: SAS/ETS(R) 9.2 User's Guide

The LOAN Procedure

Example 16.2 Refinancing a Loan

Assume that you obtained a fixed rate 15-year loan in June 1995 for $78,500 with a nominal annual rate of 9%. By early 1998, the market offers a 6.5% interest rate, and you are considering whether to refinance your loan.

Use the following statements to find out the status of the loan on February 1998. Output 16.2.1 shows the results:

   proc loan start=1995:6;
      fixed life=180 rate=9 amount=78500 noprint
            label='Original Loan';
      compare at=('10FEB1998'd);
   run;

Output 16.2.1 Loan Comparison Report for Original Loan

The LOAN Procedure

Loan Comparison Report Analysis through FEB1998
Loan Label	Ending Outstanding	Payment	Interest Paid	True Rate
Original Loan	71028.75	796.20	18007.15	9.38

The monthly payment on the original loan is $796.20. The ending outstanding principal balance as of February is $71,028.75. At this point, you might want to refinance your loan with another 15-year loan. The alternate loan has a 6.5% nominal annual rate. The initialization costs are $1,419.00. Use the following statements to compare your alternatives:

   proc loan start=1998:2 amount=71028.75;
      fixed rate=9 payment=796.20
            label='Keep the original loan' noprint;
      fixed life=180 rate=6.5 init=1419
            label='Refinance at 6.5%' noprint;
      compare at=(15 16) taxrate=33 marr=4 all;
   run;

The comparison reports of May 1999 and June 1999 in Output 16.2.2 illustrate the break even between the two alternatives. If you intend to keep the loan through June 1999 or longer, your initialization costs for the refinancing are justified. The periodic payment of the refinanced loan is $618.74.

Output 16.2.2 Loan Comparison Report for Refinancing Decision

The LOAN Procedure

Loan Comparison Report Analysis through MAY1999
Loan Label	Ending Outstanding	Present Worth of Cost	Payment	Interest Paid	True Rate
Keep the original loan	66862.10	72737.27	796.20	7776.35	6.20
Refinance at 6.5%	67382.48	72747.51	618.74	5634.83	6.23

Note:

"Keep the original loan" is the best alternative based on present worth of cost analysis through MAY1999.

Loan Comparison Report Analysis through JUN1999
Loan Label	Ending Outstanding	Present Worth of Cost	Payment	Interest Paid	True Rate
Keep the original loan	66567.37	72844.52	796.20	8277.82	6.20
Refinance at 6.5%	67128.73	72766.42	618.74	5999.82	6.12

Note:

"Refinance at 6.5%" is the best alternative based on present worth of cost analysis through JUN1999.

Top of Page