You may already know how to send email from SAS. The challenge addressed here is how to format a readable graph for a BlackBerry or any other very small screen device. The minimalist image below is one viable example.

Your SAS program can send e-mail to multiple addresses, with multiple attachments, with a CC and BCC. For more information about SAS e-mail in the SAS 9.1.3 OnlineDoc, go to: support.sas.com/onlinedoc/913/getDoc/en/lrdict.hlp/a002058232.htm.

Note: To get a similar looking result with a different release of SAS/GRAPH, it may be necessary to change one or more of the following: bar width, bar space, inserted space at the top of the graph, inserted space at the right-hand side of the graph.

---

About the Author
Dr. LeRoy Bessler has long advocated for, and implemented, minimalist graphic design in numerous SAS user conference papers that demonstrate the power of simplicity for communication effectiveness.

---

These sample files and code examples are provided by SAS Institute Inc. "as is" without warranty of any kind, either express or implied, including but not limited to the implied warranties of merchantability and fitness for a particular purpose. Recipients acknowledge and agree that SAS Institute shall not be liable for any damages whatsoever arising out of their use of this material. In addition, SAS Institute will provide no support for the materials contained herein.

---

The following code will produce the graphic displayed in this sample. 
For this sample to work, specify the file location and e-mail address as appropriate.

   goptions reset=all;
   goptions device=GIF;
   goptions ypixels=129 xpixels=172; /* Default size for a GIF image is 800 X 600.
            Preserve 4-to-3 aspect ratio, but adjust the size for the screen of a BlackBerry. */
   goptions border; /* Put the graph in a box. */
   goptions cback=CXFFFF00; /* Use RGB Yellow for background. */
   goptions htext=10 PCT ftext='Verdana'; /* Specify height and font used for those parts of the graph
            for which you do not make an explicit assignment,
            or for which no direct controls are available in SAS/GRAPH. */

   goptions gsfmode=replace gsfname=anyname;
   filename anyname "C:\FolderName\FileName.GIF";

   title1 font='Verdana'
     color=CX000000   /* RGB black */
     height=3 PCT ' ' /* Insert space at the top. */
     height=10 PCT
     justify=CENTER   /* Force a new line. */
     "Ranked Age Distribution of"
     justify=CENTER   /* Force a new line. */
     "Students in sashelp.class";

   footnote1 angle=+90 font='Verdana' height=2 PCT ' ';
     /* This "footnote" is a blank "right-side-note" to increase space at the side of the image. */
     /* Use angle=-90 to create a "left-side-note" if needed. */  

   pattern1 v=solid color= CX007400; /* Use an RGB Medium Dark Green for the bars. */

     /* Remove all axis paraphernalia: */
   axis1 label=none major=none minor=none style=0;
   axis2 label=none major=none minor=none style=0 value=none
         offset=(5 PCT,5 PCT);
      /* Offset the horizontal axis to insert extra space between bar midpoint label and bar start,
         and between bar end and bar response value. */

   proc gchart data=sashelp.class;
   hbar Age /
     discrete      /* Use Ages, not Age subranges. */
     freq
     freqlabel=' ' /* Suppress the Frequency column heading. */
     descending
     maxis=axis1 raxis=axis2
     width=4 space=3; /* bar width and spacing */
   run; quit;

   filename anyname2 email
     to="recipient@company.com"
     subject="Graph for Your BlackBerry"
     attach="C:\FolderName\FileName.GIF";

   data _null_;
   file anyname2;
   put 'Please see the attached graph.';
   run;

          These sample files and code examples are provided by SAS Institute
          Inc. "as is" without warranty of any kind, either express or implied, including
          but not limited to the implied warranties of merchantability and fitness for a
          particular purpose. Recipients acknowledge and agree that SAS Institute shall
          not be liable for any damages whatsoever arising out of their use of this material.
          In addition, SAS Institute will provide no support for the materials contained herein.
        

This sample addresses how to format a readable graph for very small screen devices.

Type:	Sample
Topic:	Third Party ==> Information Exchange ==> E-mail (SMTP)

Date Modified:	2007-07-25 03:02:39
Date Created:	2007-07-25 03:02:39

Operating System and Release Information

Product Family	Product	Host	SAS Release
			Starting	Ending
SAS System	SAS/GRAPH	Microsoft® Windows® for 64-Bit Itanium-based Systems	9.1 TS1M3	n/a
SAS System	Base SAS	Microsoft® Windows® for 64-Bit Itanium-based Systems	9.1 TS1M3	n/a