proc template;
    define tagset tagsets.noequal;
    parent=tagsets.html4;
    define event list_entry;
      start:

     /* Comment out the below statement so byval is a link */
     /*break / if cmp(HTMLCLASS,"bycontentfolder");        */
        put "<li";
        putq " class=" HTMLCLASS;
        put ">";
        trigger do_link /if listentryanchor;
        trigger do_list_value /if ^listentryanchor;
        trigger hyperlink finish / if !cmp(htmlclass,"ContentProcName");
      finish:

      /* Add a space only for a new PROC */
        put split NL / if cmp(htmlclass,"ContentProcName");
        put "</li>" NL;
    end;
    define event hyperlink;
      start:
        put "<a href=""" URL;
        put """";
        putq " target=" HREFTARGET;
        put ">";
        put VALUE / if !cmp(htmlclass,"bycontentfolder");
      finish:
        put "</a>" NL;
    end;

    /* Check value of BY variable. Locate and remove "=" */
    /* using DATA step functions.                        */

    define event do_list_value;
      eval $list index(reverse(value),"=")-1;
      eval $byval reverse(substr(reverse(value),1,$list));
      trigger hyperlink / if cmp(htmlclass,"bycontentfolder");

      put $byval;
    end;
    end;

  run;

  ods tagsets.noequal file='file.html' contents="contents.html" path="c:\temp";
proc sort data=sashelp.class; by age;
  ods proclabel "First output";
  proc print data=sashelp.class contents='';
    by age;
  run;

  ods proclabel "Second output";
  proc report data=sashelp.class nowd contents='';
    by age;
  run;

  ods proclabel "final output";
  proc print data=sashelp.class;
  run;

  proc univariate data=sashelp.class;
  run;

  ods tagsets.noequal close;