This sample illustrates one method of counting the number of missing and non-missing values for each variable in a data set. Two methods for structuring the resulting data set are shown.

---

These sample files and code examples are provided by SAS Institute Inc. "as is" without warranty of any kind, either express or implied, including but not limited to the implied warranties of merchantability and fitness for a particular purpose. Recipients acknowledge and agree that SAS Institute shall not be liable for any damages whatsoever arising out of their use of this material. In addition, SAS Institute will provide no support for the materials contained herein.

---

/* create sample data */
data one;
  input a $ b $ c $ d e;
cards;
a . a 1 3
. b . 2 4
a a a . 5
. . b 3 5
a a a . 6
a a a . 7
a a a 2 8
;
run;

/* create a format to group missing and non-missing */
proc format;
 value $missfmt ' '='missing'
                other='non-missing';
 value missfmt .='missing'
               other='non-missing';
run;

%macro lst(dsn);
  /** open dataset **/
  %let dsid=%sysfunc(open(&dsn));

  /** cnt will contain the number of variables in the dataset passed in **/
  %let cnt=%sysfunc(attrn(&dsid,nvars));

   %do i = 1 %to &cnt;
    /** create a different macro variable for each variable in dataset **/
    %let x&i=%sysfunc(varname(&dsid,&i));
    /** list the type of the current variable **/
    %let typ&i=%sysfunc(vartype(&dsid,&i));
   %end;

  /** close dataset **/
  %let rc=%sysfunc(close(&dsid));

%do i = 1 %to &cnt;
/* loop through each variable in PROC FREQ and create */
/* a separate output data set */
proc freq data=&dsn noprint;
tables &&x&i / missing out=out&i(drop=percent rename=(&&x&i=value));
format &&x&i %if &&typ&i = C %then %do; $missfmt. %end; 
%else %do; missfmt. %end;;
run;

data out&i;
set out&i;
varname="&&x&i";
/* create a new variable that is character so that */
/* the data sets can be combined */
%if &&typ&i=N %then %do;
 value1=put(value, missfmt.);
%end;
%else %if &&typ&i=C %then %do;
 value1=put(value, $missfmt.);
%end;
 drop value;
 rename value1=value;
run;

%end;

data combine;
set %do i=1 %to &cnt;
 out&i
%end;;
run;

proc print data=combine;
run;

%mend lst;
%lst(one)

/* another way to reshape the COMBINE data set */
proc transpose data=combine out=out(drop=_name_ _label_);
by varname;
id value;
var count;
run;

proc print data=out;
run;

---

These sample files and code examples are provided by SAS Institute Inc. "as is" without warranty of any kind, either express or implied, including but not limited to the implied warranties of merchantability and fitness for a particular purpose. Recipients acknowledge and agree that SAS Institute shall not be liable for any damages whatsoever arising out of their use of this material. In addition, SAS Institute will provide no support for the materials contained herein.

Original output

COUNT    varname    value

  2         a       missing
  5         a       non-missing
  2         b       missing
  5         b       non-missing
  1         c       missing
  6         c       non-missing
  3         d       missing
  4         d       non-missing
  7         e       non-missing



Transposed output

                        non_
varname    missing    missing

   a          2          5
   b          2          5
   c          1          6
   d          3          4
   e          .          7

This sample combines macro programming with PROC FREQ and DATA Step logic to count the number of missing and non-missing values for every variable in a data set. The results are stored in a data set.

Type:

Sample

Date Modified:	2011-08-30 16:24:59
Date Created:	2011-08-26 11:51:18

Operating System and Release Information

Product Family	Product	Host	SAS Release
			Starting	Ending
SAS System	Base SAS	z/OS
		Z64
		OpenVMS VAX
		Microsoft® Windows® for 64-Bit Itanium-based Systems
		Microsoft Windows Server 2003 Datacenter 64-bit Edition
		Microsoft Windows Server 2003 Enterprise 64-bit Edition
		Microsoft Windows XP 64-bit Edition
		Microsoft® Windows® for x64
		OS/2
		Microsoft Windows 95/98
		Microsoft Windows 2000 Advanced Server
		Microsoft Windows 2000 Datacenter Server
		Microsoft Windows 2000 Server
		Microsoft Windows 2000 Professional
		Microsoft Windows NT Workstation
		Microsoft Windows Server 2003 Datacenter Edition
		Microsoft Windows Server 2003 Enterprise Edition
		Microsoft Windows Server 2003 Standard Edition
		Microsoft Windows Server 2003 for x64
		Microsoft Windows Server 2008
		Microsoft Windows Server 2008 for x64
		Microsoft Windows XP Professional
		Windows 7 Enterprise 32 bit
		Windows 7 Enterprise x64
		Windows 7 Home Premium 32 bit
		Windows 7 Home Premium x64
		Windows 7 Professional 32 bit
		Windows 7 Professional x64
		Windows 7 Ultimate 32 bit
		Windows 7 Ultimate x64
		Windows Millennium Edition (Me)
		Windows Vista
		Windows Vista for x64
		64-bit Enabled AIX
		64-bit Enabled HP-UX
		64-bit Enabled Solaris
		ABI+ for Intel Architecture
		AIX
		HP-UX
		HP-UX IPF
		IRIX
		Linux
		Linux for x64
		Linux on Itanium
		OpenVMS Alpha
		OpenVMS on HP Integrity
		Solaris
		Solaris for x64
		Tru64 UNIX