The following examples demonstrate how to interpret the parameter estimates displayed by the SOLUTION option in the MODEL statement of PROC GLM. The examples include a one-way analysis of variance (ANOVA) model, a two-way ANOVA model with interaction, and an analysis of covariance (ANCOVA) model.

In PROC GLM, a predictor variable specified in the CLASS statement is represented in the model by a set of design variables created using GLM parameterization as discussed in this usage note. This parameterization imposes a particular interpretation on the parameters of the model. This interpretation of parameters, presented below, also applies to other procedures that use the GLM parameterization for CLASS variables such as PROC MIXED and PROC GLIMMIX.

Parameter interpretation in a one-way ANOVA model

The following statements create the data set to be analyzed and fit a one-way ANOVA model.

   data DrugTest;
      input Drug $ Gender $ X Y @@;
      datalines;
      A F  9 25  A F  3 19  A F  4 18  A F  11 28  A F  7 23
      A M 11 27  A M  9 24  A M  9 25  A M  10 28  A M 10 26
      D F  4 37  D F 12 54  D F  3 33  D F   6 41  D F  9 47
      D M  5 36  D M  4 36  D M  7 40  D M  10 46  D M  8 42
      G F 10 70  G F 11 75  G F  7 60  G F   9 69  G F 10 71
      G M  3 47  G M  8 60  G M 11 70  G M   4 49  G M  4 50
      ;
   
   proc glm data=DrugTest;
      ods select ParameterEstimates;
      class Drug;
      model Y = Drug / solution;
      run;

Following is the table of parameter estimates produced by the SOLUTION option.

Parameter Estimate   Standard Error t Value Pr > |t| Intercept 62.10000000 B 2.31148501 26.87 <.0001 Drug A -37.80000000 B 3.26893345 -11.56 <.0001 Drug D -20.90000000 B 3.26893345 -6.39 <.0001 Drug G 0.00000000 B . . .

This analysis also displays the following message after the parameter estimates table:

NOTE: The X'X matrix has been found to be singular, and a generalized inverse was used to solve the normal equations. Terms whose estimates are followed by the letter 'B' are not uniquely estimable.

This note is generated any time you specify the SOLUTION option in the MODEL statement and your model includes one or more CLASS variables. See this usage note for more information.

In this example, the GLM parameterization of the CLASS variable Drug creates three indicator (or "dummy") variables, one for each level of Drug. The GLM parameterization sets the parameter estimate for the last level of each CLASS variable to zero. The last level is considered the reference level. Therefore Drug G is the reference level and has a parameter estimate of 0. The parameter estimates for other levels of Drug represent the difference in the effect of each level compared with the reference level, G. Specifically:

• The Intercept (62.1) estimates the mean of Y for Drug G. The p-value (p<0.0001) is from a test that this mean equals zero.
• The Drug A estimate (-37.8) is the estimated difference in the mean of Y between Drugs A and G. The p-value (p<0.0001) is from a test that this difference equals zero, or equivalently that the mean for Drug A equals the mean for Drug G.
• The Drug D estimate (-20.9) is the estimated difference in the mean of Y between Drugs D and G. The p-value (p<0.0001) is from a test that this difference equals zero, or equivalently that the mean for Drug D equals the mean for Drug G.

The parameter estimates and tests can be reproduced using appropriate ESTIMATE statements. Doing so clarifies the interpretation of the parameter estimates and the tests provided by the SOLUTION option. The following statements reproduce the results in the parameter estimates table. The linear combination of model parameters specified in each statement is consistent with the interpretations above.

   estimate 'Intercept' intercept 1  drug 0 0 1;
   estimate 'Drug A'    drug 1 0 -1;
   estimate 'Drug D'    drug 0 1 -1;

The following results are produced. Note that the estimates and p-values are identical.

Parameter Estimate Standard Error t Value Pr > |t| Intercept 62.1000000 2.31148501 26.87 <.0001 Drug A -37.8000000 3.26893345 -11.56 <.0001 Drug D -20.9000000 3.26893345 -6.39 <.0001

Parameter interpretation in a two-way ANOVA model including interaction

The following example illustrates the results when the model involves an interaction of effects.

   proc glm data=DrugTest;
      ods select ParameterEstimates;
      class Drug Gender;
      model Y = Drug Gender Drug*Gender / solution;
      run;

Following is the table of parameter estimates produced by the SOLUTION option. The singularity note is once again presented since the SOLUTION option is specified and the model includes CLASS variables.

