Sample 25596: Fill the area between plot lines using a SYMBOL statement with PROC GPLOT
The sample code on the
Full Code tab shows how to fill the area between two plot lines by concatenating two data sets into one to form a polygon with the data points. It uses a SYMBOL statement to specify a pattern to fill the polygon and to determine the color of the area fill and the outline around the area.
These sample files and code examples are provided by SAS Institute
Inc. "as is" without warranty of any kind, either express or implied, including
but not limited to the implied warranties of merchantability and fitness for a
particular purpose. Recipients acknowledge and agree that SAS Institute shall
not be liable for any damages whatsoever arising out of their use of this material.
In addition, SAS Institute will provide no support for the materials contained herein.
The sample code below shows how to fill the area between two plot lines by concatenating two data sets into one to form a polygon with the data points. It uses a SYMBOL statement to specify a pattern to fill the polygon and to determine the color of the area fill and the outline around the area.
/* Set the graphics environment */
goptions reset=all border cback=white htitle=12pt htext=9pt;
/* Create the data set STOCKS */
data stocks;
input Year High Low;
datalines;
1960 685.47 568.05
1961 734.91 610.25
1962 726.01 535.76
1963 767.21 646.79
1964 891.71 768.08
1965 969.26 840.59
1966 995.15 744.32
1967 943.08 786.41
1968 985.21 825.13
1969 968.85 769.93
1970 842.00 631.16
1971 950.82 797.97
1972 1036.27 889.15
1973 1051.70 788.31
1974 891.66 577.60
1975 881.81 632.04
1976 1014.79 858.71
1977 999.75 800.85
1978 907.74 742.12
1979 897.61 796.67
1980 1000.17 759.13
1981 1024.05 824.01
1982 1070.55 776.92
1983 1287.20 1027.04
1984 1286.64 1086.57
1985 1553.10 1184.96
1986 1955.57 1502.29
1987 2722.42 1738.74
1988 2183.50 1879.14
1989 2791.41 2144.64
1990 2999.75 2365.10
1991 3168.83 2470.30
1992 3413.21 3136.58
1993 3794.33 3241.95
1994 3978.36 3593.35
1995 5216.47 3832.08
1996 6560.91 5032.94
1997 8259.31 6391.69
1998 9374.27 7539.07
1999 11497.12 9120.67
2000 11722.98 9796.03
2001 11337.92 8235.81
2002 10635.25 7286.27
2003 10453.92 7524.06
2004 10854.54 9749.99
2005 10940.55 10012.36
2006 12510.57 10667.35
2007 14164.53 12050.41
2008 13058.20 6547.05
2009 10605.70 6440.08
2010 11655.0 9596.04
2011 12928.5 10362.3
2012 13588.7 12221.2
;
run;
/* Restructure the data so that */
/* it defines a closed area. */
/* Create the data sets HIGH and LOW */
data high(keep=year value)
low(keep=year value);
set stocks;
value=high; output high;
value=low; output low;
run;
/* Reverse order of the observations in LOW */
proc sort data=low;
by descending year;
run;
/* Concatenate HIGH and LOW to create data set AREA */
data area;
set high low;
run;
/* Define titles and footnote */
title1 'Dow Jones Industrial Average';
title2 h=11pt 'Highs and Lows From 1960 to 2012';
footnote1 ' ';
/* Define symbol characteristics */
symbol interpol=msolid /* map/plot pattern fill */
cv=vibg /* pattern fill color */
co=grp; /* outline color */
/* Define axis characteristics */
axis1 order=(1960 to 2012 by 4)
label=none
minor=(number=3)
offset=(1,1)
width=1;
axis2 order=(0 to 15000 by 1000)
label=none
offset=(0,0)
minor=(number=1);
/* Generate the graph using data set AREA */
proc gplot data=area;
plot value*year / haxis=axis1
vaxis=axis2
vref=(1000 3000 5000 7000 9000 11000 13000)
lvref=2;
format value comma6.0;
run;
quit;
These sample files and code examples are provided by SAS Institute
Inc. "as is" without warranty of any kind, either express or implied, including
but not limited to the implied warranties of merchantability and fitness for a
particular purpose. Recipients acknowledge and agree that SAS Institute shall
not be liable for any damages whatsoever arising out of their use of this material.
In addition, SAS Institute will provide no support for the materials contained herein.
This sample shows how to fill the area between two plot lines by concatenating two data sets into one to form a polygon with the data points. It uses a SYMBOL statement to specify a pattern to fill the polygon and to determine the color of the area fill and the outline around the area.
| Type: | Sample |
| Topic: | SAS Reference ==> Procedures ==> GPLOT
Query and Reporting ==> Creating Reports ==> Graphical ==> Graph Elements ==> Symbols/Interpolation
Query and Reporting ==> Creating Reports ==> Graphical ==> Graph Types ==> Plots ==> Area
|
| Date Modified: | 2005-09-22 03:03:13 |
| Date Created: | 2005-05-23 14:17:55 |
Operating System and Release Information
| SAS System | SAS/GRAPH | z/OS | 9.1 TS1M0 | |
| Microsoft® Windows® for 64-Bit Itanium-based Systems | 9.1 TS1M0 | |
| Microsoft Windows Server 2003 Datacenter 64-bit Edition | 9.1 TS1M0 | |
| Microsoft Windows Server 2003 Enterprise 64-bit Edition | 9.1 TS1M0 | |
| Microsoft Windows 2000 Advanced Server | 9.1 TS1M0 | |
| Microsoft Windows 2000 Datacenter Server | 9.1 TS1M0 | |
| Microsoft Windows 2000 Server | 9.1 TS1M0 | |
| Microsoft Windows 2000 Professional | 9.1 TS1M0 | |
| Microsoft Windows NT Workstation | 9.1 TS1M0 | |
| Microsoft Windows Server 2003 Datacenter Edition | 9.1 TS1M0 | |
| Microsoft Windows Server 2003 Enterprise Edition | 9.1 TS1M0 | |
| Microsoft Windows Server 2003 Standard Edition | 9.1 TS1M0 | |
| Microsoft Windows XP Professional | 9.1 TS1M0 | |
| 64-bit Enabled AIX | 9.1 TS1M0 | |
| 64-bit Enabled HP-UX | 9.1 TS1M0 | |
| 64-bit Enabled Solaris | 9.1 TS1M0 | |
| HP-UX IPF | 9.1 TS1M0 | |
| Linux | 9.1 TS1M0 | |
| OpenVMS Alpha | 9.1 TS1M0 | |
| Tru64 UNIX | 9.1 TS1M0 | |
