24944 - Use GREPLAY and macro code to replay a specific number of graphs per page

Sample 24944: Use GREPLAY and macro code to replay a specific number of graphs per page

This sample program uses PROC GREPLAY together with macro code to dynamically replay a specific number of graphs per page.

The graphics output in the Results tab was produced using SAS® 9.2. Submitting the sample code with releases of SAS prior to SAS 9.2 might produce different results.

 /* Delete any old entries in WORK.GSEG catalog */
proc greplay nofs igout=work.gseg;
  delete _all_;
run;
quit; 

 /* Specify macro debugging options */
options mprint mlogic symbolgen;

goptions reset=all device=gif;  

 /* Macro MAKEGRAF creates GSLIDE graph entries that are TREPLAYED         */
 /* by PROC GREPLAY later in this program.  Remove the %DO loop and GSLIDE */
 /* procedure and place your code within the MAKEGRAF macro when you are   */
 /* ready to create your own individual graph entries.                     */
%macro makegraf;
  %do i=1 %to 6;
    proc gslide; 
      title1 "GRAPH &i";
    run;
    quit;
  %end;
%mend makegraf;

 /* This macro will dynamically treplay a specified number of grseg entries  */
 /* per page/screen. The specified values for the parameters            */
 /* ACROSS and DOWN will determine the number of panels in the template */
 /* and the number of graphs per page/screen.                           */
%MACRO PERPAGE(across,down);

 /* Create macro variable perpage */
%let perpage=%eval(&across*&down);

 /* Use DSGI functions HSIZE/VSIZE to determine default HSIZE and VSIZE */
 /* and modify for correct aspect ratio.                                */
data garea;
  rc=ginit();
  call gask('hsize',hsize,rc);
  hsze=hsize/&across;
  call symput('hsize',left(trim(hsze)));
  call gask('vsize',vsize,rc);
  vsze=vsize/&down;
  call symput('vsize',left(trim(vsze)));
  rc=gterm();
run;

 /* Adjust VSIZE and HSIZE to reflect dimension of template panel. */
 /* Turn DISPLAY off.                                              */
goptions nodisplay vsize=&vsize hsize=&hsize;

 /* Invoke macro MAKEGRAF,                       */
 /* gslide entries created in WORK.GSEG catalog. */
%makegraf

 /* Use DSGI function NUMGRAPH to determine the number of entries in */
 /* WORK.GSEG catalog.                                               */
data numgraf;
  rc=gset('catalog','work','gseg');
  rc=ginit();
  call gask('numgraph',grsegcnt,rc);
  call symput('grsegcnt',grsegcnt);
  call symput('loopit',ceil(grsegcnt/&perpage));
  ymult=100/&down;
  xmult=100/&across;
  rc=gterm();
run;

 /* Calculate the panel coordinates for template */
data coord;
  set numgraf;
  do x=0 to (100-xmult) by xmult;
    llx=x;
    ulx=x;
    urx=x+xmult;
    lrx=x+xmult;
    do y=0 to (100-ymult) by ymult;
      lly=y;
      uly=y+ymult;
      ury=y+ymult;
      lry=y;
      output;
    end;
  end;
run;

proc sort;
  by descending y;
run;

 /* Create macro variables that resolve to panel coordinates */
data mccoord;
  set coord end=eof;
  call symput('llx'||left(_n_),llx);
  call symput('ulx'||left(_n_),ulx);
  call symput('urx'||left(_n_),urx);
  call symput('lrx'||left(_n_),lrx);

  call symput('lly'||left(_n_),lly);
  call symput('uly'||left(_n_),uly);
  call symput('ury'||left(_n_),ury);
  call symput('lry'||left(_n_),lry);

  if eof then call symput('total',_n_);
run;

 /* Macro to create template */
%macro tempdef;
  %do i=1 %to &total;
    &i / llx=&&llx&i     lly=&&lly&i
         ulx=&&ulx&i     uly=&&uly&i
         urx=&&urx&i     ury=&&ury&i
         lrx=&&lrx&i     lry=&&lry&i
         color=black
  %end;
%mend tempdef;

 /* Macro to generate TREPLAY statement for GREPLAY */
%macro tplay;
  %do j=1 %to &perpage;
    %if %eval(&i*&perpage-(&perpage-&j)) <= &grsegcnt %then
        &j:%eval(&i*&perpage-(&perpage-&j));
   %end;
%mend tplay;

 /* Macro to generate templated grseg entries */
%macro greplay;
  proc greplay nofs igout=work.gseg tc=tempcat;
    tdef spec&perpage
    %tempdef;
    template spec&perpage;
    %do i=1 %to &loopit;
      treplay %tplay;
      run;
    %end;
  quit;

%mend greplay;

 /* Reset the graphics options */
goptions reset=all device=gif 
         gsfname=grafout gsfmode=replace
         xpixels=600 ypixels=400;

filename grafout 'c:\temp\test.gif';  

 /* Invoke the GREPLAY macro */
%greplay

%MEND PERPAGE;

 /* Invoke the PERPAGE macro, specifying how you */
 /* want the graphs laid out on the page.        */
%PERPAGE(across=2,down=3);

These sample files and code examples are provided by SAS Institute Inc. "as is" without warranty of any kind, either express or implied, including but not limited to the implied warranties of merchantability and fitness for a particular purpose. Recipients acknowledge and agree that SAS Institute shall not be liable for any damages whatsoever arising out of their use of this material. In addition, SAS Institute will provide no support for the materials contained herein.

Type:	Sample
Topic:	SAS Reference ==> Procedures ==> GREPLAY

Date Modified:	2005-09-01 03:03:07
Date Created:	2004-11-11 11:08:05

Product Family	Product	Host	SAS Release
			Starting	Ending
SAS System	SAS/GRAPH	All	n/a	n/a

Support

Sample 24944: Use GREPLAY and macro code to replay a specific number of graphs per page

Operating System and Release Information