Parameter Estimate   Standard Error t Value Pr > |t| Intercept 55.20000000 B 2.77368588 19.90 <.0001 Drug A -29.20000000 B 3.92258418 -7.44 <.0001 Drug D -15.20000000 B 3.92258418 -3.87 0.0007 Drug G 0.00000000 B . . . Gender F 13.80000000 B 3.92258418 3.52 0.0018 Gender M 0.00000000 B . . . Drug*Gender A F -17.20000000 B 5.54737175 -3.10 0.0049 Drug*Gender A M 0.00000000 B . . . Drug*Gender D F -11.40000000 B 5.54737175 -2.06 0.0509 Drug*Gender D M 0.00000000 B . . . Drug*Gender G F 0.00000000 B . . . Drug*Gender G M 0.00000000 B . . .

Due to the GLM parameterization of the CLASS variables, the estimates for Drug G and Gender M are set to zero. Similarly, interaction estimates involving at least one of these levels are also set to zero. The parameter estimates of the model are interpreted as follows:

• The Intercept (55.2) estimates the mean of Y for males (Gender=M) given Drug=G. The p-value (p<0.0001) is from a test that this mean equals zero.
• The Drug A estimate (-29.2) is the estimated difference in the mean of Y between Drugs A and G in males. The p-value (p<0.0001) is from a test that this difference equals zero, or equivalently that the mean for Drug A equals the mean for Drug G in males.
• The Drug D estimate (-15.2) is the estimated difference in the mean of Y between Drugs D and G in males. The p-value (p<0.0007) is from a test that this difference equals zero, or equivalently that the mean for Drug D equals the mean for Drug G in males.
• The Gender F estimate (13.8) is the estimated difference in the mean of Y between females (Gender=F) and males (Gender=M) given Drug G. The p-value (p<0.0018) is from a test that this difference equals zero, or equivalently that the mean for females equals the mean for males when given Drug G.
• The Drug A, Gender F estimate (-17.2) is the estimated difference in the mean of Y of the Drug A and G differences for females and males. That is, it is the difference in the effects of Drugs A and G in females minus the difference in the effects of Drugs A and G in males, or equivalently, the difference between females and males given Drug A minus the difference between females and males given Drug G. The p-value (p<0.0049) is from a test that this difference equals zero.
• The Drug D, Gender F estimate (-11.4) is the estimated difference in the mean of Y of the Drug D and G differences for females and males. That is, it is the difference in the effects of Drugs D and G in females minus the difference in the effects of Drugs D and G in males, or equivalently, the difference between females and males given Drug D minus the difference between females and males given Drug G. The p-value (p<0.0509) is from a test that this difference equals zero.

Again, ESTIMATE statements reproducing the parameter estimates and tests clarify the interpretations. The following statements reproduce the results in the parameter estimates table. Note the order of the parameters and their correspondence to variable levels in the parameter estimates table. Hence, drug*gender 0 1 0 0 0 -1 selects the "Drug*Gender A M" parameter and the negative of the "Drug*Gender G M" parameter.

   estimate 'Intercept'        intercept 1  drug 0 0 1  gender 0 1  drug*gender 0 0 0 0 0 1;
   estimate 'Drug A'           drug 1 0 -1  drug*gender 0 1 0 0 0 -1;
   estimate 'Drug D'           drug 0 1 -1  drug*gender 0 0 0 1 0 -1;
   estimate 'Gender F'         gender 1 -1  drug*gender 0 0 0 0 1 -1;
   estimate 'Drug A, Gender F' drug*gender 1 -1 0 0 -1 1;
   estimate 'Drug D, Gender F' drug*gender 0 0 1 -1 -1 1;

Parameter interpretation in an ANCOVA model

The following example illustrates the results when the two-way model involves a categorical (CLASS) predictor, a continuous covariate, and their interaction. This model is a set of three lines, showing the effect of X on Y for each of the three drugs. The general problem of comparing slopes is further discussed in this note.

   proc glm data=DrugTest;
      ods select ParameterEstimates;
      class Drug;
      model Y = Drug X Drug*X / solution;
      run;

Following is the table of parameter estimates produced by the SOLUTION option. The singularity note is once again presented since the SOLUTION option is specified and the model includes CLASS variables.

Parameter Estimate   Standard Error t Value Pr > |t| Intercept 36.34482759 B 1.42964273 25.42 <.0001 Drug A -22.00245954 B 2.18928079 -10.05 <.0001 Drug D -9.37575542 B 1.95210319 -4.80 <.0001 Drug G 0.00000000 B . . . X 3.34482759 B 0.17375335 19.25 <.0001 X*Drug A -2.14511289 B 0.25770115 -8.32 <.0001 X*Drug D -1.25204408 B 0.25081721 -4.99 <.0001 X*Drug G 0.00000000 B . . .

Due to the GLM parameterization of the CLASS variables, the estimates for Drug G and the interaction between X and Drug G are set to zero. The parameter estimates of the model are interpreted as follows:

• The Intercept (36.34482759) estimates the mean of Y for Drug G when X=0. That is, it is the intercept of the Drug G line in the model. The p-value (p<0.0001) is from a test that this mean equals zero.
• The Drug A estimate (-22.00245954) is the estimated difference in the mean of Y between Drugs A and G when X=0. That is, it is the difference in intercepts between the Drug A and Drug G lines in the model. The p-value (p<0.0001) is from a test that this difference equals zero, or equivalently that the Drug A and Drug G lines have the same intercept. Since the intercept for Drug G is 36.3448, the intercept for Drug A is 36.3448+(-22.0025) = 14.3423.
• The Drug D estimate (-9.37575542) is the estimated difference in the mean of Y between Drugs D and G when X=0. That is, it is the difference in intercepts between the Drug D and Drug G lines in the model. The p-value (p<0.0001) is from a test that this difference equals zero, or equivalently that the Drug D and Drug G lines have the same intercept. Since the intercept for Drug G is 36.3448, the intercept for Drug D is 36.3448+(-9.3758) = 26.9690.
• The X estimate (3.34482759) is the estimated slope for the Drug G line in the model. The p-value (p<0.0001) is from a test that this slope equals zero, or equivalently that the Drug G line is parallel to the X axis.
• The X*Drug A estimate (-2.14511289) is the estimated difference in the slopes of the Drug A and Drug G lines in the model. The p-value (p<0.0001) is from a test that this difference equals zero or equivalently that the Drug A and Drug G lines are parallel. Since the slope estimate for Drug G is 3.3448, the slope estimate for Drug A is 3.3448+(-2.1451) = 1.1997.
• The X*Drug D estimate (-1.25204408) is the estimated difference in the slopes of the Drug D and Drug G line in the model. The p-value (p<0.0001) is from a test that this difference equals zero or equivalently that the Drug D and Drug G lines are parallel. Since the slope estimate for Drug G is 3.3448, the slope estimate for Drug D is 3.3448+(-1.2520) = 2.0928.

Again, ESTIMATE statements reproducing the parameter estimates and tests clarify the interpretations. The following statements reproduce the results in the parameter estimates table.

   estimate 'Intercept' intercept 1  drug 0 0 1  x 0;
   estimate 'Drug A'    drug 1 0 -1  x 0;
   estimate 'Drug D'    drug 0 1 -1  x 0;
   estimate 'X'         x 1  x*drug 0 0 1;
   estimate 'X*Drug A'  x*drug 1 0 -1;
   estimate 'X*Drug D'  x*drug 0 1 -1;

Operating System and Release Information

Product Family	Product	System	SAS Release
			Reported	Fixed*
SAS System	SAS/STAT	z/OS
		OpenVMS VAX
		Microsoft® Windows® for 64-Bit Itanium-based Systems
		Microsoft Windows Server 2003 Datacenter 64-bit Edition
		Microsoft Windows Server 2003 Enterprise 64-bit Edition
		Microsoft Windows XP 64-bit Edition
		Microsoft® Windows® for x64
		OS/2
		Microsoft Windows 95/98
		Microsoft Windows 2000 Advanced Server
		Microsoft Windows 2000 Datacenter Server
		Microsoft Windows 2000 Server
		Microsoft Windows 2000 Professional
		Microsoft Windows NT Workstation
		Microsoft Windows Server 2003 Datacenter Edition
		Microsoft Windows Server 2003 Enterprise Edition
		Microsoft Windows Server 2003 Standard Edition
		Microsoft Windows Server 2008
		Microsoft Windows XP Professional
		Windows 7 Enterprise 32 bit
		Windows 7 Enterprise x64
		Windows 7 Home Premium 32 bit
		Windows 7 Home Premium x64
		Windows 7 Professional 32 bit
		Windows 7 Professional x64
		Windows 7 Ultimate 32 bit
		Windows 7 Ultimate x64
		Windows Millennium Edition (Me)
		Windows Vista
		64-bit Enabled AIX
		64-bit Enabled HP-UX
		64-bit Enabled Solaris
		ABI+ for Intel Architecture
		AIX
		HP-UX
		HP-UX IPF
		IRIX
		Linux
		Linux for x64
		Linux on Itanium
		OpenVMS Alpha
		OpenVMS on HP Integrity
		Solaris
		Solaris for x64
		Tru64 UNIX

* For software releases that are not yet generally available, the Fixed Release is the software release in which the problem is planned to be fixed.

---

Type:	Usage Note
Priority:
Topic:	Analytics ==> Analysis of Variance Analytics ==> Mixed Models SAS Reference ==> Procedures ==> GENMOD SAS Reference ==> Procedures ==> GLIMMIX SAS Reference ==> Procedures ==> GLM SAS Reference ==> Procedures ==> MIXED

Date Modified:	2015-02-23 14:44:23
Date Created:	2010-01-12 22:22:53